x11-misc/shared-mime-info: enable LFS

Closes: https://bugs.gentoo.org/684884
Package-Manager: Portage-2.3.62_p4, Repoman-2.3.12_p87
Signed-off-by: Mike Gilbert <floppym@gentoo.org>

x11-misc/shared-mime-info/shared-mime-info-1.10-r1.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit flag-o-matic xdg-utils
+
+DESCRIPTION="The Shared MIME-info Database specification"
+HOMEPAGE="https://freedesktop.org/wiki/Software/shared-mime-info"
+SRC_URI="https://people.freedesktop.org/~hadess/${P}.tar.xz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+
+RDEPEND=">=dev-libs/glib-2
+	dev-libs/libxml2"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+DOCS=( ChangeLog HACKING NEWS README )
+
+src_configure() {
+	export ac_cv_func_fdatasync=no #487504
+
+	# https://bugs.gentoo.org/684884
+	append-lfs-flags
+
+	local myeconfargs=(
+		$(use_enable test default-make-check)
+		--disable-update-mimedb
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	# FIXME: 0.91 fails with -j9 every second time like:
+	# update_mime_database-update-mime-database.o: file not recognized: File truncated
+	# collect2: ld returned 1 exit status
+	emake -j1
+}
+
+src_install() {
+	default
+
+	# in prefix, install an env.d entry such that prefix patch is used/added
+	if use prefix; then
+		echo "XDG_DATA_DIRS=\"${EPREFIX}/usr/share\"" > "${T}"/50mimeinfo || die
+		doenvd "${T}"/50mimeinfo
+	fi
+}
+
+pkg_postinst() {
+	use prefix && export XDG_DATA_DIRS="${EPREFIX}"/usr/share
+	xdg_mimeinfo_database_update
+}