dev-build/dolphin-plugins-makefileactions: 26.04.0 version bump

Signed-off-by: Sam James <sam@gentoo.org>

dev-build/dolphin-plugins-makefileactions/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-25.12.3.tar.xz 337964 BLAKE2B ca59dcec606af363da0ffe6bba9de4165f94c738cb8249d0f2f93f294dbaa00a2d2a2a7bf739be01519a0f1faf868cad9ba87ea6447634c45814a2ab80c238b4 SHA512 e79f80cd17f1acb7a8160020625fa59a7983f7762c1c26c620cb856b87470cfede44fc7a0f1c14116b8fc237dfb0fa81e338bf41853bdce901b4015e47fc0b4d
+DIST dolphin-plugins-26.04.0.tar.xz 338228 BLAKE2B 6eed06690f59f422ea640bf41b60d98aafaa15d7b379f1f5d609fc972bcb956dfa6dd505b7f34b1ad82c1b2a09f15b3fe361e6cac13fc0b36896691fdc8b20c3 SHA512 0320a40fa40f15e4200277b27393db46f2601307fd4603183dfb7de6655bcd9b7faef30ceec6af927ee26bc4e53320662f9004e84b2f1656044cfdb77b94994d

dev-build/dolphin-plugins-makefileactions/dolphin-plugins-makefileactions-26.04.0.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="makefileactions"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.22.0
+QTMIN=6.10.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Makefile targets integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	!<kde-apps/dolphin-plugins-subversion-24.08.2-r1
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+	# kcompletion, ktextwidgets only required by other plugins
+	ecm_punt_kf_module Completion
+	ecm_punt_kf_module TextWidgets
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_git=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}