www-client/opera-developer: Version 66.0.3502.0

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Jeroen Roovers <jer@gentoo.org>

www-client/opera-developer/Manifest

@@ -1,2 +1,3 @@
 DIST opera-developer_66.0.3489.0_amd64.deb 68148646 BLAKE2B 67c00f9e23a64f63ce749ddf774e498673db9e44c7fcd4d93850ee9bab1627241997c49f67d0f5e365d2c2bd23a7c458fee83e85b597ddfe7610b54918d2f9e7 SHA512 0474d86f9b37c42841aa228f359f11dc3fd988593f66f5a6074f62fcbb3615c2100b91880f494ae6372c92accc33e6ad59c679e534caeb9d1573fa1a0c9f6361
 DIST opera-developer_66.0.3494.0_amd64.deb 68188132 BLAKE2B 0669dba7747356dcaf4a62638b593ea6be6ce39ed9e05013f153379586f82bcafea5adad494a0bb587b4bc998f4a3a6a0eac0678aaf6352a7bfee198ad1a8f40 SHA512 18d6b7e71159a44ffc5b79de6608c706e46cd910d78e5a37b915d7145562803f7d679901df2383f314e12233d43c10bd50e26792ccfd600df7790caab6435fe5
+DIST opera-developer_66.0.3502.0_amd64.deb 67053024 BLAKE2B 42b2b344a2a3c0c111cdab18ac7b86431b77cb488ce109018ff6e8bdc61975105ce39ca447cee7f23c3bbcfe65fa238fe900ec83c863d79c53db4cd57bde810c SHA512 5e27254a3b0b4cceb7febd8b3e3d7af9568a3ce75a2d901502cc0fe20bef6d1a2f63a8d3951fce8ab3de6563893e64bd31b6703ee7767942d66e6c07ee38a9d2

www-client/opera-developer/opera-developer-66.0.3502.0.ebuild

@@ -0,0 +1,115 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB es es-419 fi fil fr fr-CA hi hr hu id it
+	ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+inherit chromium-2 multilib unpacker xdg-utils
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2014"
+SLOT="0"
+SRC_URI_BASE="
+	https://download1.operacdn.com/pub/
+	https://download2.operacdn.com/pub/
+	https://download3.operacdn.com/pub/
+	https://download4.operacdn.com/pub/
+"
+SRC_URI="amd64? ("
+for uri in ${SRC_URI_BASE}; do
+SRC_URI+="
+	"${uri}${PN}/${PV}/linux/${PN}_${PV}_amd64.deb"
+"
+done
+SRC_URI+=")"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gconf:2
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/freetype
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXi
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/libnotify
+	x11-libs/pango[X]
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+
+src_unpack() {
+	unpack_deb ${A}
+}
+
+pkg_setup() {
+	OPERA_HOME="usr/$(get_libdir)/${PN}"
+}
+
+src_prepare() {
+	default
+
+	case ${ARCH} in
+		amd64)
+			mv usr/lib/x86_64-linux-gnu usr/$(get_libdir) || die
+			rm -r usr/lib || die
+			;;
+		x86)
+			mv usr/lib/i386-linux-gnu/${PN} usr/$(get_libdir)/ || die
+			;;
+	esac
+
+	mv usr/share/doc/${PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	rm usr/bin/${PN} || die
+
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+}
+
+src_install() {
+	mv * "${D}" || die
+	dosym ../$(get_libdir)/${PN}/${PN} /usr/bin/${PN}
+	fperms 4711 /usr/$(get_libdir)/${PN}/opera_sandbox
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}