kde-apps/lokalize: 24.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/lokalize/Manifest

@@ -1,2 +1,3 @@
 DIST lokalize-24.05.2.tar.xz 2076256 BLAKE2B 3a750865e167796fada9ce6fd3919b63a48c3d90e3ac982541fd59bee7cfba574926351141280db6684ef7bf263348ae2f83f6b0902d0ccc1d96763976af9df3 SHA512 518a32a1d61b768470d19d10b8348b0a91cb4355400cf2356309a36642fccb79586360c07a9afb3bf33152a928fff4bb2dcfc1226deb01bcaca91ae273e50253
 DIST lokalize-24.08.0.tar.xz 2040812 BLAKE2B 34ebd443d6f34eb09efbcdcc775bafbe08a357a21f14bc924d287b93f4d13a558d623df23898fb55f8784503426e947060a8f3a519cef05ae3e9148c2e517b4a SHA512 ecd2f5de46035d89c615776430068f2cff35c289dfc1d965463577d7f6fa7d8dbdfeddede3a9779432717587b33c8003b4b9e9a3d750ddc057dc35b1d6049d95
+DIST lokalize-24.08.1.tar.xz 2047108 BLAKE2B 2e6e16514273c27c6ce3dba633e4d32497c2bfdc07ccc30545ba9e1f1b3f182505691d162225c0b11ca9f579dfb91825ad2b6420378d542f688b29ba6823d66e SHA512 ea62d4ae57957f99e8afa00efda09491380e9e63c2d91582b3e017ed1fe5f675ff1d4c71804dbf60b1efe2519e15d61fced396fe910314a2e87197cb0d32d29e

kde-apps/lokalize/lokalize-24.08.1.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..12} )
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit python-single-r1 ecm gear.kde.org optfeature
+
+DESCRIPTION="Localization tool for KDE software and other free and open source software"
+HOMEPAGE="https://apps.kde.org/lokalize/ https://l10n.kde.org/tools/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+RESTRICT="test" # tests are broken, bug 739734
+
+DEPEND="${PYTHON_DEPS}
+	>=app-text/hunspell-1.2.8:=
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,sql,widgets,xml]
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kparts-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/sonnet-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	$(python_gen_cond_dep '
+		dev-python/translate-toolkit[${PYTHON_USEDEP}]
+	')
+"
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_install() {
+	ecm_src_install
+	rm "${ED}"/usr/share/lokalize/scripts/msgmerge.{py,rc} || die
+	python_fix_shebang "${ED}"/usr/share/${PN}
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "autofetch kde.org translations in new project wizard" dev-vcs/subversion
+		optfeature "spell and grammar checking" app-text/languagetool
+	fi
+	ecm_pkg_postinst
+}