net-misc/xmrig: 6.18.0 version bump, EAPI=8

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Craig Andrews <candrews@gentoo.org>

net-misc/xmrig/Manifest

@@ -1,2 +1,3 @@
 DIST xmrig-6.16.4.tar.gz 2422895 BLAKE2B bdf4c2ee41b11a5a0d72518aadb71677536dee4ec80af191a337bddb9623e9ec8d0d3f5328732be6246eb08b28f845927ae611e2c8dc66d1b42f1c8f56a3451f SHA512 a66f5d8ef217a4ea31d65c03cc863be694947ce536ca66b0b66f523557fba1651accdc196b6ca1dbc34bd5688041248a3c30e9ee122394207f7e47d82d9e987d
 DIST xmrig-6.17.0.tar.gz 2443393 BLAKE2B 01fa7682dae6dd4aaa0f3b677bedfb3b2e9de35799f9bae0aa1a733b35152d1d6c56dfed06b9aa54fe64df4f40029d2657b9fc95e541746bd8e28bff15eef96b SHA512 a8361a5ccc8237afb59c496d88d920b7222158d9f874ff891f0cb78278e6e00881b75f4e129858c44ffc7d90227c995121f6611f1a20f84139930a883271f0d6
+DIST xmrig-6.18.0.tar.gz 2389032 BLAKE2B c7561e2d9303c80f97615471a28f57bc48c93749459e48451de52d1130b436298354a0419c3ed3c96f2bfe3592b7d28f85b91c7698174917d6eb08b685a12145 SHA512 ed20b760ae7603de752c933513c3f7abb2e254a44d79252264952f3e70c7b5320389ed4f6534a6dc8eb7cac8b1086239c46baf18c71f7ba7f0018914b2fd5917

net-misc/xmrig/xmrig-6.18.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake systemd
+
+DESCRIPTION="RandomX, CryptoNight, KawPow, AstroBWT, and Argon2 CPU/GPU miner"
+HOMEPAGE="https://xmrig.com https://github.com/xmrig/xmrig"
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+	inherit git-r3
+else
+	SRC_URI="https://github.com/xmrig/xmrig/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64"
+fi
+
+LICENSE="Apache-2.0 GPL-3+ MIT"
+SLOT="0"
+IUSE="cpu_flags_x86_sse4_1 donate hwloc opencl +ssl"
+
+DEPEND="
+	dev-libs/libuv:=
+	hwloc? ( >=sys-apps/hwloc-2.5.0:= )
+	opencl? ( virtual/opencl )
+	ssl? ( dev-libs/openssl:= )
+"
+RDEPEND="
+	${DEPEND}
+	!arm64? ( sys-apps/msr-tools )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-6.12.2-nonotls.patch
+)
+
+src_prepare() {
+	if ! use donate ; then
+		sed -i 's/1;/0;/g' src/donate.h || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+		-DWITH_HWLOC=$(usex hwloc)
+		-DWITH_TLS=$(usex ssl)
+		-DWITH_OPENCL=$(usex opencl)
+		-DWITH_CUDA=OFF
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	default
+	keepdir /etc/xmrig
+	systemd_dounit "${FILESDIR}"/xmrig.service
+	dobin "${BUILD_DIR}/xmrig"
+	dobin "${S}/scripts/enable_1gb_pages.sh"
+	dobin "${S}/scripts/randomx_boost.sh"
+}

net-misc/xmrig/xmrig-9999.ebuild

@@ -1,7 +1,7 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=7
+EAPI=8
 
 inherit cmake systemd