dev-python/requests-cache: Bump to 1.3.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/requests-cache/Manifest

@@ -1 +1,2 @@
 DIST requests-cache-1.3.2.gh.tar.gz 1827145 BLAKE2B 360ecabd8149071578ebb0f0dfef00040b64d2714e6f92c3c47027cfca7802627f0e7bd84a16b7dc04158424dc9037860d02c6b462047c63c0a4bf82ec5fa327 SHA512 4acbb40180bab12c684370dfcbca9049fc2ee4766624b9d85fc88cfdf03a6f24f577bb167e2ab78134e76ac73009605887d8d5fdb258f193f6066f86226817a4
+DIST requests-cache-1.3.3.gh.tar.gz 1829373 BLAKE2B 71f0edd6019dd6cdf690967d6aaf8199759cf6aa85688257da66f2f7e3e559d8619f2e105cfbdfb93df1caf7b07d9a9e5a4b7dfe48eff052c9e40f70f69d59a2 SHA512 61e9570295e1c6351a1c65afe2b693be47f76951aacb1a1ef9852f45214738c459de90fa14109f9322dd3d77f9b52ad0f98b741cdb9b3cb57a339a91549f02ac

dev-python/requests-cache/requests-cache-1.3.3.ebuild

@@ -0,0 +1,87 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+# TODO: see if we can remove pypy3.11, because of the segfaults
+PYTHON_COMPAT=( python3_{12..14} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Persistent cache for requests library"
+HOMEPAGE="
+	https://pypi.org/project/requests-cache/
+	https://github.com/requests-cache/requests-cache/
+"
+SRC_URI="
+	https://github.com/requests-cache/requests-cache/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-21.2[${PYTHON_USEDEP}]
+	>=dev-python/cattrs-22.2[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2.5[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.22[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-1.25.5[${PYTHON_USEDEP}]
+	>=dev-python/url-normalize-2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/itsdangerous[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		>=dev-python/rich-10.0[${PYTHON_USEDEP}]
+		>=dev-python/ujson-5.4[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/time-machine[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-httpbin requests-mock )
+: ${EPYTEST_TIMEOUT:=60}
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# These require extra servers running
+		tests/integration/test_dynamodb.py
+		tests/integration/test_gridfs.py
+		tests/integration/test_mongodb.py
+		tests/integration/test_redis.py
+	)
+	local EPYTEST_DESELECT=(
+		# Requires Internet access
+		tests/integration/test_upgrade.py::test_version_upgrade
+	)
+
+	case ${EPYTHON} in
+		pypy3*)
+			EPYTEST_DESELECT+=(
+				# "database is locked", upstream probably relies on GC
+				# too much
+				tests/integration/test_sqlite.py
+				# random segfaults
+				tests/integration/test_filesystem.py
+			)
+			;;
+	esac
+
+	local -x USE_PYTEST_HTTPBIN=true
+	epytest
+}
+
+pkg_postinst() {
+	optfeature "redis backend" "dev-python/redis"
+	optfeature "MongoDB backend" "dev-python/pymongo"
+
+	optfeature "JSON serialization" "dev-python/ujson"
+	optfeature "YAML serialization" "dev-python/pyyaml"
+	optfeature "signing serialized data" "dev-python/itsdangerous"
+}