dev-python/astroid: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/astroid/Manifest

@@ -1,3 +1,2 @@
 DIST astroid-3.2.4.gh.tar.gz 465788 BLAKE2B 745a860b7bacb45cb86e9b232fe3a37cdac40cb471b00832a7dd7da4c3374760749cebe8c8688748e750cc3639554515a7a9e24f5f4d2ebac10af2c906fa04a9 SHA512 e48289794f67cf53bb8a2dcf357c1e892140a0a625c2e19601cf5ad579aaa33a94f0e052915fa6e854bc0a2e626f41b2d13773aa2b2af2412efeb33d030ed2b6
-DIST astroid-3.3.1.gh.tar.gz 464132 BLAKE2B 011b61777ce4f3900ed1c23a664b7ae0c16e364f61cd664078d78bf6a90097f423afe03579e151439a9b02874e2fa12844f0587632e1bf1f40b428d2d99cc6da SHA512 992f80c30fdb02d283e73d1329a58ddd10a4f800e74b4697086b194a329ff6ae7ae026c907317e9604371a60cb814f243f2506d921d196214f11741f098485c1
 DIST astroid-3.3.2.gh.tar.gz 464183 BLAKE2B a891a57ce697e539b865ead8f1a1a42aa57962d1ac3cb39624f3c8cac1a233ce5ed207a87f6b8ef0b2fcacc296610819d5612262a6fbfe08eed20a2955b168c4 SHA512 dc9777e701f0bf3dc5367da8e7c79eeba18f485ad1425f8e3e50814efef9f8fd0e11f30363d1c602cfd05c51b2b2e9749989da1413db59c9f648fbc47cfbc8ae

dev-python/astroid/astroid-3.3.1.ebuild

@@ -1,89 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( pypy3 python3_{10..13} )
-
-inherit distutils-r1
-
-DESCRIPTION="Abstract Syntax Tree for logilab packages"
-HOMEPAGE="
-	https://github.com/pylint-dev/astroid/
-	https://pypi.org/project/astroid/
-"
-SRC_URI="
-	https://github.com/pylint-dev/astroid/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
-
-# Version specified in pyproject.toml
-RDEPEND="
-	$(python_gen_cond_dep '
-		>=dev-python/typing-extensions-4.0.0[${PYTHON_USEDEP}]
-	' 3.10)
-"
-# dev-python/regex isn't available for pypy
-BDEPEND="
-	dev-python/setuptools-scm[${PYTHON_USEDEP}]
-	test? (
-		dev-python/attrs[${PYTHON_USEDEP}]
-		>=dev-python/numpy-1.17.0[${PYTHON_USEDEP}]
-		dev-python/python-dateutil[${PYTHON_USEDEP}]
-		$(python_gen_cond_dep '
-			dev-python/regex[${PYTHON_USEDEP}]
-		' 'python*')
-	)
-"
-
-distutils_enable_tests pytest
-
-export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# no clue why they're broken
-		tests/test_modutils.py::GetModulePartTest::test_known_values_get_builtin_module_part
-		tests/test_regrtest.py::NonRegressionTests::test_numpy_distutils
-		# pydantic-2?
-		tests/brain/test_dataclasses.py::test_pydantic_field
-		# requires urllib3 with bundled six (skipped with urllib3>=2)
-		tests/test_modutils.py::test_file_info_from_modpath__SixMetaPathImporter
-		# hangs
-		tests/test_nodes.py::AsStringTest::test_recursion_error_trapped
-		# TODO
-		tests/test_builder.py::BuilderTest::test_data_build_error_filename
-		# numpy-2 (https://github.com/pylint-dev/astroid/issues/2442)
-		tests/brain/numpy/test_core_einsumfunc.py::test_numpy_function_calls_inferred_as_ndarray
-		tests/brain/numpy/test_core_fromnumeric.py::BrainNumpyCoreFromNumericTest::test_numpy_function_calls_inferred_as_ndarray
-		tests/brain/numpy/test_core_multiarray.py::BrainNumpyCoreMultiarrayTest::test_numpy_function_calls_inferred_as_ndarray
-		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_datetime_astype_return
-		tests/brain/numpy/test_core_numerictypes.py::NumpyBrainCoreNumericTypesTest::test_generic_types_are_subscriptables
-		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type
-		tests/brain/numpy/test_core_umath.py::NumpyBrainCoreUmathTest::test_numpy_core_umath_functions_return_type_tuple
-	)
-
-	case ${EPYTHON} in
-		pypy3)
-			EPYTEST_DESELECT+=(
-				tests/test_transforms.py::TestTransforms::test_transform_aborted_if_recursion_limited
-			)
-			;;
-		python3.13)
-			EPYTEST_DESELECT+=(
-				# changes in py3.13.0b4
-				# https://github.com/pylint-dev/astroid/issues/2478
-				tests/test_nodes.py::AsStringTest::test_f_strings
-				tests/test_nodes_lineno.py::TestLinenoColOffset::test_end_lineno_string
-			)
-			;;
-	esac
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	epytest
-}