mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
dev-python/pandas: Bump to 1.2.4
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -2,3 +2,4 @@ DIST pandas-1.1.5.tar.gz 5229894 BLAKE2B 5b47774e33c7fccd7a9110e8971e8ce63cafd68
|
||||
DIST pandas-1.2.1.tar.gz 5459053 BLAKE2B 49d99e7217d52f1233cdff20628da9028b7a8ce1d89a5ebe502c6e960ca9f7948005e7a63a15b76f9bc44ab5f15e00eef86c3b3179e6cad820e6f5072c7c78f0 SHA512 9bf9212ebdd07785f1877f5f80d6a5beb4637e8a1cf741e32a705a48724280a8e8daae209c66c1a3f00718b566127d77af578d6c72a5d9b68e2b03784c604083
|
||||
DIST pandas-1.2.2.tar.gz 5463571 BLAKE2B e27e032bb9d6abb6f40d1a15bc7e9796690f0bd099e5fc7704cbd5b40b37c0f277b462116bd7582263abef8f728d3109f6c4c425cac427f0c750b019fd5e8ad8 SHA512 288ec9f3a2042c2a376340ddc25b4e2d9d3c4de146468316378269d4b70fb271241acb9aa5295415d8bebabad859a9ea9dc95aa71a68f06c2eba73809b9b30e2
|
||||
DIST pandas-1.2.3.tar.gz 5466356 BLAKE2B f392321915128769814b3a8b7673cd7b00c9c292f4cb8d8b2e8537f7cc513f92cb6b8ff74dffe3b167987e8fa387738264dbebfdf4019f9cd7afd4f78234212a SHA512 3108424253aa143a85ef166091829bbd8c9b6446b516f37252742146d184f722e1fb8af5b4d04937362a298068019a91392e40c818126df6a7459bab7f3077cb
|
||||
DIST pandas-1.2.4.tar.gz 5469105 BLAKE2B 7f39e3ca67f5997c0668b0c2e9792869963adcd0347a3983188a992794ad58ccba82105b4dc3315cc17d79104f7fea7a273c218967eb51b1ea1514e87aeebb66 SHA512 79e7a38b8edad52b70eb81ba821141b928c782009d59c50076e7d1e7c015078d333c0c80bda7ba720f4ccb221a0ba93a02885fe6a573567ee37ffae14ee9b2c3
|
||||
|
||||
190
dev-python/pandas/pandas-1.2.4.ebuild
Normal file
190
dev-python/pandas/pandas-1.2.4.ebuild
Normal file
@@ -0,0 +1,190 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{7..9} )
|
||||
PYTHON_REQ_USE="threads(+)"
|
||||
|
||||
VIRTUALX_REQUIRED="manual"
|
||||
|
||||
inherit distutils-r1 flag-o-matic multiprocessing optfeature virtualx
|
||||
|
||||
DESCRIPTION="Powerful data structures for data analysis and statistics"
|
||||
HOMEPAGE="https://pandas.pydata.org/"
|
||||
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P/_/}.tar.gz"
|
||||
S="${WORKDIR}/${P/_/}"
|
||||
|
||||
SLOT="0"
|
||||
LICENSE="BSD"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~x86"
|
||||
IUSE="doc full-support minimal test X"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RECOMMENDED_DEPEND="
|
||||
>=dev-python/bottleneck-1.2.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/numexpr-2.1[${PYTHON_USEDEP}]
|
||||
"
|
||||
|
||||
# TODO: add pandas-gbq to the tree
|
||||
OPTIONAL_DEPEND="
|
||||
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
|
||||
dev-python/blosc[${PYTHON_USEDEP}]
|
||||
|| (
|
||||
dev-python/html5lib[${PYTHON_USEDEP}]
|
||||
dev-python/lxml[${PYTHON_USEDEP}]
|
||||
)
|
||||
dev-python/jinja[${PYTHON_USEDEP}]
|
||||
dev-python/matplotlib[${PYTHON_USEDEP}]
|
||||
|| (
|
||||
dev-python/openpyxl[${PYTHON_USEDEP}]
|
||||
dev-python/xlsxwriter[${PYTHON_USEDEP}]
|
||||
)
|
||||
>=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
|
||||
dev-python/statsmodels[${PYTHON_USEDEP}]
|
||||
$(python_gen_cond_dep '
|
||||
>=dev-python/xarray-0.10.8[${PYTHON_USEDEP}]
|
||||
' python3_{6,7})
|
||||
>=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/xlrd-1.0.0[${PYTHON_USEDEP}]
|
||||
dev-python/xlwt[${PYTHON_USEDEP}]
|
||||
>=dev-python/scipy-1.1[${PYTHON_USEDEP}]
|
||||
X? (
|
||||
|| (
|
||||
dev-python/PyQt5[${PYTHON_USEDEP}]
|
||||
x11-misc/xclip
|
||||
x11-misc/xsel
|
||||
)
|
||||
)
|
||||
"
|
||||
COMMON_DEPEND="
|
||||
>dev-python/numpy-1.15.4[${PYTHON_USEDEP}]
|
||||
dev-python/python-dateutil[${PYTHON_USEDEP}]
|
||||
dev-python/pytz[${PYTHON_USEDEP}]
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-python/cython-0.29.21[${PYTHON_USEDEP}]
|
||||
doc? (
|
||||
${VIRTUALX_DEPEND}
|
||||
app-text/pandoc
|
||||
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
|
||||
dev-python/html5lib[${PYTHON_USEDEP}]
|
||||
dev-python/ipython[${PYTHON_USEDEP}]
|
||||
dev-python/lxml[${PYTHON_USEDEP}]
|
||||
dev-python/matplotlib[${PYTHON_USEDEP}]
|
||||
dev-python/nbsphinx[${PYTHON_USEDEP}]
|
||||
>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
|
||||
dev-python/pytz[${PYTHON_USEDEP}]
|
||||
dev-python/rpy[${PYTHON_USEDEP}]
|
||||
dev-python/sphinx[${PYTHON_USEDEP}]
|
||||
dev-python/xlrd[${PYTHON_USEDEP}]
|
||||
dev-python/xlwt[${PYTHON_USEDEP}]
|
||||
dev-python/scipy[${PYTHON_USEDEP}]
|
||||
x11-misc/xclip
|
||||
)
|
||||
test? (
|
||||
${VIRTUALX_DEPEND}
|
||||
${RECOMMENDED_DEPEND}
|
||||
${OPTIONAL_DEPEND}
|
||||
dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
|
||||
dev-python/hypothesis[${PYTHON_USEDEP}]
|
||||
dev-python/nose[${PYTHON_USEDEP}]
|
||||
dev-python/openpyxl[${PYTHON_USEDEP}]
|
||||
dev-python/pymysql[${PYTHON_USEDEP}]
|
||||
>=dev-python/pytest-5.1[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-mock[${PYTHON_USEDEP}]
|
||||
dev-python/pytest-xdist[${PYTHON_USEDEP}]
|
||||
dev-python/psycopg:2[${PYTHON_USEDEP}]
|
||||
dev-python/xlsxwriter[${PYTHON_USEDEP}]
|
||||
x11-misc/xclip
|
||||
x11-misc/xsel
|
||||
)
|
||||
"
|
||||
# dev-python/statsmodels invokes a circular dep
|
||||
# hence rm from doc? ( ), again
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
!minimal? ( ${RECOMMENDED_DEPEND} )
|
||||
full-support? ( ${OPTIONAL_DEPEND} )
|
||||
"
|
||||
|
||||
python_prepare_all() {
|
||||
# Prevent un-needed download during build
|
||||
sed -e "/^ 'sphinx.ext.intersphinx',/d" \
|
||||
-i doc/source/conf.py || die
|
||||
|
||||
# requires package installed
|
||||
sed -e '/extra_compile_args =/s:"-Werror"::' \
|
||||
-i setup.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_compile() {
|
||||
distutils-r1_python_compile -j1
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
# To build docs the need be located in $BUILD_DIR,
|
||||
# else PYTHONPATH points to unusable modules.
|
||||
if use doc; then
|
||||
cd "${BUILD_DIR}"/lib || die
|
||||
cp -ar "${S}"/doc . && cd doc || die
|
||||
LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
|
||||
fi
|
||||
}
|
||||
|
||||
src_test() {
|
||||
virtx distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local deselect=(
|
||||
# test for rounding errors, fails if we have better precision
|
||||
# e.g. on amd64 with FMA or on arm64
|
||||
# https://github.com/pandas-dev/pandas/issues/38921
|
||||
pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
|
||||
|
||||
# weird issue, doesn't seem very important
|
||||
'pandas/tests/base/test_misc.py::test_memory_usage[series-with-empty-index]'
|
||||
)
|
||||
|
||||
local -x LC_ALL=C.UTF-8
|
||||
pushd "${BUILD_DIR}"/lib > /dev/null || die
|
||||
"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
|
||||
PYTHONPATH=. pytest pandas -vv --skip-slow --skip-network \
|
||||
${deselect[@]/#/--deselect } \
|
||||
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" \
|
||||
-m "not single" || die "Tests failed with ${EPYTHON}"
|
||||
find . '(' -name .pytest_cache -o -name .hypothesis ')' \
|
||||
-exec rm -r {} + || die
|
||||
popd > /dev/null || die
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
if use doc; then
|
||||
dodoc -r "${BUILD_DIR}"/lib/doc/build/html
|
||||
einfo "An initial build of docs is absent of references to statsmodels"
|
||||
einfo "due to circular dependency. To have them included, emerge"
|
||||
einfo "statsmodels next and re-emerge pandas with USE doc"
|
||||
fi
|
||||
|
||||
distutils-r1_python_install_all
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
|
||||
optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
|
||||
optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
|
||||
optfeature "for msgpack compression using blosc" dev-python/blosc
|
||||
optfeature "Template engine for conditional HTML formatting" dev-python/jinja
|
||||
optfeature "Plotting support" dev-python/matplotlib
|
||||
optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-1.6.1" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
|
||||
optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.2.1"
|
||||
optfeature "R I/O support" dev-python/rpy
|
||||
optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
|
||||
optfeature "SQL database support" ">=dev-python/sqlalchemy-0.8.1"
|
||||
optfeature "miscellaneous statistical functions" dev-python/scipy
|
||||
optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/pygtk x11-misc/xclip x11-misc/xsel
|
||||
}
|
||||
Reference in New Issue
Block a user