dev-util/intel-graphics-system-controller: add 0.9.5

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

dev-util/intel-graphics-system-controller/Manifest

@@ -1 +1,2 @@
 DIST intel-graphics-system-controller-0.9.3.tar.gz 206474 BLAKE2B 3af1caeed8d553b017f333ddacfbccb28e6d0f370ebc93b890686417fa400fb227f46cb83cfd686808a5e308ebbc2b2534b318ea4ba8a94a237b721e0ef5be37 SHA512 758059556efa6b94702291d11ca8267a3e4258299a324388c4a8fcb9efd2a2218ad354447ea32277439fc65d52f9481441d0bd699bfae1c375b7f807e21f9d94
+DIST intel-graphics-system-controller-0.9.5.tar.gz 207675 BLAKE2B 39e0bb6e7a81eadc31f44cad8a168c2077e39344bfe557a3d7417176c58b1cb15c22bebf0411d5b5c6af8e6acc2081f11a18383b5c45de8e7cd48f1aeb75b65e SHA512 6cd698e42cf5aa6b303fa1846b0906cbed16cb194bbdff860a11f9db31a2307a093f28d3caf19037ef9d4d62ef773066d88b9e0c0b7062fc24339ff4bdc9394e

dev-util/intel-graphics-system-controller/intel-graphics-system-controller-0.9.5.ebuild

@@ -0,0 +1,50 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="igsc"
+MY_P="${MY_PN}-${PV}"
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit cmake python-any-r1
+
+DESCRIPTION="Intel graphics system controller firmware update library"
+HOMEPAGE="https://github.com/intel/igsc"
+SRC_URI="https://github.com/intel/${MY_PN}/archive/refs/tags/V${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="Apache-2.0"
+SLOT="0/${PV}"
+KEYWORDS="~amd64"
+IUSE="+cli doc"
+
+RDEPEND=">=dev-libs/metee-3.2.4:="
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		app-text/doxygen
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+	)
+"
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CLI="$(usex cli)"
+		-DENABLE_DOCS="$(usex doc)"
+		-DENABLE_PERF="OFF"
+		-DENABLE_WERROR="OFF"
+
+		# If enabled, tests are automatically run during
+		# the compile phase and we cannot run them because
+		# they require permissions to access the hardware.
+		-DENABLE_TESTS="OFF"
+	)
+
+	cmake_src_configure
+}