net-misc/icecast: Security bump to version 2.4.4

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

net-misc/icecast/Manifest

@@ -1 +1,2 @@
 DIST icecast-2.4.3.tar.gz 2393358 BLAKE2B a2b34eeb7c94974e13250620f9a19ed0165ec0cc676c5947edf8f88cea76240ab5eb90807d598c29944573c3717b8b7951261434521bc81100c3a6ba22d85840 SHA512 70e755ee935e738f2b7310333823992517747897692d101b67d73d5cd40d6385a20c25d089a0430806c116021e6e2055761efee9fec27cd9bccb2b58a2bfd446
+DIST icecast-2.4.4.tar.gz 2360592 BLAKE2B fd4034749feb4bf38c684ac6d8de572fdebce875843dc1be286264c8fe8d38feb24ea889b07ec79aada34cf16dae46eb21a8c5470f67c08f2dd56dc04c12130f SHA512 e9ffb478cac2570891787455591d881a59185e067bb36f51706a7070cd9d82d80425ec8cf151f5ebb17d1b75654449fc760f8b82a1bb05f020b47ec09e46b4d0

net-misc/icecast/icecast-2.4.4.ebuild

@@ -0,0 +1,95 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools systemd user
+
+DESCRIPTION="Opensource alternative to shoutcast that supports mp3, ogg and aac streaming"
+HOMEPAGE="http://www.icecast.org/"
+SRC_URI="http://downloads.xiph.org/releases/icecast/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~x86-fbsd"
+IUSE="kate libressl logrotate +speex +ssl +theora +yp"
+
+#Although there is a --with-ogg and --with-orbis configure option, they're
+#only useful for specifying paths, not for disabling.
+DEPEND="
+	dev-libs/libxml2
+	dev-libs/libxslt
+	media-libs/libogg
+	media-libs/libvorbis
+	kate? ( media-libs/libkate )
+	logrotate? ( app-admin/logrotate )
+	speex? ( media-libs/speex )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= )
+	)
+	theora? ( media-libs/libtheora )
+	yp? ( net-misc/curl )
+"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	# bug #368539
+	"${FILESDIR}"/${PN}-2.3.3-libkate.patch
+	# bug #430434
+	"${FILESDIR}"/${PN}-2.3.3-fix-xiph_openssl.patch
+)
+
+pkg_setup() {
+	enewuser icecast -1 -1 -1 nogroup
+}
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-dependency-tracking
+		--docdir=/usr/share/doc/${PF}
+		--sysconfdir=/etc/icecast2
+		$(use_enable kate)
+		$(use_enable yp)
+		$(use_with speex)
+		$(use_with ssl openssl)
+		$(use_with theora)
+		$(use_with yp curl)
+	)
+	econf "${myeconfsrgs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS README TODO HACKING NEWS conf/icecast.xml.dist
+	docinto html
+	dodoc doc/*.html
+
+	newinitd "${FILESDIR}"/${PN}.initd ${PN}
+	systemd_dounit "${FILESDIR}"/${PN}.service
+
+	insinto /etc/icecast2
+	doins "${FILESDIR}"/icecast.xml
+	fperms 600 /etc/icecast2/icecast.xml
+
+	if use logrotate; then
+		dodir /etc/logrotate.d
+		insopts -m0644
+		insinto /etc/logrotate.d
+		newins "${FILESDIR}"/${PN}.logrotate ${PN}
+	fi
+	diropts -m0764 -o icecast -g nogroup
+	dodir /var/log/icecast
+	keepdir /var/log/icecast
+	rm -r "${ED}"/usr/share/doc/icecast || die
+}
+
+pkg_postinst() {
+	touch "${ROOT}"/var/log/icecast/{access,error}.log
+	chown icecast:nogroup "${ROOT}"/var/log/icecast/{access,error}.log
+}