dev-util/pkgdev: add 0.2.7

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-util/pkgdev/Manifest

@@ -1 +1,2 @@
 DIST pkgdev-0.2.5.tar.gz 76886 BLAKE2B c1f5789ab7d9ef425d5fe444e046e0f9df8c5725e663177f997e9e8849b95af9a3ad022bf474791eba37b74e369028471187cf2b2d62aea0a1246e8d6cfa4a39 SHA512 29a271b92e9272428f28b7a4530fe8cb1e392b5c9ef46dbd98ac130e4ec01eb8f584ca297a7dd3bc4dded9713823dafd8dc0b722d066d6360befd6637388284f
+DIST pkgdev-0.2.7.tar.gz 77938 BLAKE2B 86cd05dad2e2c9fdea4a27cb804224ede75d84c3b7558ee42946ef38fcb2efbe7660951bb83047a9b48354b0d25638c8afcd760226c6a3af9ba61b299a98e3ee SHA512 0103245a4c79af80af9eeaa634cb244c4ca0ddfcc07534821dbc9300a0c406296820a0afd77e837548c6ed5954723d01778ce0d63987642043a79df4a54efb91

dev-util/pkgdev/pkgdev-0.2.7.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{9..11} )
+inherit distutils-r1 optfeature
+
+if [[ ${PV} == *9999 ]] ; then
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgdev.git
+		https://github.com/pkgcore/pkgdev.git"
+	inherit git-r3
+else
+	inherit pypi
+	KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~x64-macos"
+fi
+
+DESCRIPTION="Collection of tools for Gentoo development"
+HOMEPAGE="https://github.com/pkgcore/pkgdev"
+
+LICENSE="BSD MIT"
+SLOT="0"
+IUSE="doc"
+
+if [[ ${PV} == *9999 ]] ; then
+	RDEPEND="
+		~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
+		~dev-util/pkgcheck-9999[${PYTHON_USEDEP}]
+		~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]
+	"
+else
+	RDEPEND="
+		>=dev-python/snakeoil-0.10.4[${PYTHON_USEDEP}]
+		>=sys-apps/pkgcore-0.12.16[${PYTHON_USEDEP}]
+		>=dev-util/pkgcheck-0.10.16[${PYTHON_USEDEP}]
+	"
+fi
+
+RDEPEND+="
+	dev-vcs/git
+"
+BDEPEND="
+	>=dev-python/flit_core-3.8[${PYTHON_USEDEP}]
+	>=dev-python/snakeoil-0.10.4[${PYTHON_USEDEP}]
+	test? (
+		x11-misc/xdg-utils
+	)
+"
+
+distutils_enable_sphinx doc \
+	">=dev-python/snakeoil-0.10.3" \
+	dev-python/tomli
+distutils_enable_tests pytest
+
+python_compile_all() {
+	use doc && emake PYTHON="${EPYTHON}" man
+
+	sphinx_compile_all # HTML pages only
+}
+
+python_install_all() {
+	# If USE=doc, there'll be newly generated docs which we install instead.
+	if use doc || [[ ${PV} != *9999 ]]; then
+		doman build/sphinx/man/*
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "sending email support" x11-misc/xdg-utils
+	optfeature "tatt subcommand" "app-portage/nattka dev-python/jinja"
+}