dev-python/nbclassic: Bump to 1.3.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/nbclassic/Manifest

@@ -1 +1,2 @@
 DIST nbclassic-1.2.0.tar.gz 20204389 BLAKE2B 37d2614b48e28d187b7f22aeab71bb5b1d8dbc0349654bbd8323a76bb6cd789ed6bd3d0c04764e6e9757d37df1131dde3fe3927d1933de6b9e2db2d4651e00b9 SHA512 416345cb773392b4d2b03a914ed3511bf75a7ea8dad02360a0623233af56f38a9853647ad1b62f0f7e397e6b3715bd66bc5e52e4736fe5b30884136fab0b459c
+DIST nbclassic-1.3.0.tar.gz 81486814 BLAKE2B 829660842360748b3c2a166d9281bfb66cdd5a7ad5e4215deab7ad8ff98a08fd87de066babd89ef80738eab32db22d32dc62c68d1ba1be42cde33f6cd15bbd57 SHA512 01d63aaab04f060341fd489dac1d0b7b2897e878b44b3f896a73ebf5a31f4122a518a6c91ee61562926c755e5b803e1864593dfe518259b4fc2f43eb5c372225

dev-python/nbclassic/nbclassic-1.3.0.ebuild

@@ -0,0 +1,94 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} pypy3 pypy3_11 )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1 pypi xdg-utils
+
+DESCRIPTION="Jupyter Notebook as a Jupyter Server Extension"
+HOMEPAGE="
+	https://jupyter.org/
+	https://github.com/jupyter/nbclassic/
+	https://pypi.org/project/nbclassic/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+
+RDEPEND="
+	dev-python/ipykernel[${PYTHON_USEDEP}]
+	dev-python/ipython-genutils[${PYTHON_USEDEP}]
+	>=dev-python/nest-asyncio-1.5[${PYTHON_USEDEP}]
+	>=dev-python/notebook-shim-0.2.3[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/nbval[${PYTHON_USEDEP}]
+		dev-python/pytest-jupyter[${PYTHON_USEDEP}]
+		dev-python/pytest-tornasync[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/requests-unixsocket[${PYTHON_USEDEP}]
+		dev-python/testpath[${PYTHON_USEDEP}]
+	)
+	doc? (
+		virtual/pandoc
+	)
+"
+
+distutils_enable_tests pytest
+distutils_enable_sphinx docs/source \
+	dev-python/pydata-sphinx-theme \
+	dev-python/nbsphinx \
+	dev-python/sphinxcontrib-github-alt \
+	dev-python/myst-parser \
+	dev-python/ipython-genutils
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# This horror of a build system requires nodejs + yarn to regenerate
+	# some files that are already pregenerated in sdist.
+	sed -i -e 's:^\[tool.hatch.build.hooks.jupyter-builder\]$:[ignoreme]:' pyproject.toml || die
+	# Confuses hatchling sometimes, resulting in partial install.
+	# https://github.com/jupyter/nbclassic/issues/336
+	rm .gitignore || die
+
+	# Let's save some space at build-time, we're not using them anyway.
+	rm -r node_modules || die
+
+	# Dead symlinks that trip up hatchling sometimes, depending
+	# on the phase of the moon.
+	rm nbclassic/static/components/jquery-typeahead/node_modules/.bin/lz-string || die
+	# Symlink to itself.
+	rm nbclassic/static/components/moment/meteor/moment.js || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	# Notebook interferes with our tests, pretend it does not exist
+	echo "raise ImportError" > notebook.py || die
+
+	epytest -p pytest_tornasync.plugin
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	# move /usr/etc stuff to /etc
+	mv "${ED}/usr/etc" "${ED}/etc" || die
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}