mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 17:09:10 -07:00
mail-client/mutt-1.13.0: version bump
Package-Manager: Portage-2.3.76, Repoman-2.3.16 Signed-off-by: Fabian Groffen <grobian@gentoo.org>
This commit is contained in:
Fabian Groffen
@@ -2,7 +2,9 @@ DIST mutt-1.10.1.tar.gz 4255890 BLAKE2B 2a0e7629c42ba11ec5c3686d9c17e283ed9cb1f9
|
||||
DIST mutt-1.11.4.tar.gz 4582417 BLAKE2B 750385cc90df0d34d35103883a9918f205830ea93e5ec9f33cd579d5c121d630b3074f1918fa0e8e5aa91edd503c7ba38c34785a8a96803d7af30d08a0966c4d SHA512 18c5bfa5c45ef70b3307afccf28f613a36de035f1b5c493f84f0571f7ba297cd0b25e01be9102a028c51c28c459c4bc62281da88926e16ce58c3c1407609e0eb
|
||||
DIST mutt-1.12.1.tar.gz 4675166 BLAKE2B f1c073e05d60f41a8057d90074b7cbc2a882243b0c4b495b1b147356c83daad136d5574dd6a567c0180823e73d8fb79a38d316ab0b2c56731baed24fe9ad9890 SHA512 0101120ad2acab89552be210725bae1a903f0b2c48be7207750589d141236537823f27c39e8d700eee16eb6b978058d056180b3d51e45e0242546f176b971538
|
||||
DIST mutt-1.12.2.tar.gz 4675774 BLAKE2B 0b0a4695f31db97437e7d6e52ca8e131376bd0ae168195a4a73c3d2230f43460000c5b623e39b89c5cc7bf5253e7ffad8f007b844a864fcde94baef1aa7369f9 SHA512 a824a056edef0c320b7633a39ab2421646442132190c2b2bf788ac39aaf7a0143d12847eb27290913d8ae793810bb6353803977610045b36235579001a1096bd
|
||||
DIST mutt-1.13.0.tar.gz 4889693 BLAKE2B 1c3f1e2107ea4f6147b9010ab4751afc09dbf16eec88c8c94b8edf84783abb8e75649eb3482d043c1c2fdd8c9428599ddcd844b72fa55881b5728ab09b564e07 SHA512 76dc0a0cce4293851fb4caa0018538f112bac0f02a1faa2a8ec62bbf078b130d2907709423b3eda5217d24886e58a1e7a184a094701c9bdb989e93b9dac123fa
|
||||
DIST mutt-gentoo-1.10.1-patches-r0.tar.xz 108396 BLAKE2B 86edca04154f96efce27543326f8610dffba0085c7d69e82a7ac5f48ae9cd6662bcf6afa0e55b3d83ec054ee2eb86dff70b0c15a5170f41cc57887e17a661406 SHA512 1e0675803abc2bc116ef6e726f5009c43b0fb7bbf9bd3141a7cbbded51033695ddcc5228612f228cd19dae4181719e756a85e3fa2c8c9a9a4a9aefb4170bd5f5
|
||||
DIST mutt-gentoo-1.11.4-patches-r0.tar.xz 107064 BLAKE2B f8ad915fd0ceea729fdc14719e69c43751e75fd4afc9f19460d15493fd97baee9606703d7d6a8239a34b2c0d6f2458fc007277933bbc724b6a8588bb7514decd SHA512 57714259f802efe54e21cd23560bb158777b50320604db0a8ff8a47c25166a873d13d64b03eba4cb1c5067a586e7c64d9d0ba84ddbe0e179745e92d704a55cd1
|
||||
DIST mutt-gentoo-1.12.1-patches-r0.tar.xz 106064 BLAKE2B 60b73bcfd9713261c7b88fe74d70a630954511a38331c3e8e958ef7f6459b3bf8548211ee920fe238085c6481c03633cec21e7ae70c1473c89914ce720bd7c21 SHA512 feffbd49ad8156e226e7d4dc56b1c976f3f2a0f8dc3551c11696d5653342b91b4406a494d6081b969fe8267bf09a441a4f3c5a0014d108000e55c985aaafa596
|
||||
DIST mutt-gentoo-1.12.2-patches-r1.tar.xz 106720 BLAKE2B 788735757dd4cf8c1d9fe09350eaf4780b1e90f1e1d9bf39c98ee03255b9b84847a387402940d1a05e4be2b8684688216ea62f564c40715cd6ccf4bebaeebdc0 SHA512 ec8c0989bff2008e6df0c43a8e833fb4f463993eacb1cbdd11722a6c49bb400804c80f74ac0073883a050f352a65d2743c4aebc882a2cd7db369a4e214a95701
|
||||
DIST mutt-gentoo-1.13.0-patches-r0.tar.xz 36020 BLAKE2B 56bda1576ef2ab8c0fa2f35ee0ddab88a391512c1530ad7ec77d921ee5686645cbde97ca3b131eb7370a89fe0517b1d4424aca3aea81dc708dcad51226eb1f29 SHA512 750e2165b4e4ae4f8caa0bf81797edbe10f0e10195978cbbf1a59263e788c5fa5e0ed78cdff19af1a574d9fdc0cc4c84c82faa712e755a482f8107390446a746
|
||||
|
||||
253
mail-client/mutt/mutt-1.13.0.ebuild
Normal file
253
mail-client/mutt/mutt-1.13.0.ebuild
Normal file
@@ -0,0 +1,253 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
|
||||
inherit eutils flag-o-matic autotools
|
||||
|
||||
PATCHREV="r0"
|
||||
PATCHSET="gentoo-${PVR}/${PATCHREV}"
|
||||
|
||||
DESCRIPTION="A small but very powerful text-based mail client"
|
||||
HOMEPAGE="http://www.mutt.org/"
|
||||
MUTT_G_PATCHES="mutt-gentoo-${PV}-patches-${PATCHREV}.tar.xz"
|
||||
SRC_URI="ftp://ftp.mutt.org/pub/mutt/${P}.tar.gz
|
||||
https://bitbucket.org/${PN}/${PN}/downloads/${P}.tar.gz
|
||||
https://dev.gentoo.org/~grobian/distfiles/${MUTT_G_PATCHES}"
|
||||
IUSE="berkdb debug doc gdbm gnutls gpgme +hcache idn +imap kerberos libressl +lmdb mbox nls pgp-classic pop qdbm +sasl selinux slang smime-classic +smtp +ssl tokyocabinet vanilla prefix"
|
||||
# hcache: allow multiple, bug #607360
|
||||
REQUIRED_USE="
|
||||
hcache? ( || ( berkdb gdbm lmdb qdbm tokyocabinet ) )
|
||||
imap? ( ssl )
|
||||
pop? ( ssl )
|
||||
smime-classic? ( ssl !gnutls )
|
||||
smtp? ( ssl sasl )
|
||||
sasl? ( || ( imap pop smtp ) )
|
||||
kerberos? ( || ( imap pop smtp ) )"
|
||||
SLOT="0"
|
||||
LICENSE="GPL-2"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
|
||||
# yes, we overdepend on the backend impls here, hopefully one day we can
|
||||
# have REQUIRED_USE do what it is made for again. bug #607360
|
||||
CDEPEND="
|
||||
app-misc/mime-types
|
||||
virtual/libiconv
|
||||
|
||||
berkdb? ( >=sys-libs/db-4:= )
|
||||
gdbm? ( sys-libs/gdbm )
|
||||
lmdb? ( dev-db/lmdb:= )
|
||||
qdbm? ( dev-db/qdbm )
|
||||
tokyocabinet? ( dev-db/tokyocabinet )
|
||||
|
||||
ssl? (
|
||||
gnutls? ( >=net-libs/gnutls-1.0.17:= )
|
||||
!gnutls? (
|
||||
libressl? ( dev-libs/libressl:= )
|
||||
!libressl? ( >=dev-libs/openssl-0.9.6:0= )
|
||||
)
|
||||
)
|
||||
|
||||
nls? ( virtual/libintl )
|
||||
sasl? ( >=dev-libs/cyrus-sasl-2 )
|
||||
kerberos? ( virtual/krb5 )
|
||||
idn? ( net-dns/libidn2 )
|
||||
gpgme? ( >=app-crypt/gpgme-0.9.0:= )
|
||||
slang? ( sys-libs/slang )
|
||||
!slang? ( >=sys-libs/ncurses-5.2:0= )
|
||||
"
|
||||
DEPEND="${CDEPEND}
|
||||
net-mail/mailbase
|
||||
doc? (
|
||||
dev-libs/libxml2
|
||||
dev-libs/libxslt
|
||||
app-text/docbook-xsl-stylesheets
|
||||
|| ( www-client/lynx www-client/w3m www-client/elinks )
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
selinux? ( sec-policy/selinux-mutt )
|
||||
smime-classic? ( || ( dev-libs/libressl >=dev-libs/openssl-0.9.6:0 ) )
|
||||
pgp-classic? ( app-crypt/gnupg )
|
||||
"
|
||||
|
||||
src_prepare() {
|
||||
local PATCHDIR="${WORKDIR}"/mutt-gentoo-${PV}-patches-${PATCHREV}
|
||||
|
||||
if use !vanilla ; then
|
||||
# apply patches
|
||||
export EPATCH_FORCE="yes"
|
||||
export EPATCH_SUFFIX="patch"
|
||||
# http://hg.code.sf.net/p/gentoomuttpatches/code/file/mutt-1.10
|
||||
local patches=(
|
||||
patches-mutt
|
||||
bugs-gentoo
|
||||
features-common
|
||||
features-extra
|
||||
gentoo
|
||||
)
|
||||
local patchset
|
||||
for patchset in "${patches[@]}" ; do
|
||||
[[ -d "${PATCHDIR}/${patchset}" ]] || continue
|
||||
einfo "Patches for ${PATCHSET} patchset ${patchset}"
|
||||
EPATCH_SOURCE="${PATCHDIR}"/${patchset} epatch \
|
||||
|| die "patchset ${patchset} failed"
|
||||
done
|
||||
# add some explanation as to why not to go upstream
|
||||
sed -i \
|
||||
-e '/ReachingUs = N_(/aThis release of Mutt is heavily enriched with patches.\\nFor this reason, any bugs are better reported at https://bugs.gentoo.org/\\nor re-emerge with USE=vanilla and try to reproduce your problem.\\n\\' \
|
||||
main.c || die "Failed to add bug instructions"
|
||||
fi
|
||||
|
||||
local upatches=
|
||||
# allow user patches
|
||||
eapply_user && upatches=" with user patches"
|
||||
|
||||
# patch version string for bug reports
|
||||
local patchset=
|
||||
use vanilla || patchset=", ${PATCHSET}"
|
||||
sed -i -e 's|"Mutt %s (%s)"|"Mutt %s (%s'"${patchset}${upatches}"')"|' \
|
||||
muttlib.c || die "failed patching in Gentoo version"
|
||||
|
||||
# many patches touch the buildsystem, we always need this
|
||||
AT_M4DIR="m4" eautoreconf
|
||||
|
||||
# the configure script contains some "cleverness" whether or not to setgid
|
||||
# the dotlock program, resulting in bugs like #278332
|
||||
sed -i -e 's/@DOTLOCK_GROUP@//' Makefile.in || die "sed failed"
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local myconf=(
|
||||
# signing and encryption
|
||||
$(use_enable pgp-classic pgp)
|
||||
$(use_enable smime-classic smime)
|
||||
$(use_enable gpgme)
|
||||
|
||||
# features
|
||||
$(use_enable debug)
|
||||
$(use_enable doc)
|
||||
$(use_enable nls)
|
||||
|
||||
# protocols
|
||||
$(use_enable imap)
|
||||
$(use_enable pop)
|
||||
$(use_enable smtp)
|
||||
|
||||
$(use ssl && use gnutls && echo --with-gnutls --without-ssl)
|
||||
$(use ssl && use !gnutls && echo --without-gnutls --with-ssl )
|
||||
$(use !ssl && echo --without-gnutls --without-ssl)
|
||||
|
||||
$(use_with sasl)
|
||||
$(use_with idn idn2) --without-idn # avoid automagic libidn dep
|
||||
$(use_with kerberos gss)
|
||||
"$(use slang && echo --with-slang="${EPREFIX}"/usr || echo a=b)"
|
||||
"$(use_with !slang curses "${EPREFIX}"/usr)"
|
||||
|
||||
"--enable-compressed"
|
||||
"--enable-external-dotlock"
|
||||
"--enable-iconv"
|
||||
"--enable-nfs-fix"
|
||||
"--enable-sidebar"
|
||||
"--sysconfdir=${EPREFIX}/etc/${PN}"
|
||||
"--with-docdir=${EPREFIX}/usr/share/doc/${PN}-${PVR}"
|
||||
"--without-bundled-regex" # use the implementation from libc
|
||||
"--with-exec-shell=${EPREFIX}/bin/sh"
|
||||
)
|
||||
|
||||
if [[ ${CHOST} == *-solaris2.* && ${CHOST#*-solaris2.} -le 10 ]] ; then
|
||||
# arrows in index view do not show when using wchar_t
|
||||
# or misalign due to wrong computations
|
||||
myconf+=( "--without-wc-funcs" )
|
||||
fi
|
||||
|
||||
# note: REQUIRED_USE should have selected only one of these, but for
|
||||
# bug #607360 we're forced to allow multiple. For that reason, this
|
||||
# list is ordered to preference, and only the first is taken.
|
||||
local hcaches=(
|
||||
"lmdb"
|
||||
"qdbm"
|
||||
"tokyocabinet"
|
||||
"gdbm"
|
||||
"berkdb:bdb"
|
||||
)
|
||||
local ucache hcache lcache
|
||||
for hcache in "${hcaches[@]}" ; do
|
||||
if use ${hcache%%:*} ; then
|
||||
ucache=${hcache}
|
||||
break
|
||||
fi
|
||||
done
|
||||
if [[ -n ${ucache} ]] ; then
|
||||
myconf+=( "--enable-hcache" )
|
||||
else
|
||||
myconf+=( "--disable-hcache" )
|
||||
fi
|
||||
for hcache in "${hcaches[@]}" ; do
|
||||
[[ ${hcache} == ${ucache} ]] \
|
||||
&& myconf+=( "--with-${hcache#*:}" ) \
|
||||
|| myconf+=( "--without-${hcache#*:}" )
|
||||
done
|
||||
|
||||
if use mbox; then
|
||||
myconf+=( "--with-mailpath=${EPREFIX}/var/spool/mail" )
|
||||
else
|
||||
myconf+=( "--with-homespool=Maildir" )
|
||||
fi
|
||||
|
||||
econf "${myconf[@]}" || die "configure failed"
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake DESTDIR="${D}" install || die "install failed"
|
||||
if use mbox; then
|
||||
insinto /etc/mutt
|
||||
newins "${FILESDIR}"/Muttrc.mbox Muttrc
|
||||
else
|
||||
insinto /etc/mutt
|
||||
doins "${FILESDIR}"/Muttrc
|
||||
fi
|
||||
|
||||
# A newer file is provided by app-misc/mime-types. So we link it.
|
||||
rm "${ED}"/etc/${PN}/mime.types
|
||||
dosym "${EPREFIX}"/etc/mime.types /etc/${PN}/mime.types
|
||||
|
||||
# nuke manpages that should be provided by an MTA, bug #177605
|
||||
rm "${ED}"/usr/share/man/man5/{mbox,mmdf}.5 \
|
||||
|| ewarn "failed to remove files, please file a bug"
|
||||
|
||||
if use !prefix ; then
|
||||
fowners root:mail /usr/bin/mutt_dotlock
|
||||
fperms g+s /usr/bin/mutt_dotlock
|
||||
fi
|
||||
|
||||
dodoc BEWARE COPYRIGHT ChangeLog NEWS OPS* PATCHES README* TODO VERSION
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if [[ -z ${REPLACING_VERSIONS} ]] ; then
|
||||
echo
|
||||
elog "If you are new to mutt you may want to take a look at"
|
||||
elog "the Gentoo QuickStart Guide to Mutt E-Mail:"
|
||||
elog " https://wiki.gentoo.org/wiki/Mutt"
|
||||
echo
|
||||
else
|
||||
ewarn "The nntp and notmuch patches were dropped from this release."
|
||||
ewarn "Due to too much maintenance cost, the nntp and notmuch patches"
|
||||
ewarn "were dropped from this release. If you need support for any"
|
||||
ewarn "of these features, please consider using mail-client/neomutt."
|
||||
echo
|
||||
fi
|
||||
if use !pgp-classic && use !smime-classic && use !gpgme ; then
|
||||
ewarn "Please note that crypto related USE-flags of Mutt have changed."
|
||||
ewarn "To comply with PMS, the following USE-flags were renamed:"
|
||||
ewarn "(see https://bugs.gentoo.org/695078)"
|
||||
ewarn " pgp_classic -> pgp-classic"
|
||||
ewarn " smime_classic -> smime-classic"
|
||||
echo
|
||||
fi
|
||||
if use gpgme ; then
|
||||
ewarn "Note: in order for Mutt to actually use the gpgme backend"
|
||||
ewarn " you MUST include 'set crypt_use_gpgme=yes' in .muttrc"
|
||||
# https is broken due to a certificate mismatch :(
|
||||
ewarn " http://www.mutt.org/doc/manual/#crypt-use-gpgme"
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user