dev-util/pkgdev: add 0.2.4

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-util/pkgdev/Manifest

@@ -1 +1,2 @@
 DIST pkgdev-0.2.3.tar.gz 67292 BLAKE2B 8e4195c1094200836e23f97ed8ddf44659dcbe123180b253bf961fc08f2534d3573c7194302b3dbe866b45a548e63951ef63d4fce77c4d0903c34a0f4ece9c0b SHA512 ea09483fff8d64ed2a53ab3435bf01be172f1ef6fcbcfa5eac2f19104fdd20cd57f045f578db896c92689f4e6e36acfa4ae4feb28424b5566041fc0e1d5ccb05
+DIST pkgdev-0.2.4.tar.gz 64156 BLAKE2B 321e14b246a97236142a862968bfc127f3215314ef173dc0d610ca867d00a0db067def7810083b11bf6aea1e36202e6c91d7c63d74aa2b85fb17ec476cba1f7c SHA512 0390e130abda2f8eea1d3dd029d31d9381f2543ca98f547b91716ce383791c3760bd89bb276b5b15eaaa165be339c8147d26e93ba81d5be4c8a4cbede6a31caf

dev-util/pkgdev/pkgdev-0.2.4.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgdev.git
+		https://github.com/pkgcore/pkgdev.git"
+	inherit git-r3
+else
+	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Collection of tools for Gentoo development"
+HOMEPAGE="https://github.com/pkgcore/pkgdev"
+
+LICENSE="BSD MIT"
+SLOT="0"
+
+if [[ ${PV} == *9999 ]] ; then
+	RDEPEND="
+		~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		~dev-util/pkgcheck-9999[${PYTHON_USEDEP}]
+		~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]
+	"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.10.3[${PYTHON_USEDEP}]
+		>=dev-util/pkgcheck-0.10.16[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.12.16[${PYTHON_USEDEP}]
+	"
+fi
+
+RDEPEND+="
+	dev-vcs/git
+"
+BDEPEND="
+	>=dev-python/flit_core-3.8[${PYTHON_USEDEP}]
+	test? (
+		x11-misc/xdg-utils
+	)
+"
+
+distutils_enable_sphinx doc \
+	">=dev-python/snakeoil-0.10.3" \
+	dev-python/tomli
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake PYTHON="${EPYTHON}" man
+
+	sphinx_compile_all # HTML pages only
+}
+
+python_install_all() {
+	# If USE=doc, there'll be newly generated docs which we install instead.
+	if use doc || [[ ${PV} != *9999 ]]; then
+		doman build/sphinx/man/*
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "sending email support" x11-misc/xdg-utils
+}