dev-ada/gnatcoll-core: version bump to 2020

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ada/gnatcoll-core/Manifest

@@ -1 +1,2 @@
 DIST gnatcoll-core-2019-20190515-24AD8-src.tar.gz 1423276 BLAKE2B 154b7a7f77c1f0d6414cb407958d64b84be8d19b7e3a12f69bd3dd1253b71df394aa0c842d2caf9d2de071ea5466589111526329155291f0d967c8b4cc2b18ac SHA512 9b2101448b96ac46cebada1fe3cb7b583cbf296f9b7d627771e83c56c78ce72c50ede5474f64f16feba252a18fd46b473901820766902b0c68d63beaf55a884a
+DIST gnatcoll-core-2020-20200429-19B7C-src.tar.gz 1396475 BLAKE2B 329e7f799ad62dfc6f71ca78a736bfc8c768a576f817d03b0d73e25b6e97ae0de0ad5a055bb800f7b83d7449ef8fe703c2779f73fc13a09bbcc1d3d8cc880fd1 SHA512 320878335f2ea1ce91a7770cc181e9cc228c80b1f7a3926a4e27c3822eb8f58726c62a014e2fa4c3f8699851ea87424be26d619ab4931b2e969e3a2e96e58b73

dev-ada/gnatcoll-core/gnatcoll-core-2020.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+ADA_COMPAT=( gnat_201{6,7,8,9} )
+inherit ada multiprocessing
+
+MYP=${P}-20200429-19B7C
+
+DESCRIPTION="GNAT Component Collection Core packages"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="https://community.download.adacore.com/v1/c94f2ac914cb305f6bef174329fa0b5003d84935?filename=${MYP}-src.tar.gz
+	-> ${MYP}-src.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs static-pic"
+
+RDEPEND="
+	>=dev-ada/libgpr-2020[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}-src
+
+PATCHES=( "${FILESDIR}"/${PN}-2018-gentoo.patch )
+
+src_prepare() {
+	default
+	sed -i \
+		-e "s:@GNATLS@:${GNATLS}:g" \
+		src/gnatcoll-projects.ads \
+		|| die
+}
+
+src_configure() {
+	emake prefix="${D}"/usr PROCESSORS=$(makeopts_jobs) setup
+}
+
+src_compile() {
+	build () {
+		gprbuild -p -m -j$(makeopts_jobs) \
+			-XBUILD=PROD -v -XGNATCOLL_VERSION=${PV} \
+			-XLIBRARY_TYPE=$1 -XXMLADA_BUILD=$* -XGPR_BUILD=$1 \
+			gnatcoll.gpr -cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} || die
+	}
+	if use shared; then
+		build relocatable
+	fi
+	if use static-pic; then
+		build static-pic
+	fi
+	if use static-libs; then
+		build static
+	fi
+}
+
+src_install() {
+	if use shared; then
+		emake install-relocatable
+	fi
+	if use static-pic; then
+		emake install-static-pic
+	fi
+	if use static-libs; then
+		emake install-static
+	fi
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}