dev-ros/roslaunch: Bump to 1.15.9.

Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Alexis Ballier <aballier@gentoo.org>

dev-ros/roslaunch/Manifest

@@ -1 +1,2 @@
 DIST ros_comm-1.15.8.tar.gz 1080826 BLAKE2B c1a1e085225a96cf0b50309cb78e1ccdabefce1f23ee669393b7fc747537c7e39bfb6ad382b0d24e3b5507b1d0f3eaf2051a1bee90507b0e724e06a83df301a2 SHA512 b1c34ab6548400fc014eda496e5d1e1c7d134b9062a031386ac4eac3245ca83b034f74f0a189ccf9ec6933c18d6df0ae1a93d05f1526d09debf70c25aa25b6b9
+DIST ros_comm-1.15.9.tar.gz 1087337 BLAKE2B 8c1582425770eee7898de42785c620c5fe82e31764d8947c16f9dbb43dd03d0201344e72d5a24911f7cc3cf4eacd51d6fc2940cc2346b635a2c769b055898297 SHA512 3f009a29d74dd74169585afb8d08c41faa19128e384ef6aa6c7bf58ae4d31345e4ea5441fc99a81b7742f724df7c7e3c16c4e51473c4fddeb4b9b6bf41cff04b

dev-ros/roslaunch/roslaunch-1.15.9.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ROS_REPO_URI="https://github.com/ros/ros_comm"
+KEYWORDS="~amd64 ~arm"
+ROS_SUBDIR=tools/${PN}
+
+inherit ros-catkin user
+
+DESCRIPTION="Tool for easily launching multiple ROS nodes"
+LICENSE="BSD"
+SLOT="0"
+IUSE=""
+
+RDEPEND="
+	dev-ros/roslib[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/rospkg[\${PYTHON_USEDEP}]")
+	dev-ros/rosclean[${PYTHON_SINGLE_USEDEP}]
+	$(python_gen_cond_dep "dev-python/pyyaml[\${PYTHON_USEDEP}]")
+	dev-ros/rosgraph_msgs[${CATKIN_MESSAGES_PYTHON_USEDEP}]
+	dev-ros/rosparam[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosmaster[${PYTHON_SINGLE_USEDEP}]
+	dev-ros/rosout
+"
+DEPEND="${RDEPEND}
+	test? (
+		$(python_gen_cond_dep "dev-util/rosdep[\${PYTHON_USEDEP}]")
+		$(python_gen_cond_dep "dev-python/nose[\${PYTHON_USEDEP}]")
+		dev-ros/test_rosmaster
+	)"
+
+src_test() {
+	export ROS_PACKAGE_PATH="${S}:${S}/../rosmaster/:${EPREFIX}/usr/share/ros_packages/rosparam:${EPREFIX}/usr/share/ros_packages/roslib:${EPREFIX}/usr/share/ros_packages/rosout"
+	ros-catkin_src_test
+}
+
+src_install() {
+	ros-catkin_src_install
+
+	dodir /etc/ros
+	sed -e "s/@PKG_VERSION@/${PV}/" "${FILESDIR}/roscore.xml.in" > "${ED}/etc/ros/roscore.xml" || die
+
+	newinitd "${FILESDIR}/roscore.initd" roscore
+	newconfd "${FILESDIR}/roscore.confd" roscore
+
+	newinitd "${FILESDIR}/roslaunch.initd" roslaunch
+	newconfd "${FILESDIR}/roslaunch.confd" roslaunch
+
+	doenvd "${FILESDIR}/40roslaunch"
+
+	# Needed by test_roslaunch
+	insinto /usr/share/${PN}
+	doins test/xml/noop.launch
+}
+
+pkg_preinst() {
+	enewgroup ros
+	enewuser ros -1 -1 /home/ros ros
+}