dev-python/blockdiag: Bump to 2.0.1, update homepage

Replace bitbucket homepage on 1.5.4 ebuild.
Replace bitbucket remote-id in metadata.xml with github

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Brian Dolbec <dolsen@gentoo.org>

dev-python/blockdiag/Manifest

@@ -1 +1,2 @@
 DIST blockdiag-1.5.4.tar.gz 2693073 BLAKE2B 8a825742b4144667153af00d5e334325f8a3b49823355787dbd577729da8b0fc221ead14ab899ef8aef1800bbc2cdc47f060330bf0a2f2f1bcd055d172d8adbb SHA512 0eef8b3837282ed611e044ee618abca1f799b4a151bc2d7cece140c97ac728b2f3b9a3bb6877d3fed42a74e0173d0cbfd2966521c4dfb21c266975b4062405d2
+DIST blockdiag-2.0.1.tar.gz 2694776 BLAKE2B 289bbeab89dff4e8274efb9e2061b1e412e29bfbd663f64b55346ee09d09279e0813347c51b6cdc9e547b417eba637a85f7cb37f48006467bfa1c9875a113971 SHA512 07690882b05d4cf7be04245e183a7c54d9cd4acab3bb4b5e170b7b0f9229d6ea42eba4dc9fab47604c1572d3c4b09de96cffb610c0c31882b9c0b150f0e76d89

dev-python/blockdiag/blockdiag-1.5.4.ebuild

@@ -7,7 +7,7 @@ PYTHON_COMPAT=( python3_{6,7,8} )
 inherit distutils-r1
 
 DESCRIPTION="Generate block-diagram image from text"
-HOMEPAGE="http://blockdiag.com/ https://pypi.org/project/blockdiag/ https://bitbucket.org/blockdiag/blockdiag/"
+HOMEPAGE="http://blockdiag.com/ https://pypi.org/project/blockdiag/ https://github.com/blockdiag/blockdiag/"
 SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
 
 LICENSE="Apache-2.0"

dev-python/blockdiag/blockdiag-2.0.1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+DISTUTILS_USE_SETUPTOOLS="rdepend"
+
+inherit distutils-r1
+
+DESCRIPTION="Generate block-diagram image from text"
+HOMEPAGE="http://blockdiag.com/ https://pypi.org/project/blockdiag/ https://github.com/blockdiag/blockdiag/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/funcparserlib-0.3.6[${PYTHON_USEDEP}]
+	>=dev-python/pillow-3.0.0[${PYTHON_USEDEP}]
+	dev-python/webcolors[${PYTHON_USEDEP}]
+"
+DEPEND="
+	test? (
+		${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/reportlab[${PYTHON_USEDEP}]
+		dev-python/docutils[${PYTHON_USEDEP}]
+		media-fonts/ja-ipafonts
+	)
+"
+
+python_prepare_all() {
+	sed -i -e /build-base/d setup.cfg || die
+	# unnecessary dep
+	sed -i -e '/pep8/d' setup.py || die
+	# disable tests requiring Internet access
+	sed -i -e 's:test_app_cleans_up_images:_&:' \
+		src/blockdiag/tests/test_command.py || die
+	sed -i -e 's:ghostscript_not_found_test:_&:' \
+		src/blockdiag/tests/test_generate_diagram.py || die
+	rm src/blockdiag/tests/diagrams/node_icon.diag || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}
+
+pkg_postinst() {
+	einfo "For additional functionality, install the following optional packages:"
+	einfo "    dev-python/reportlab for pdf format"
+	einfo "    media-gfx/imagemagick"
+	einfo "    wand: https://pypi.org/project/Wand"
+	einfo "          Ctypes-based simple MagickWand API binding for Python"
+}

dev-python/blockdiag/metadata.xml

@@ -11,7 +11,7 @@
 			<name>Takeshi Komiya</name>
 		</maintainer>
 		<remote-id type="pypi">blockdiag</remote-id>
-		<remote-id type="bitbucket">blockdiag/blockdiag</remote-id>
+		<remote-id type="github">blockdiag/blockdiag</remote-id>
 	</upstream>
 	<longdescription>blockdiag generate block-diagram image file from spec-text
 	file.  Additional functionality is available with dev-python/reportlab