dev-python/kombu: Bump to 5.6.0_rc1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/kombu/Manifest

@@ -1,2 +1,3 @@
 DIST kombu-5.5.4.tar.gz 461992 BLAKE2B 7c81ddd2c151b7abd984c2523e7855785796db23de5c1a43348870019de26079fb9b6475a5174ceea6ca461188cff4a8fe4da76d95345ac611a13d29c3a9848f SHA512 f3227303aa7ad1a4bd480c601f99f7b4ae2db6d3790defd02b4a9e4ccd6875630a9e6582f65f334a04a5111c456c489395fc4af5b2dd4a557e6aa47616859668
 DIST kombu-5.6.0b3.tar.gz 470444 BLAKE2B 5de996d63f0a5eb7b722f155ded48f6cdd8aba8e410ef82c10c0a095c14771cf3da1f49da2e9ef52fe3d74c295f1d5107b3ea797d727ff2241f30a5175a67214 SHA512 fba003297fbcba76511577f6ef53e9292d81f3b0b4d09a65dcb08918cd1529560b9635c026b6b8f3d9d4037feb4477ec0b909790772198343dc7a11b6612cf9a
+DIST kombu-5.6.0rc1.tar.gz 470754 BLAKE2B 8b059617ff7cc846bcb7800bfd74b2d70637e636369dc47f149dd96d81c40bc2ae32d447c46ea625754d9c2ad2246db82b4c400493d9199e5c09ee8232b4c4d6 SHA512 a1b86d5a2b30d23b40b5eccbb4af4e40965d7da0e4fc793aa3abd733152cd4378002334267a091d27dbf607701ec76764c05c6cf4888817f06e72e6a7e15f7ed

dev-python/kombu/kombu-5.6.0_rc1.ebuild

@@ -0,0 +1,92 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="AMQP Messaging Framework for Python"
+HOMEPAGE="
+	https://github.com/celery/kombu/
+	https://pypi.org/project/kombu/
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="examples"
+
+RDEPEND="
+	>=dev-python/amqp-5.1.1[${PYTHON_USEDEP}]
+	<dev-python/amqp-6.0.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/tzdata-2025.2[${PYTHON_USEDEP}]
+	dev-python/vine[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		>=dev-python/boto3-1.22.2[${PYTHON_USEDEP}]
+		app-arch/brotli[python,${PYTHON_USEDEP}]
+		dev-python/hypothesis[${PYTHON_USEDEP}]
+		>=dev-python/msgpack-0.3.0[${PYTHON_USEDEP}]
+		>=dev-python/pycurl-7.43.0.5[${PYTHON_USEDEP}]
+		>=dev-python/pymongo-4.1.1[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
+		>=dev-python/redis-4.2.2[${PYTHON_USEDEP}]
+		dev-python/sqlalchemy[${PYTHON_USEDEP}]
+		dev-python/zstandard[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-freezer )
+distutils_enable_tests pytest
+distutils_enable_sphinx docs \
+	dev-python/sphinx-celery
+
+EPYTEST_DESELECT=(
+	# TODO
+	t/unit/transport/test_redis.py::test_Channel::test_connparams_health_check_interval_supported
+	t/unit/transport/test_redis.py::test_Channel::test_global_keyprefix_transaction
+	# bad filename assumption?
+	t/unit/asynchronous/aws/test_connection.py::test_AsyncHTTPSConnection::test_request_with_cert_path_https
+)
+EPYTEST_IGNORE=(
+	# obsolete Pyro4
+	t/unit/transport/test_pyro.py
+	# unpackaged azure
+	t/unit/transport/test_azurestoragequeues.py
+	# unpackage google-cloud
+	t/unit/transport/test_gcpubsub.py
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# unpin deps (notably tzdata, sigh)
+	> requirements/default.txt || die
+}
+
+python_install_all() {
+	if use examples; then
+		docompress -x "/usr/share/doc/${PF}/examples"
+		docinto examples
+		dodoc -r examples/.
+	fi
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "Amazon SQS backend" "dev-python/boto3 dev-python/pycurl"
+	optfeature "Etcd backend" dev-python/python-etcd
+	optfeature "MongoDB backend" dev-python/pymongo
+	optfeature "Redis backend" dev-python/redis
+	optfeature "sqlalchemy backend" dev-python/sqlalchemy
+	optfeature "yaml backend" dev-python/pyyaml
+	optfeature "MessagePack (de)serializer for Python" dev-python/msgpack
+	optfeature "brotli compression" "app-arch/brotli[python]"
+	optfeature "zstd compression" dev-python/zstandard
+}