dev-python/trio: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/trio/Manifest

@@ -1,2 +1 @@
-DIST trio-0.29.0.gh.tar.gz 599433 BLAKE2B 35a162f01cca02134ffcd1c0cd3c072c1a20c07cc67038f3257fcb4732c696174ab3ee6e37706ffbb878b6a647d9e26489a55cdccb051b33c43517b660d227cd SHA512 88b6845c26f5bb02b749db7f64843e1858c3d52aad4332101022d61ec183f96304f1ce05a8ece5f97d04edf9aef668d791831439ae49fe1a7b904cf76061629e
 DIST trio-0.30.0.gh.tar.gz 605667 BLAKE2B 1df453c8a3747bfacb39029a3146bd323deb3cd22b5ba2119e01795f18b9340595ac7b850095b272be575cd508059f5b13993ddfe904e1e4a0cd70ef127c80f8 SHA512 5e76808fd9c79c3eab686b80d201654cdb9023b35c0aa8eb6415d079e810be9e60f13149da63ba1eb78c879f68392b6957aac16402413cd329f440399ffb65b7

dev-python/trio/trio-0.29.0.ebuild

@@ -1,77 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=setuptools
-PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
-
-inherit distutils-r1
-
-DESCRIPTION="Python library for async concurrency and I/O"
-HOMEPAGE="
-	https://github.com/python-trio/trio/
-	https://pypi.org/project/trio/
-"
-SRC_URI="
-	https://github.com/python-trio/${PN}/archive/v${PV}.tar.gz
-		-> ${P}.gh.tar.gz
-"
-
-LICENSE="|| ( Apache-2.0 MIT )"
-SLOT="0"
-KEYWORDS="amd64 arm arm64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
-
-RDEPEND="
-	>=dev-python/attrs-23.2.0[${PYTHON_USEDEP}]
-	$(python_gen_cond_dep '
-		>=dev-python/exceptiongroup-1.2.1[${PYTHON_USEDEP}]
-	' 3.10)
-	dev-python/idna[${PYTHON_USEDEP}]
-	dev-python/outcome[${PYTHON_USEDEP}]
-	>=dev-python/sniffio-1.3.0[${PYTHON_USEDEP}]
-	dev-python/sortedcontainers[${PYTHON_USEDEP}]
-"
-BDEPEND="
-	test? (
-		>=dev-python/astor-0.8.0[${PYTHON_USEDEP}]
-		>=dev-python/immutables-0.6[${PYTHON_USEDEP}]
-		dev-python/pyopenssl[${PYTHON_USEDEP}]
-		dev-python/trustme[${PYTHON_USEDEP}]
-	)
-"
-
-distutils_enable_tests pytest
-# Bug https://bugs.gentoo.org/916756
-# distutils_enable_sphinx docs/source \
-# 	dev-python/immutables \
-# 	dev-python/sphinxcontrib-trio \
-# 	dev-python/sphinx-rtd-theme \
-# 	dev-python/towncrier
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Times out on slower arches (ia64 in this case)
-		# https://github.com/python-trio/trio/issues/1753
-		tests/test_unix_pipes.py::test_close_at_bad_time_for_send_all
-		# requires ruff
-		_tests/tools/test_gen_exports.py
-	)
-
-	case ${EPYTHON} in
-		python3.14)
-			EPYTEST_DESELECT+=(
-				# xfail-ed upstream with ref to
-				# https://github.com/python/cpython/issues/125603
-				_core/_tests/test_run.py::test_ki_protection_doesnt_leave_cyclic_garbage
-			)
-			;;
-	esac
-
-	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
-	rm -rf trio || die
-	epytest -p trio._tests.pytest_plugin \
-		-m "not redistributors_should_skip" \
-		--pyargs trio \
-		--skip-optional-imports
-}