dev-python/urllib3: Bump to 1.25.8

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/urllib3/Manifest

@@ -1,2 +1,3 @@
 DIST urllib3-1.24.2.tar.gz 230699 BLAKE2B 9c2f2be8fa743f542493d75072c02423d1bd40189561fa0ea393a8a2515b24da9a2a383aeec35b55bdd2a9954d3d585450d759548358ed91ecfdb9ec03d391b6 SHA512 9939e9e7c4da30b5effb334969cd835c9d0404a136761098203c699570aab02e63fb3f1b4ab680def0bc0906fabe5f0782ab94cf3095ff10ccf9b3c371653cf2
 DIST urllib3-1.25.7.tar.gz 264636 BLAKE2B 32ee47df52e0d164865400ecb5f0b65d3640173b53e1d9cf8f2dbdec46ac34d56ca66991ab719d9fafb8d49440630a3318312a925f11e3c6b8d26cfa72600c4a SHA512 e43c1b7893488b77a38a9fdcfc9760ceea72c53cf176eb8e4d1d9990732c5c1936f85c653a646eaadb3eaf72a99ccdbb5023430b97beca6458b868095005eac2
+DIST urllib3-1.25.8.tar.gz 261077 BLAKE2B 9625c8bce484e3a0ae8b49a776377d5420a496652d75220438f8f9cfbfa96c22a6fbea29380f45f18d8620d14568056dcb3e8b6a08fe711085298d2f6b2ea870 SHA512 6e380d98d9a8b06534abfab4eb67b685a8311a091e31adcefe2b0ffc61d2b728229df067790b20358f2646e9054a546450c3351e4aa618f31d85573ea50ceaa2

dev-python/urllib3/urllib3-1.25.8.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} pypy3 )
+PYTHON_REQ_USE="ssl(+)"
+
+inherit distutils-r1
+
+DESCRIPTION="HTTP library with thread-safe connection pooling, file post, and more"
+HOMEPAGE="https://github.com/urllib3/urllib3"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="brotli test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/PySocks-1.5.8[${PYTHON_USEDEP}]
+	<dev-python/PySocks-2.0[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+	>=dev-python/cryptography-1.3.4[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-0.14[${PYTHON_USEDEP}]
+	>=dev-python/idna-2.0.0[${PYTHON_USEDEP}]
+	virtual/python-ipaddress[${PYTHON_USEDEP}]
+	brotli? ( dev-python/brotlipy[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/brotlipy[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		>=dev-python/trustme-0.5.3[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=www-servers/tornado-4.2.1[${PYTHON_USEDEP}]
+		' python{2_7,3_{5,6,7}})
+	)
+"
+
+distutils_enable_sphinx docs \
+	dev-python/alabaster \
+	dev-python/mock
+
+python_prepare_all() {
+	# tests requiring a route to be present
+	sed -e 's:test_enhanced_timeout:_&:' \
+		-e 's:test_https_timeout:_&:' \
+		-i test/with_dummyserver/test_https.py || die
+	sed -e 's:test_https_proxy_.*timeout:_&:' \
+		-i test/with_dummyserver/test_proxy_poolmanager.py || die
+	# no clue why those fail, might be tornado's fault, might be just
+	# very flaky
+	sed -e 's:test_client_no_intermediate:_&:' \
+		-i test/with_dummyserver/test_https.py || die
+	sed -e 's:test_cross_host_redirect:_&:' \
+		-e 's:test_cross_protocol_redirect:_&:' \
+		-e 's:test_basic_ipv6_proxy:_&:' \
+		-i test/with_dummyserver/test_proxy_poolmanager.py || die
+	sed -e 's:test_connection_closed_on_read_timeout_preload_false:_&:' \
+		-i test/with_dummyserver/test_socketlevel.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	# FIXME: get tornado ported
+	case ${EPYTHON} in
+		python2*|python3.[567])
+			pytest -vv || die "Tests fail with ${EPYTHON}"
+			;;
+	esac
+}