gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

net-analyzer/zabbix: bump to 7.0.18

Browse Source 
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>
This commit is contained in:
Miroslav Šulc
2025-09-25 15:41:59 +02:00
parent 397e7cec92
commit 84ebe9348c
2 changed files with 373 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

2
net-analyzer/zabbix/Manifest
View File

@@ -4,6 +4,8 @@ DIST zabbix-7.0.13-go-deps.tar.xz 34381580 BLAKE2B 0acdf38f362ef2cd9bf2d7b0c2a54
DIST zabbix-7.0.13.tar.gz 45654298 BLAKE2B 8011590e32fe160e23eb1a58f03571842d7289a26b0d9cfa754fc22aa26c3e6af14f58607797f07b55698f5ef44e8d511f3b362376bd822ebea269e10fe6a744 SHA512 f6cd29c862c10bdbef3e949b4641a2dc340f1b6cceafbebf11074f55aa043540064bbedb80838f9bb4f3636a425f0d1260d3cf27a363d74307910c04c7c8642f
DIST zabbix-7.0.17-go-deps.tar.xz 35427636 BLAKE2B ff67ab3527736a97de93c92304c7f1c05f5ae390c08dbc0ce8fddf964a4e222d124be3173d4b96992cf984f07155c1c79b75d01c0520481bc1be234fa27a7b04 SHA512 78142679cfa1bb9369efe06e1fb7b8086a11caf1e1e3a0d528464d33eed5678129c0847c79f8f517c1e8f8c90860a8771f3933ae9f3e179a01386ae128bbd448
DIST zabbix-7.0.17.tar.gz 45971019 BLAKE2B 88bcf427743467019b6a2759aa59474904a90e643d4d214faa07cde9719ea68299ef1183da548c5257b270a86771af1e9eb5f0b135bf51011f87c19210d80d63 SHA512 87ef51f8b866791419017e730980debb352d04e5968171813fe2ce0de8a8cb4f42ddff3e9953dd3807f96a682ed9ca3c3f656a4a404a92b1dfbe681108599aa8
DIST zabbix-7.0.18-go-deps.tar.xz 36261808 BLAKE2B ef625c9a3a2eb13af088bec0466e18273314365bbf8231d453e48a66d6d20983afce6b162596a2785387f772035d09e593d6d44643e71a7ff9be5fb5f6136523 SHA512 a26f939c9d4e08fa1c39203201a46c869ebdb133c942aa76181eeb4b07104cb3deea6899f2b88d1f98a17586a59358b63ba468ff0ef10072aea24072b0f68568
DIST zabbix-7.0.18.tar.gz 46113850 BLAKE2B 8a88e359a6aa411ca5eb010fe24352edc3fb9dfba64d86e4e609ac3537c46cb45d470ba2f8bc196e62359459fd695d94d8be5a18afa5d1fe933fcb6f7de80cf7 SHA512 cb3530ee122aac0df1d969192bff6721b00560acabbc97877f1323e717def04f8111a42109289d881ca059364b33bcf1b5a7e5549ee33b3375a9a8956d5b354d
DIST zabbix-7.2.11-go-deps.tar.xz 35748380 BLAKE2B d54077865860d27294051f5b21c6a2281236b3916a8cdf91665cd11793521c55bf946ece8214166e57b86afe13759c7574c05286216f96ca3c44962cc7e95e7f SHA512 6cdd5cfff9beb00bcfa4f336d391a21e5c9432adea173b5d937742f473f16d43d89d1c684af12a3a1abbf4ff09a1d1ed558de9ff678bc2acb6cc25e8cceba194
DIST zabbix-7.2.11.tar.gz 41846551 BLAKE2B fdb1e7f6b68a1d6af34a8f24dcacd97ca27663fffc4c06d160cc7d0c704031896f3f563f9a94e55daf80a4c88bb80c2dd2c56d7df7e270c66acabb5aef467a3f SHA512 6ddf058f822acbc133543dbc15253335cd48f25ccd5cf50641e9109ba3df1c98c1a211ce510f4ad3ebf9c221e7acbdb8619f3aa39c0d2d5d6e189a75b55bafcd
DIST zabbix-7.2.12-go-deps.tar.xz 35431848 BLAKE2B 070b2ecd463e2fdd52acabe59cc8690a0d528b52f269a4e79d314624d615f80bc44310c647b5a4bd6897fa500a1ed4b7ab5439932887dcd7a7005f49c0128e09 SHA512 f68dd2267e8d05ba0c841f59a6a984e10db376bda5066ebcf0dd8eaa7ee1f9bff258132b4bb5fb5eed5b0621d9f4a660c6676f050b6ef701f8184acd4f1f4fb5

371
net-analyzer/zabbix/zabbix-7.0.18.ebuild Normal file
View File

@@ -0,0 +1,371 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# To create the go modules tarball:
# cd src/go
# GOMODCACHE="${PWD}"/go-mod go mod download -modcacherw
# tar -acf $(pwd | grep -Eo 'zabbix-[0-9.]+')-go-deps.tar.xz go-mod
EAPI=8
GO_OPTIONAL="yes"
# needed to make webapp-config dep optional
WEBAPP_OPTIONAL="yes"
inherit autotools webapp java-pkg-opt-2 systemd tmpfiles toolchain-funcs go-module user-info
DESCRIPTION="ZABBIX is software for monitoring of your applications, network and servers"
HOMEPAGE="https://www.zabbix.com/"
MY_P=${P/_/}
MY_PV=${PV/_/}
SRC_URI="https://cdn.zabbix.com/${PN}/sources/stable/$(ver_cut 1-2)/${P}.tar.gz
agent2? ( https://dev.gentoo.org/~fordfrog/distfiles/${P}-go-deps.tar.xz )
"
S=${WORKDIR}/${MY_P}
LICENSE="AGPL-3"
SLOT="0/$(ver_cut 1-2)"
WEBAPP_MANUAL_SLOT="yes"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="agent +agent2 curl frontend gnutls ipv6 java ldap libxml2 mysql odbc openipmi +openssl +postgres proxy selinux server snmp sqlite ssh static"
REQUIRED_USE="|| ( agent agent2 frontend proxy server )
?? ( gnutls openssl )
agent2? ( !gnutls )
proxy? ( ^^ ( mysql postgres sqlite ) )
server? ( ^^ ( mysql postgres ) !sqlite )
static? ( !snmp )"
COMMON_DEPEND="
curl? ( net-misc/curl )
gnutls? ( net-libs/gnutls:0= )
java? ( >=virtual/jdk-1.8:* )
ldap? (
=dev-libs/cyrus-sasl-2*
net-libs/gnutls:=
net-nds/openldap:=
)
libxml2? ( dev-libs/libxml2:= )
mysql? ( dev-db/mysql-connector-c:= )
odbc? ( dev-db/unixODBC )
openipmi? ( sys-libs/openipmi )
openssl? ( dev-libs/openssl:=[-bindist(-)] )
postgres? ( dev-db/postgresql:* )
proxy? (
dev-libs/libevent:=
sys-libs/zlib
)
server? (
dev-libs/libevent:=
sys-libs/zlib
)
snmp? ( net-analyzer/net-snmp:= )
sqlite? ( dev-db/sqlite )
ssh? ( net-libs/libssh2 )
"
RDEPEND="${COMMON_DEPEND}
acct-group/zabbix
acct-user/zabbix
java? ( >=virtual/jre-1.8:* )
mysql? ( virtual/mysql )
proxy? (
dev-libs/libpcre2:=
net-analyzer/fping[suid]
)
selinux? ( sec-policy/selinux-zabbix )
server? (
app-admin/webapp-config
dev-libs/libpcre2:=
net-analyzer/fping[suid]
)
frontend? (
app-admin/webapp-config
dev-lang/php:*[bcmath,ctype,gd,jpeg(+),nls,png(+),session,sockets,sysvipc,truetype,unicode,xml,xmlreader,xmlwriter]
media-libs/gd[png]
virtual/httpd-php:*
mysql? ( dev-lang/php[mysqli] )
odbc? ( dev-lang/php[odbc] )
postgres? ( dev-lang/php[postgres] )
sqlite? ( dev-lang/php[sqlite] )
)
"
DEPEND="${COMMON_DEPEND}
static? (
curl? ( net-misc/curl[static-libs] )
ldap? (
=dev-libs/cyrus-sasl-2*[static-libs]
net-libs/gnutls[static-libs]
net-nds/openldap[static-libs]
)
libxml2? ( dev-libs/libxml2[static-libs] )
mysql? ( dev-db/mysql-connector-c[static-libs] )
odbc? ( dev-db/unixODBC[static-libs] )
postgres? ( dev-db/postgresql:*[static-libs] )
sqlite? ( dev-db/sqlite[static-libs] )
ssh? ( net-libs/libssh2 )
)
"
BDEPEND="
virtual/pkgconfig
agent2? (
>=dev-lang/go-1.12
app-arch/unzip
)
"
# upstream tests fail for agent2
RESTRICT="test"
PATCHES=(
"${FILESDIR}/${PN}-4.0.18-modulepathfix.patch"
"${FILESDIR}/${PN}-3.0.30-security-disable-PidFile.patch"
"${FILESDIR}/${PN}-6.4.0-configure-sscanf.patch"
)
ZABBIXJAVA_BASE="opt/zabbix_java"
pkg_setup() {
if use frontend; then
webapp_pkg_setup
fi
java-pkg-opt-2_pkg_setup
}
src_prepare() {
default
# Since we patch configure.ac with e.g., ${PN}-6.4.0-configure-sscanf.patch".
eautoreconf
}
src_configure() {
local econf_args=(
--with-libpcre2
"$(use_enable agent)"
"$(use_enable agent2)"
"$(use_enable ipv6)"
"$(use_enable java)"
"$(use_enable proxy)"
"$(use_enable server)"
"$(use_enable static)"
"$(use_with curl libcurl)"
"$(use_with gnutls)"
"$(use_with ldap)"
"$(use_with libxml2)"
"$(use_with mysql)"
"$(use_with odbc unixodbc)"
"$(use_with openipmi openipmi)"
"$(use_with openssl)"
"$(use_with postgres postgresql)"
"$(use_with snmp net-snmp)"
"$(use_with sqlite sqlite3)"
"$(use_with ssh ssh2)"
)
econf ${econf_args[@]}
}
src_compile() {
if [ -f Makefile ] || [ -f GNUmakefile ] || [ -f makefile ]; then
emake AR="$(tc-getAR)" RANLIB="$(tc-getRANLIB)"
fi
}
src_install() {
local dirs=(
/etc/zabbix
/var/lib/zabbix
/var/lib/zabbix/home
/var/lib/zabbix/scripts
/var/lib/zabbix/alertscripts
/var/lib/zabbix/externalscripts
/var/log/zabbix
)
for dir in "${dirs[@]}"; do
keepdir "${dir}"
done
if use server; then
insinto /etc/zabbix
doins "${S}"/conf/zabbix_server.conf
fperms 0640 /etc/zabbix/zabbix_server.conf
fowners root:zabbix /etc/zabbix/zabbix_server.conf
newinitd "${FILESDIR}"/zabbix-server-r1.init zabbix-server
dosbin src/zabbix_server/zabbix_server
insinto /usr/share/zabbix
doins -r "${S}"/database/
systemd_dounit "${FILESDIR}"/zabbix-server.service
newtmpfiles "${FILESDIR}"/zabbix-server.tmpfiles zabbix-server.conf
fi
if use proxy; then
insinto /etc/zabbix
doins "${S}"/conf/zabbix_proxy.conf
fperms 0640 /etc/zabbix/zabbix_proxy.conf
fowners root:zabbix /etc/zabbix/zabbix_proxy.conf
newinitd "${FILESDIR}"/zabbix-proxy.init zabbix-proxy
dosbin src/zabbix_proxy/zabbix_proxy
insinto /usr/share/zabbix
doins -r "${S}"/database/
systemd_dounit "${FILESDIR}"/zabbix-proxy.service
newtmpfiles "${FILESDIR}"/zabbix-proxy.tmpfiles zabbix-proxy.conf
fi
if use agent; then
insinto /etc/zabbix
doins "${S}"/conf/zabbix_agentd.conf
fperms 0640 /etc/zabbix/zabbix_agentd.conf
fowners root:zabbix /etc/zabbix/zabbix_agentd.conf
newinitd "${FILESDIR}"/zabbix-agentd.init zabbix-agentd
dosbin src/zabbix_agent/zabbix_agentd
dobin \
src/zabbix_sender/zabbix_sender \
src/zabbix_get/zabbix_get
systemd_dounit "${FILESDIR}"/zabbix-agentd.service
newtmpfiles "${FILESDIR}"/zabbix-agentd.tmpfiles zabbix-agentd.conf
fi
if use agent2; then
insinto /etc/zabbix
doins "${S}"/src/go/conf/zabbix_agent2.conf
fperms 0640 /etc/zabbix/zabbix_agent2.conf
fowners root:zabbix /etc/zabbix/zabbix_agent2.conf
keepdir /etc/zabbix/zabbix_agent2.d/plugins.d
newinitd "${FILESDIR}"/zabbix-agent2.init zabbix-agent2
dosbin src/go/bin/zabbix_agent2
systemd_dounit "${FILESDIR}"/zabbix-agent2.service
newtmpfiles "${FILESDIR}"/zabbix-agent2.tmpfiles zabbix-agent2.conf
fi
fowners root:zabbix /etc/zabbix
fowners zabbix:zabbix \
/var/lib/zabbix \
/var/lib/zabbix/home \
/var/lib/zabbix/scripts \
/var/lib/zabbix/alertscripts \
/var/lib/zabbix/externalscripts \
/var/log/zabbix
fperms 0750 \
/etc/zabbix \
/var/lib/zabbix \
/var/lib/zabbix/home \
/var/lib/zabbix/scripts \
/var/lib/zabbix/alertscripts \
/var/lib/zabbix/externalscripts \
/var/log/zabbix
dodoc README INSTALL NEWS ChangeLog \
conf/zabbix_agentd.conf \
conf/zabbix_proxy.conf \
conf/zabbix_agentd/userparameter_examples.conf \
conf/zabbix_agentd/userparameter_mysql.conf \
conf/zabbix_server.conf
if use frontend; then
webapp_src_preinst
cp -R ui/* "${D}/${MY_HTDOCSDIR}"
webapp_configfile \
"${MY_HTDOCSDIR}"/include/db.inc.php \
"${MY_HTDOCSDIR}"/include/config.inc.php
webapp_src_install
fi
if use java; then
dodir \
/${ZABBIXJAVA_BASE} \
/${ZABBIXJAVA_BASE}/bin \
/${ZABBIXJAVA_BASE}/lib
keepdir /${ZABBIXJAVA_BASE}
exeinto /${ZABBIXJAVA_BASE}/bin
doexe src/zabbix_java/bin/zabbix-java-gateway-"${MY_PV}".jar
exeinto /${ZABBIXJAVA_BASE}/lib
doexe \
src/zabbix_java/lib/logback-classic-1.5.16.jar \
src/zabbix_java/lib/logback-console.xml \
src/zabbix_java/lib/logback-core-1.5.16.jar \
src/zabbix_java/lib/logback.xml \
src/zabbix_java/lib/android-json-4.3_r3.1.jar \
src/zabbix_java/lib/slf4j-api-2.0.16.jar
newinitd "${FILESDIR}"/zabbix-jmx-proxy.init zabbix-jmx-proxy
newconfd "${FILESDIR}"/zabbix-jmx-proxy.conf zabbix-jmx-proxy
fi
}
pkg_postinst() {
if use server || use proxy ; then
elog
elog "You may need to configure your database for Zabbix"
elog "if you have not already done so."
elog
zabbix_homedir=$(egethome zabbix)
if [ -n "${zabbix_homedir}" ] && \
[ "${zabbix_homedir}" != "/var/lib/zabbix/home" ]; then
ewarn
ewarn "The user 'zabbix' should have his homedir changed"
ewarn "to /var/lib/zabbix/home if you want to use"
ewarn "custom alert scripts."
ewarn
ewarn "A real homedir might be needed for configfiles"
ewarn "for custom alert scripts."
ewarn
ewarn "To change the homedir use:"
ewarn " usermod -d /var/lib/zabbix/home zabbix"
ewarn
fi
fi
if use server; then
tmpfiles_process zabbix-server.conf
elog
elog "For distributed monitoring you have to run:"
elog
elog "zabbix_server -n <nodeid>"
elog
elog "This will convert database data for use with Node ID"
elog "and also adds a local node."
elog
fi
if use proxy; then
tmpfiles_process zabbix-proxy.conf
fi
if use agent; then
tmpfiles_process zabbix-agentd.conf
fi
if use agent2; then
tmpfiles_process zabbix-agent2.conf
fi
elog "--"
elog
elog "You may need to add these lines to /etc/services:"
elog
elog "zabbix-agent 10050/tcp Zabbix Agent"
elog "zabbix-agent 10050/udp Zabbix Agent"
elog "zabbix-trapper 10051/tcp Zabbix Trapper"
elog "zabbix-trapper 10051/udp Zabbix Trapper"
elog
}
pkg_prerm() {
(use frontend || use server) && webapp_pkg_prerm
}