x11-wm/jwm: add 2.4.3

Closes: https://bugs.gentoo.org/912594
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>
This commit is contained in:
Michael Mair-Keimberger
2024-07-21 17:05:47 +02:00
committed by Conrad Kostecki
parent b631378bb4
commit 88292ec69e
2 changed files with 83 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST jwm-2.4.2.tar.xz 316000 BLAKE2B 7a0a1c5f60cb3554c999ce3d00d94af4d58ac4bdfcbaaa13a7b675273b4c5d0058c7c85bec950fa91d33a46a89f0b83faf2ab2cda0430a741884e2fdfd8116a7 SHA512 2669c3e2ab2d9a5539d02559108a2bc601bb2209de03dc15057a65c14b5e1268cc58009f4102c4d90302c0705ada5578997a3644c736a46a7e8cf13766cc92fe
DIST jwm-2.4.3.tar.xz 317192 BLAKE2B d0b0ff1088ab3390a90c054162ea2c2fe782b61f28b3fdb28464ace362143fdc94e25ec82f7f4178b86a26c9315cdfcf9a81bff2e76bb5e3d62f88968a4ee80b SHA512 35b8a6da9614f11881013aa77c36ee88ce9a213f056e797231b772132beb841d54094809b6a476383999bddeccf61451f72cd166309dd79c223b634cf5d1e69e
+82
View File
@@ -0,0 +1,82 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit wrapper
DESCRIPTION="Very fast and lightweight still powerful window manager for X"
HOMEPAGE="https://joewing.net/projects/jwm/"
SRC_URI="https://github.com/joewing/${PN}/releases/download/v${PV}/${P}.tar.xz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~ppc ~x86"
IUSE="svg debug iconv jpeg nls png pango truetype xinerama xpm"
RDEPEND="dev-libs/expat
x11-libs/libXau
x11-libs/libXdmcp
x11-libs/libXext
x11-libs/libXmu
x11-libs/libXrender
svg? (
x11-libs/cairo
gnome-base/librsvg
)
iconv? ( virtual/libiconv )
jpeg? ( media-libs/libjpeg-turbo )
nls? ( sys-devel/gettext
virtual/libintl )
pango? ( x11-libs/pango )
png? ( media-libs/libpng:0= )
truetype? ( x11-libs/libXft )
xinerama? ( x11-libs/libXinerama )
xpm? ( x11-libs/libXpm )"
DEPEND="${RDEPEND}
x11-base/xorg-proto"
BDEPEND="virtual/pkgconfig"
src_configure() {
local myeconfargs=(
$(use_enable svg cairo)
$(use_enable svg rsvg)
$(use_enable debug)
$(use_enable jpeg)
$(use_enable nls)
$(use_enable pango)
$(use_enable png)
$(use_enable truetype xft)
$(use_enable xinerama)
$(use_enable xpm)
$(use_with iconv libiconv-prefix /usr)
$(use_with nls libintl-prefix /usr)
--enable-shape
--enable-xrender
--disable-rpath
)
econf "${myeconfargs[@]}"
}
src_install() {
dodir /etc
dodir /usr/bin
dodir /usr/share/man
default
make_wrapper "${PN}" "/usr/bin/${PN}" "" "" "/etc/X11/Sessions"
insinto "/usr/share/xsessions"
doins "${FILESDIR}"/jwm.desktop
dodoc README.md README.upgrading example.jwmrc CONTRIBUTING.md
}
pkg_postinst() {
einfo "JWM can be configured system-wide with ${EROOT}/etc/system.jwmrc"
einfo "or per-user by creating a configuration file in ~/.jwmrc"
einfo
einfo "An example file can be found in ${EROOT}/usr/share/doc/${PF}/"
}