dev-python/yarl: Bump to 1.18.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/yarl/Manifest

@@ -1,2 +1,3 @@
 DIST yarl-1.17.1.tar.gz 178163 BLAKE2B 88d864944829e4b69ae346b0c6eb205969e9f9d2326d46f1eb4ed0506516f71730731763daf56e8230b699d5775c053c4750f6a770422cad392199ba5c099074 SHA512 5c1c25a8b828694a6538e7a07d01fc5d14238b279f8db4d76ee247a4f043b3e836c292cf6a77bb5ba544ec43dee449f2417eb0a5aaed6954449043a0fea3f811
 DIST yarl-1.17.2.tar.gz 178947 BLAKE2B 5cca5ef7fa2745f76c72ba0fbd54a62344f8961d365f6777812cec6c44d42d3a573f25db25b3afe7ff93775aaff8c4f71a6cf13ed86061e14e37cab984c0d7d8 SHA512 d99cfb5bb89f60b41cad021af5971e42439f47c77b24de0ab43c372cedb15ee18bfca478889f002a322e24838e2978c30923f965ea879ba52549644b2a957348
+DIST yarl-1.18.0.tar.gz 180098 BLAKE2B bd49cb019cb0a7572ddb562aaf599929bfcd2f67758631d93fc0db90ea60919852f90ea196d6a5bdba9d03661d2bcbe82e2d51284c0ff6acc76b269e99bed5b5 SHA512 061b4cdb5d18718e847a45c5fdc854f75294be2198d5d803bf473eae06467a56188e36c672d31f083c7a96f213db831fe79c92479a43b63a40cc4a007062c0aa

dev-python/yarl/yarl-1.18.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..13} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Yet another URL library"
+HOMEPAGE="
+	https://github.com/aio-libs/yarl/
+	https://pypi.org/project/yarl/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+RDEPEND="
+	>=dev-python/idna-2.0[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.0[${PYTHON_USEDEP}]
+	>=dev-python/propcache-0.2.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	native-extensions? (
+		dev-python/cython[${PYTHON_USEDEP}]
+	)
+	dev-python/expandvars[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x YARL_NO_EXTENSIONS=0
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# benchmarks
+		tests/test_quoting_benchmarks.py
+		tests/test_url_benchmarks.py
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	local opts=()
+	# note different boolean logic than for backend (sigh)
+	local -x YARL_NO_EXTENSIONS=
+	if ! use native-extensions || [[ ${EPYTHON} != python* ]]; then
+		YARL_NO_EXTENSIONS=1
+	fi
+
+	rm -rf yarl || die
+	epytest -o addopts= "${opts[@]}"
+}