dev-libs/capstone: install into --libdir=

Reported-by: Agostino Sarubbo
Closes: https://bugs.gentoo.org/730722
Package-Manager: Portage-2.3.103, Repoman-2.3.23
Signed-off-by: Sergei Trofimovich <slyfox@gentoo.org>

dev-libs/capstone/capstone-4.0.2-r2.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DISTUTILS_OPTIONAL=1
+PYTHON_COMPAT=( python{3_6,3_7} )
+
+inherit cmake-utils distutils-r1 toolchain-funcs
+
+DESCRIPTION="disassembly/disassembler framework + bindings"
+HOMEPAGE="http://www.capstone-engine.org/"
+SRC_URI="https://github.com/aquynh/${PN}/archive/${PV/_rc/-rc}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/4" # libcapstone.so.4
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+
+RESTRICT="!test? ( test )"
+
+IUSE="python static-libs test"
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	python? ( dev-python/setuptools[${PYTHON_USEDEP}] )
+"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+S=${WORKDIR}/${P/_rc/-rc}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-libsuffix.patch
+)
+
+wrap_python() {
+	if use python; then
+		pushd bindings/python >/dev/null || die
+		distutils-r1_${1} "$@"
+		popd >/dev/null
+	fi
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	wrap_python ${FUNCNAME}
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCAPSTONE_BUILD_TESTS="$(usex test)"
+		-DCAPSTONE_BUILD_STATIC="$(usex static-libs)"
+	)
+	cmake-utils_src_configure
+
+	wrap_python ${FUNCNAME}
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	wrap_python ${FUNCNAME}
+}
+
+src_test() {
+	cmake-utils_src_test
+
+	wrap_python ${FUNCNAME}
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	wrap_python ${FUNCNAME}
+}

dev-libs/capstone/files/capstone-4.0.2-libsuffix.patch

@@ -0,0 +1,12 @@
+cmake does not provide 'LIBSUFFIX' variables, but provides 'LIB_SUFFIX'.
+https://bugs.gentoo.org/730722
+--- a/capstone.pc.in
++++ b/capstone.pc.in
+@@ -1,6 +1,6 @@
+ prefix=@CMAKE_INSTALL_PREFIX@
+ exec_prefix=${prefix}
+-libdir=${prefix}/lib@LIBSUFFIX@
++libdir=${prefix}/lib@LIB_SUFFIX@
+ includedir=${prefix}/include/capstone
+ 
+ Name: capstone