gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-25 07:08:13 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/python-language-server: version bump 0.35.0

Browse Source 
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@riseup.net>
Signed-off-by: Matt Turner <mattst88@gentoo.org>
This commit is contained in:
Andrew Ammerlaan
2020-09-11 19:12:21 +02:00
committed by Matt Turner
parent a3df81bab8
commit 8a5c12726c
2 changed files with 75 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/python-language-server/Manifest
View File

@@ -1 +1,2 @@
DIST python-language-server-0.34.1.tar.gz 70238 BLAKE2B 55ec41875907bb6c09f682c8ce6165e7e2fab5d03c3d4758bcbe658968aeeee7f0316a472efe68ddd87872b0e2d34908c8a7e9528aa5eec6d3359b2565a2cbbc SHA512 12404753f4271ec3606cee535ba8e886037bf0c61cc5c4415358066be837e2248f6393124340551387cba7351dee924b4f5ebc9c4e35b1ab0943067968967a90
DIST python-language-server-0.35.1.tar.gz 72944 BLAKE2B fe469e5365dec4a2192a2ca2f75fc9f05476434c0f6db26d851521149053455b256678ed98c5f1209d30b262808b615a3f7ac77fb604adf1455203e40f93c96f SHA512 278f281c8c82729ad60db2785b3f4b64568de529edb7a6f1b5683d09838ea43ed79182c50e42210e766b9a3f3c10b0c0256121b9925803c45f9e948f144ca994

74
dev-python/python-language-server/python-language-server-0.35.1.ebuild Normal file
View File

@@ -0,0 +1,74 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7,8} )
DISTUTILS_USE_SETUPTOOLS=rdepend
inherit distutils-r1 optfeature
DESCRIPTION="An implementation of the Language Server Protocol for Python"
HOMEPAGE="https://github.com/palantir/python-language-server"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
BDEPEND="dev-python/versioneer[${PYTHON_USEDEP}]
test? (
dev-python/autopep8[${PYTHON_USEDEP}]
dev-python/flaky[${PYTHON_USEDEP}]
>=dev-python/flake8-3.8.0[${PYTHON_USEDEP}]
dev-python/matplotlib[${PYTHON_USEDEP}]
>=dev-python/mccabe-0.6.0[${PYTHON_USEDEP}]
<dev-python/mccabe-0.7.0[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pandas[${PYTHON_USEDEP}]
>=dev-python/pycodestyle-2.6.0[${PYTHON_USEDEP}]
<dev-python/pycodestyle-2.7.0[${PYTHON_USEDEP}]
>=dev-python/pydocstyle-2.0.0[${PYTHON_USEDEP}]
>=dev-python/pyflakes-2.2.0[${PYTHON_USEDEP}]
<dev-python/pyflakes-2.3.0[${PYTHON_USEDEP}]
>=dev-python/pylint-2.5.0[${PYTHON_USEDEP}]
dev-python/QtPy[gui,testlib,${PYTHON_USEDEP}]
>=dev-python/rope-0.10.5[${PYTHON_USEDEP}]
dev-python/yapf[${PYTHON_USEDEP}]
)"
RDEPEND="
>=dev-python/jedi-0.17.0[${PYTHON_USEDEP}]
<dev-python/jedi-0.18.0[${PYTHON_USEDEP}]
dev-python/pluggy[${PYTHON_USEDEP}]
>=dev-python/python-jsonrpc-server-0.4.0[${PYTHON_USEDEP}]
~dev-python/ujson-1.35[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
python_prepare_all() {
# remove pytest-cov dep
sed -i -e '0,/addopts/I!d' setup.cfg || die
# jsonrpc-server does not actually work with ujson>3.0.0: test fail
sed -i -e 's/ujson>=3.0.0/ujson==1.35/g' setup.py || die
sed -i -e 's/ujson>=3.0.0/ujson==1.35/g' python_language_server.egg-info/requires.txt || die
distutils-r1_python_prepare_all
}
pkg_postinst() {
elog "To get additional features, optional runtime dependencies may be installed:"
optfeature "Automatically formats Python code to conform to the PEP 8 style guide" dev-python/autopep8
optfeature "A wrapper around PyFlakes, pep8 & mccabe" dev-python/flake8
optfeature "flake8 plugin: McCabe complexity checker" dev-python/mccabe
optfeature "Python style guide checker (fka pep8)" dev-python/pycodestyle
optfeature "Python docstring style checker" dev-python/pydocstyle
optfeature "Passive checker for Python programs" dev-python/pyflakes
optfeature "Python code static checker" dev-python/pylint
optfeature "Python refactoring library" dev-python/rope
optfeature "A formatter for Python files" dev-python/yapf
}