media-gfx/eog: Version bump to 3.38.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

media-gfx/eog/Manifest

@@ -1,3 +1,4 @@
 DIST eog-3.36.3.tar.xz 3651556 BLAKE2B 6224b21342b24bed8cfed5702c440547423a7c0db36278c082f336f274ebabea401700c418eafced814fb33043362963055acbcacc81edff8b0f202898c09542 SHA512 90205561dbc49aa42e60f636ce23d04dcd05513d28176ffa4c1dd6602889c4b2c920bd299086d3d7bfee72fcc6a029e2d34e14eb80ba5f91573161fbd1b85aea
 DIST eog-3.36.4.tar.xz 3651632 BLAKE2B f971ab236422a875ea8d91a661c6c653ba2ef4834b282dcce7d5c53e9c23bedf49610c0a8ff1bedb2af1821610ab29de8476a2b13b6cb1b82e58c3309b56b7dd SHA512 d1f4aa2e225a8147507cbed74a74bd435887884a2431f3ea0d1c569217a291f93c1440bede1c6abf03660ad8df46530e8b2195399ac8faaac36b1e31e8e93daf
 DIST eog-3.38.1.tar.xz 3655616 BLAKE2B 1e0265dc798413e9b2588c36879a526069bc3d8788339e97470d8d0b738e01cd2fc00bc3db118721fd45a40e5829e225d9451d4cf868e0c9a7bfd74cdc90c06d SHA512 26317413271001b4edcd30438e81a2bb1d2e10edd639c054ffdc08743a5274b27afb51186a660e29022be5e9ecf10043b94e7d409194589d2bba6906ede2cff9
+DIST eog-3.38.2.tar.xz 3614956 BLAKE2B ab442006b2eca1550d072c57af989e748f130b07088e724ccf8e2d6e6b2cf132e06ff2ff89d9333f6fa3cd701c27cdb616dabf125f14dc5a4d1b92d14a85be56 SHA512 f9af91a76b85b8e1250f3ecf04cfc30ae35892282fe65c810358d27cc7e0aac3cafe50dcf815c54c6056c24eb1107d6f5ecf8131f78559095cda5024d255ebe6

media-gfx/eog/eog-3.38.2.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=x11-misc/shared-mime-info-0.20
+	>=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+	>=x11-libs/gtk+-3.22.0:3[introspection,X]
+	sys-libs/zlib
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	lcms? ( media-libs/lcms:2 )
+	xmp? ( media-libs/exempi:2 )
+	jpeg? ( virtual/jpeg:0 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	svg? ( >=gnome-base/librsvg-2.44.0:2 )
+
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gtk-doc-1.16
+		app-text/docbook-xml-dtd:4.1.2 )
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif libexif)
+		$(meson_use lcms cms)
+		$(meson_use xmp)
+		$(meson_use jpeg libjpeg)
+		$(meson_use svg librsvg)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dinstalled_tests=false
+		-Dlibportal=false # Not packaged
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}