dev-python/pyarrow: Bump to 12.0.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/pyarrow/Manifest

@@ -1 +1,2 @@
 DIST apache-arrow-12.0.0.tar.gz 20159048 BLAKE2B 43b4f36e1d1f84fc83c46a3627ad72cead38310f4325b8d21d17d726cd416016f0839d312c80737c0a921da6aefee537413e30309a656301c19834c2986d734e SHA512 f815be4fb20b6001ba5525270765fe239b5468708a7be34b93b60ee0ce63464727d183c9756fbc33bffd199019e1f06a7fddd306ce8388435cea7771070a2ca9
+DIST apache-arrow-12.0.1.tar.gz 20172604 BLAKE2B bf66761d33ceb778c2f53c2e643e0c2bb4448f29eaa94d17e9815628665f4965fde28bd47fce4a5874717d2161c3f8adbb2e8a0e6658a51ae6d617e4f09d202b SHA512 551ae200551fcc73b7deddcc5f0b06633159ab1308506901a9086e4e2e34e4437f26d609fdbacba0ebe7d1fe83bdb8e92a268e9e41575d655d5b2d4fbef7a7ce

dev-python/pyarrow/pyarrow-12.0.1.ebuild

@@ -0,0 +1,71 @@
+# Copyright 2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 multiprocessing
+
+DESCRIPTION="Python library for Apache Arrow"
+HOMEPAGE="
+	https://pypi.org/project/pyarrow/
+	https://arrow.apache.org/
+"
+SRC_URI="mirror://apache/arrow/arrow-${PV}/apache-arrow-${PV}.tar.gz"
+S="${WORKDIR}/apache-arrow-${PV}/python"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="parquet snappy ssl"
+
+RDEPEND="
+	~dev-libs/apache-arrow-${PV}[compute,dataset,json,parquet?,re2,snappy?,ssl?]
+	dev-python/numpy[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		<dev-python/pandas-2[${PYTHON_USEDEP}]
+		dev-python/pytest-lazy-fixture[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# wtf?
+	tests/test_fs.py::test_localfs_errors
+	# these require apache-arrow with jemalloc that doesn't seem
+	# to be supported by the Gentoo package
+	tests/test_memory.py::test_env_var
+	tests/test_memory.py::test_specific_memory_pools
+	tests/test_memory.py::test_supported_memory_backends
+)
+
+src_compile() {
+	export PYARROW_PARALLEL="$(makeopts_jobs)"
+	export PYARROW_BUILD_VERBOSE=1
+	export PYARROW_CXXFLAGS="${CXXFLAGS}"
+	export PYARROW_BUNDLE_ARROW_CPP_HEADERS=0
+	export PYARROW_CMAKE_GENERATOR=Ninja
+	export PYARROW_WITH_HDFS=1
+	if use parquet; then
+		export PYARROW_WITH_DATASET=1
+		export PYARROW_WITH_PARQUET=1
+		use ssl && export PYARROW_WITH_PARQUET_ENCRYPTION=1
+	fi
+	if use snappy; then
+		export PYARROW_WITH_SNAPPY=1
+	fi
+
+	distutils-r1_src_compile
+}
+
+python_test() {
+	cd "${T}" || die
+	epytest --pyargs pyarrow
+}