gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-05-01 05:08:10 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/aesara: Bump to 2.7.8

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2022-07-21 19:13:28 +02:00
parent 09786ab56c
commit 894a9ab413
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 97 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/aesara/Manifest
View File

@ -2,3 +2,4 @@ DIST aesara-rel-2.7.3.gh.tar.gz 7918433 BLAKE2B 5f0eaa5cb241db3fb59bfd5fda056681
DIST aesara-rel-2.7.5.gh.tar.gz 7920343 BLAKE2B 04f7c1cf587799b915a54067a98608cee49de8ab8a50c6d8434aa7ad6bd27b547f9e4a4f71d459d8fca9805f97232a9ba4a1beb5240a8e89dd19f807da2b2957 SHA512 c68dc6e2893d2749d6ec3a74b850979f0766ac65c34bf07af3c0f1a16874e44f5102e1d036a88a7a43f51a44d3fffd65babf67373982362b034a2410124d4aad
DIST aesara-rel-2.7.6.gh.tar.gz 7917317 BLAKE2B 21f801bebfe207586482b7eddb2fb1a2d812cb7c9bb28f2a7bc96543dabbe7ea7aa16781636d9e52d8abd389c8c148b3ae16696214d2914b702bb9dce114f149 SHA512 719d6ded6a058b739b3f2dcd734ef785b05eb07dec152c523d2ace7c5e9dd05d1550113f10e114b63b72d3a697900763c6f1e753db9c8d01a6c877fc5d3c2732
DIST aesara-rel-2.7.7.gh.tar.gz 7918070 BLAKE2B 70a48fdeac8be6c070850294101aa379652f26c2ff7c9723232d6aea31b3aa52675299c2f85fb6e1b5a4c5dfc020f12d72bf1e8b5ddc1d487e750c2ad7583d8c SHA512 2a1e4488aab1dbef71537871cc9a2060d4e760a1b4dfc74ed1d4d2b2acf6a030c4ee27c9f464934219630eaffde4431571a4424bf27f6ee53a80b7bfc1fdfa2b
DIST aesara-rel-2.7.8.gh.tar.gz 7918625 BLAKE2B 89f600e6b053526b8a214246746138066e2937633e132e68eef52e5dffa33509d4eee48f513077128e865f265a4e4b0ebe727dce5ed699c3f445b6850966c3c5 SHA512 33d57a5679480176cd814f6f5a36dc83ab0fe5f704a60ced2beceb10a4684bba7464f0d9473adc65541b755d3a5850af61d5ac8d8303f31d9c6718109ee331e1

96
dev-python/aesara/aesara-2.7.8.ebuild Normal file
View File

@ -0,0 +1,96 @@
# Copyright 2021-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{8..10} )
inherit distutils-r1 multiprocessing optfeature
MY_P=aesara-rel-${PV}
DESCRIPTION="Library for operating on mathematical expressions with multi-dimensional arrays"
HOMEPAGE="
https://github.com/aesara-devs/aesara/
https://pypi.org/project/aesara/
"
SRC_URI="
https://github.com/aesara-devs/aesara/archive/rel-${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
RDEPEND="
dev-python/cons[${PYTHON_USEDEP}]
dev-python/etuples[${PYTHON_USEDEP}]
dev-python/logical-unification[${PYTHON_USEDEP}]
dev-python/minikanren[${PYTHON_USEDEP}]
dev-python/filelock[${PYTHON_USEDEP}]
<dev-python/numpy-1.23[${PYTHON_USEDEP}]
dev-python/six[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
>=dev-python/setuptools-45[${PYTHON_USEDEP}]
dev-python/typing-extensions[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
PATCHES=(
"${FILESDIR}"/aesara-2.6.5-compiledir-tid.patch
)
distutils_enable_sphinx doc 'dev-python/sphinx_rtd_theme'
distutils_enable_tests pytest
python_test() {
local EPYTEST_DESELECT=(
# speed tests are unreliable
tests/scan/test_basic.py::test_speed
tests/scan/test_basic.py::test_speed_rnn
tests/scan/test_basic.py::test_speed_batchrnn
tests/link/test_vm.py::test_speed
tests/link/test_vm.py::test_speed_lazy
tests/tensor/test_gc.py::test_merge_opt_runtime
# rounding problem?
# https://github.com/aesara-devs/aesara/issues/477
tests/tensor/test_math_scipy.py::TestGammaUBroadcast::test_good
tests/tensor/test_math_scipy.py::TestGammaUInplaceBroadcast::test_good
# dunno
'tests/tensor/test_elemwise.py::TestDimShuffle::test_memory_leak[False]'
)
local EPYTEST_IGNORE=(
# we do not package numba
tests/link/test_numba.py
tests/link/test_numba_performance.py
# ..or jax
tests/link/test_jax.py
)
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x AESARA_FLAGS="cxx=${CXX}"
AESARA_FLAGS+=",config.gcc__cxxflags=\"${CXXFLAGS}\""
AESARA_FLAGS+=',compiledir_format="compiledir_%(thread_id)s"'
epytest -p xdist.plugin -n "$(makeopts_jobs)"
# clean up the compiledir, as it can grow pretty large
rm -r "${HOME}"/.aesara || die
}
python_compile() {
distutils-r1_python_compile
rm "${BUILD_DIR}/install$(python_get_sitedir)/bin/__init__.py" || die
}
pkg_postinst() {
optfeature "GPU code generation/execution on NVIDIA gpus" dev-util/nvidia-cuda-toolkit dev-util/nvidia-cuda-sdk
optfeature "GPU/CPU code generation on CUDA and OpenCL devices" dev-libs/libgpuarray dev-python/pycuda
}