kde-frameworks/kfilemetadata: 6.14.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/kfilemetadata/Manifest

@@ -1,2 +1,3 @@
 DIST kfilemetadata-5.116.0.tar.xz 527164 BLAKE2B 9562f6e4d135cc0686fe12c4748198e94ea5d10dc0f52ad72c83cdb33d9a3ef04efe885bd1af94405eedf05fe36e1f20eadd449d1d1228e92b74878db963f75a SHA512 1c5d264ad2bc123ba0d85882461009efc10c268441e33f82810823d1e2c6fb30209336542b4e2c1eabb96b53cc9184fc3982c27922872a9b92cac38bafe2da0e
 DIST kfilemetadata-6.13.0.tar.xz 695316 BLAKE2B cab93b2aef29e4d01df4d0fe0237e717538819b2563677a0826c0c1f7658cd08442940686d2226d42eea251875d9717bb3600f242a8ace3d4d59782cd11c7dbf SHA512 738d6e3502275e1333249b4865e032ecf29ac8aa7ffcba80423657fc4f294cd6f03117271d303eabd5b0207fec2e5ec2de616da0a0602d662bba935fcd56c64f
+DIST kfilemetadata-6.14.0.tar.xz 695864 BLAKE2B 5f82108078643c9a0c26a3be3bdad370ea68deee17e9178c7d564be65ccbebb41784a7f53c533bbb8dc11851a6c5290a7c51bf254c95fcc3f946532f32bd5224 SHA512 1b3e78b36d9b2f091bdcd685747166c36d8c82e6933d68238d8c01f49ffa20b9b34b6ba8b94df244c9dcbd943bc0c845687129bf6ee972dd53626c4f0c0e5563

kde-frameworks/kfilemetadata/kfilemetadata-6.14.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,xml]
+	=kde-frameworks/karchive-${KDE_CATV}*:6
+	=kde-frameworks/kcodecs-${KDE_CATV}*:6
+	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
+	=kde-frameworks/ki18n-${KDE_CATV}*:6
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:6 )
+	pdf? ( app-text/poppler[qt6(-)] )
+	taglib? ( media-libs/taglib:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+CMAKE_SKIP_TESTS=(
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	usermetadatawritertest
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket6)
+		-DENABLE_MOBIPOCKET_TEXT_EXTRACTION=OFF
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+}