dev-libs/libqtxdg: add 4.4.0

Closes: https://bugs.gentoo.org/957469
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>

dev-libs/libqtxdg/Manifest

@@ -1 +1,2 @@
 DIST libqtxdg-4.3.0.tar.xz 72784 BLAKE2B 5fd1a9fb0ebe245e048c93686c68bf5ebd4486181d0119138defa43f97b8a58ed8e8fbf8a33b458ef26cb43ded1a7226967a6284e110a73a372600418c32943f SHA512 10230ce8e09f061bcb3e5e9d82f57c0678d0a01c87d17f7943356d57e00ab89bbaca7d74f86a24ed94738ca2d507a4eb6a5a05a96d5e04c9214f314066fb468d
+DIST libqtxdg-4.4.0.tar.xz 75152 BLAKE2B 0a245f426eb731fc915a7179e79566f74b01edc54266b3468afba4a6b340b7eb8117f615b04734e1c40a49dd0d4905911a7e95f5fc48b9a83dafb9afb5ed157e SHA512 22806f5a9a4156ae5f1a0ec3b9818d03a63180c2da9420c919b86b76cb67b8f360b90740afa2d8d8ef58e6f48470960a054e1e71e689be4bead6cf4e21cb2df1

dev-libs/libqtxdg/libqtxdg-4.4.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake optfeature virtualx
+
+# The notice is triggered by an example file, which is unused here.
+# https://bugs.gentoo.org/951350
+CMAKE_QA_COMPAT_SKIP=1
+
+DESCRIPTION="Qt Implementation of XDG Standards"
+HOMEPAGE="
+	https://lxqt-project.org/
+	https://github.com/lxqt/libqtxdg/
+"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
+else
+	SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+fi
+
+LICENSE="LGPL-2.1+ Nokia-Qt-LGPL-Exception-1.1"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	>=dev-util/lxqt-build-tools-2.4.0
+	virtual/pkgconfig
+"
+RDEPEND="
+	dev-libs/glib:2
+	>=dev-qt/qtbase-6.6:6=[dbus,gui,widgets,xml]
+	>=dev-qt/qtsvg-6.6:6
+	x11-misc/xdg-utils
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Tests don't work with C
+	LC_ALL=en_US.UTF-8 virtx cmake_src_test
+}
+
+pkg_postinst() {
+	! has_version lxqt-base/lxqt-meta && optfeature "features that require a terminal emulator" x11-terms/xterm
+}