mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 22:47:14 -08:00
dev-util/schroot: New version
This commit is contained in:
@@ -1,4 +1,5 @@
|
||||
DIST schroot_1.6.10-1.debian.tar.xz 27108 SHA256 d93a7acc4b6c06a024b6bb0bfc1867a144193aadbb09cab454373c2983120cd9 SHA512 2b989054485f397c7de4f9d5e625f2bb2d4738ecb087ff83903a247696a2c98dea611e9743d4ae6bee401b122c21aac4f5e220b5e544f9968f94d6f326fadfa6 WHIRLPOOL 7f9a1b782093321b0dc236098688dacd93f608725bd551ef848262049da3f08b12b2ec34188413ec5b16070753acdc0a07af8d723599581340ecd9cfc6493b67
|
||||
DIST schroot_1.6.10-2.debian.tar.xz 34296 SHA256 71ed5b264029bd62226337a29f7ec926c29724c9540b24f7ccccfbef81c2391a SHA512 ea980199b90a2cffc36348e01e2de229c5cb4321f10bcde4b593eeaaa18f34ab9187cc9c717e6043c477819fefbd793cc707e1e77a5bae1c1815a668956cd84c WHIRLPOOL b6de6552c78418cde8ffc201017d3665a85a161d2417648b8213a37979889ae54380da051c59f1643d28989ae3f905976493b860002e1a4ded3aaea1434d3673
|
||||
DIST schroot_1.6.10.orig.tar.xz 797328 SHA256 3ce8dfd9cb97b099e4b6d4ccec421d6cc8c9ef84574681e928a12badb5643d0b SHA512 25155989c7811ab4c7bf3cdceaa8d0ffb12f08388143891def96fcd205f1cc401dad9a74f0e9a9ef8610d50174ff8319a8368401431dc87e1a11c0241e61fcbe WHIRLPOOL 91c4682101c6eeb1f56d3e5c583a55af1164abd6853a822ac5c5f1c6820140fb1049765877e97985a90264f4e9d898886487fac794a794904f98210494974090
|
||||
DIST schroot_1.6.3.orig.tar.xz 730756 SHA256 0b914a0ae1eef0288e5bf016c14031d3433d1b3f18820bebc5480647594ebc82 SHA512 e435715091eed17e1f073218b2cc2355ad529bb702b9f8cfeb58ed3be38b78fa61280713801ce29e5b21c93939f5898e6f6e4f493d3f7d2550a873289a6c22be WHIRLPOOL 065142aa34a225d0cda44ca3d3703131fe2a0ab46ad914bf386a58dd0480650ca03a5b6d00216eca41edff5a534083874d121623002aec57e933a95a4d2cc60f
|
||||
DIST schroot_1.6.5-1.debian.tar.gz 30518 SHA256 acf7cdbbb486a5724e61d10ba682df24dc66ec9274c6897f64b7dbd5f9632aed SHA512 3f5753a877cf8226f9eb085620c91f3e6179855adb7faf1f60e78d12b30ac545f6f6d124a239bd6a8d6b3ac28b417ee1d3ccc7ea4978cad77f3bba1d6e2c043d WHIRLPOOL 13b8afc0575fc1d4e27e35ba0cf277ffb04353b2dc0ebcfb8596d6ada064402f2004bd0b9fd658daad8cef69c1a3c5d615be0569335f6b243ed2f09134d63543
|
||||
|
||||
@@ -0,0 +1,147 @@
|
||||
# Copyright 1999-2016 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
# $Id$
|
||||
|
||||
EAPI="6"
|
||||
|
||||
inherit cmake-utils eutils pam versionator bash-completion-r1
|
||||
|
||||
MY_P=${PN}_${PV}
|
||||
DEB_REL=2
|
||||
|
||||
DESCRIPTION="Utility to execute commands in a chroot environment"
|
||||
HOMEPAGE="http://packages.debian.org/source/sid/schroot"
|
||||
SRC_URI="mirror://debian/pool/main/${PN::1}/${PN}/${MY_P}.orig.tar.xz
|
||||
mirror://debian/pool/main/${PN::1}/${PN}/${MY_P}-${DEB_REL}.debian.tar.xz"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~x86"
|
||||
IUSE="btrfs +dchroot debug doc lvm nls pam test"
|
||||
|
||||
COMMON_DEPEND="
|
||||
>=dev-libs/boost-1.42.0
|
||||
>=sys-apps/util-linux-2.16
|
||||
btrfs? ( >=sys-fs/btrfs-progs-0.19-r2 )
|
||||
lvm? ( sys-fs/lvm2 )
|
||||
pam? ( sys-libs/pam )
|
||||
"
|
||||
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
app-arch/xz-utils
|
||||
sys-apps/groff
|
||||
doc? (
|
||||
app-doc/doxygen
|
||||
media-gfx/graphviz
|
||||
)
|
||||
nls? (
|
||||
>=app-text/po4a-0.40
|
||||
sys-devel/gettext
|
||||
)
|
||||
test? ( >=dev-util/cppunit-1.10.0 )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
sys-apps/debianutils
|
||||
dchroot? ( !sys-apps/dchroot )
|
||||
nls? ( virtual/libintl )
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${S}/debian/patches/Add-support-for-more-compression-formats.patch"
|
||||
"${S}/debian/patches/Add-SESSION_SOURCE-and-CHROOT_SESSION_SOURCE.patch"
|
||||
"${S}/debian/patches/10mount-Move-mount-directory-to-var-run.patch"
|
||||
"${S}/debian/patches/Support-union-mounts-with-overlay-as-in-Linux-4.0.patch"
|
||||
"${S}/debian/patches/GCC5-fixes-on-regexes.patch"
|
||||
)
|
||||
|
||||
src_unpack() {
|
||||
unpack ${MY_P}.orig.tar.xz
|
||||
cd "${S}"
|
||||
unpack ${MY_P}-${DEB_REL}.debian.tar.xz
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
sed -i -e 's/warn(/message(WARNING /' man/CMakeLists.txt || die
|
||||
sed -i -e '/^have schroot/d' etc/bash_completion/schroot || die
|
||||
|
||||
cmake-utils_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-Dbtrfs-snapshot=$(usex btrfs)
|
||||
-Ddchroot=$(usex dchroot)
|
||||
-Ddchroot-dsa=$(usex dchroot)
|
||||
-Ddebug=$(usex debug)
|
||||
-Ddoxygen=$(usex doc)
|
||||
-Dlvm-snapshot=$(usex lvm)
|
||||
-Dnls=$(usex nls)
|
||||
-Dpam=$(usex pam)
|
||||
-Dtest=$(usex test)
|
||||
-Dbash_completion_dir="$(get_bashcompdir)"
|
||||
-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
|
||||
-DCMAKE_INSTALL_LOCALSTATEDIR="${EPREFIX}/var"
|
||||
)
|
||||
if ! use nls; then
|
||||
mycmakeargs+=(-DPO4A_EXECUTABLE=NOTFOUND)
|
||||
fi
|
||||
|
||||
cmake-utils_src_configure
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
cmake-utils_src_compile all $(usev doc)
|
||||
}
|
||||
|
||||
src_test() {
|
||||
if [[ $EUID -ne 0 ]]; then
|
||||
ewarn "Disabling tests because you are not root"
|
||||
return 0
|
||||
fi
|
||||
|
||||
cmake-utils_src_test
|
||||
}
|
||||
|
||||
src_install() {
|
||||
cmake-utils_src_install
|
||||
|
||||
insinto /usr/share/doc/${PF}/contrib/setup.d
|
||||
doins contrib/setup.d/05customdir contrib/setup.d/09fsck contrib/setup.d/10mount-ssh
|
||||
|
||||
newdoc debian/schroot.NEWS NEWS.debian
|
||||
|
||||
newinitd "${FILESDIR}"/schroot.initd schroot
|
||||
newconfd "${FILESDIR}"/schroot.confd schroot
|
||||
|
||||
if use doc; then
|
||||
docinto html/sbuild
|
||||
dohtml "${BUILD_DIR}"/doc/sbuild/html/*
|
||||
docinto html/schroot
|
||||
dohtml "${BUILD_DIR}"/doc/schroot/html/*
|
||||
fi
|
||||
|
||||
if use pam; then
|
||||
rm -f "${ED}"etc/pam.d/schroot
|
||||
pamd_mimic_system schroot auth account session
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ ${REPLACING_VERSIONS} == 1.[24]* ]]; then
|
||||
elog "Please read /usr/share/doc/${PF}/NEWS.debian* for important"
|
||||
elog "upgrade information."
|
||||
fi
|
||||
# If installing to a running system, upgrading from <=1.6.10-r3, then
|
||||
# make sure that the runtime dirs are still visible to the new install
|
||||
if [[ ${ROOT} == / && ${REPLACING_VERSIONS} ]] && ! version_is_at_least 1.6.10-r4 ${REPLACING_VERSIONS}; then
|
||||
ln -s "${EPREFIX}"/var/lib/schroot "${EPREFIX}"/var/run/schroot
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
if [[ -z ${REPLACED_BY_VERSION} ]]; then
|
||||
for dir in $(find "${EROOT}"/var/lib/schroot/mount -maxdepth 1 -type d | tac); do
|
||||
rmdir "$dir" || elog "Failed to remove session mount directory $dir: Please check for any stray mounts or data under this directory and remove by hand."
|
||||
done
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user