app-accessibility/at-spi2-core: add 2.56.4

Signed-off-by: Lukas Schmelting <lschmelting@posteo.com>
Part-of: https://github.com/gentoo/gentoo/pull/43527
Closes: https://github.com/gentoo/gentoo/pull/43527
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

app-accessibility/at-spi2-core/Manifest

@@ -1,2 +1,3 @@
 DIST at-spi2-core-2.54.1.tar.xz 576224 BLAKE2B b1a1657081f22623bba7730f687dc69e4b7c1562020edc42b29f0a8842ea8443021aab1b8fd23d75877c8023c43c586ce70640be42fef5663983381018e9e80b SHA512 28f94e745b2c563e7515207dc24da0658f68c2badd3085b15b14405e10e128ef776d674d840dfd8c2222bdb8fd88348a1a7e70df0bb19deed0e688d1c0c8b3c3
 DIST at-spi2-core-2.56.3.tar.xz 582176 BLAKE2B 524127c427d802180ebda0f9a683d22ac4849244eb67f5aa906f8694a63bd8501c0e302344b036eceeda6ae5d8db4069627fecee977bcc5c69b63a8925d9f161 SHA512 33ef0c384ef4c2b135d071934ed751deed0613b296eaf8005d205b441506ff975f74da7707c8033c255da312abc19b210135dda8aa8158a913fc298d77b80a2d
+DIST at-spi2-core-2.56.4.tar.xz 582412 BLAKE2B c82db9064fe92a5fbadfb290f5a4df8982c8307b62530f7b141dc6c169bbb2ff00c9e75dd00d5811ff321636eb38b05ec5d0a0a3a5a13c4001b728c3043f37d6 SHA512 dedf45876d055b56088cc196639e67a0bbb8107882925939562c53bd851e5d7e98b71d4ef560d10b61092f2ac9c0df8fc255438da35141efa161888c2b612341

app-accessibility/at-spi2-core/at-spi2-core-2.56.4.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org meson-multilib systemd virtualx xdg
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/at-spi2-core"
+
+LICENSE="LGPL-2.1+"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos"
+IUSE="X dbus-broker gtk-doc +introspection systemd"
+REQUIRED_USE="
+	dbus-broker? ( systemd )
+	gtk-doc? ( X )
+"
+
+DEPEND="
+	>=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.67.4:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1:2=[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-1.54.0:= )
+	systemd? ( sys-apps/systemd[${MULTILIB_USEDEP}] )
+	X? (
+		x11-libs/libX11[${MULTILIB_USEDEP}]
+		x11-libs/libXtst[${MULTILIB_USEDEP}]
+		x11-libs/libXi[${MULTILIB_USEDEP}]
+	)
+
+	!<dev-libs/atk-2.46.0
+	!<app-accessibility/at-spi2-atk-2.46.0
+"
+RDEPEND="${DEPEND}
+	dbus-broker? ( sys-apps/dbus-broker )
+"
+BDEPEND="
+	dev-util/glib-utils
+	gtk-doc? (
+		dev-python/sphinx
+		dev-util/gdbus-codegen
+		>=dev-util/gi-docgen-2021.1
+	)
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+multilib_src_configure() {
+	local emesonargs=(
+		-Ddefault_bus=$(usex dbus-broker dbus-broker dbus-daemon)
+		$(meson_use systemd use_systemd)
+		-Dgtk2_atk_adaptor=true
+		-Dsystemd_user_dir="$(systemd_get_userunitdir)"
+		$(meson_native_use_bool gtk-doc docs)
+		$(meson_native_use_feature introspection)
+		$(meson_feature X x11)
+		-Datk_only=false
+	)
+	meson_src_configure
+}
+
+multilib_src_test() {
+	# Avoid locates using commas as decimal separators and breaking some
+	# tests
+	LC_ALL=C.UTF-8 virtx dbus-run-session meson test -C "${BUILD_DIR}" || die
+}
+
+multilib_src_install_all() {
+	einstalldocs
+
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/{libatspi,atk} || die
+		mv "${ED}"/usr/share/doc/libatspi "${ED}"/usr/share/gtk-doc/libatspi/html || die
+		mv "${ED}"/usr/share/doc/atk "${ED}"/usr/share/gtk-doc/atk/html || die
+	fi
+}