app-text/gspell: Version bump to 1.9.1

Signed-off-by: Matt Turner <mattst88@gentoo.org>

app-text/gspell/Manifest

@@ -1 +1,2 @@
 DIST gspell-1.8.4.tar.xz 424356 BLAKE2B 031787c4f5c3f3cfe21d5f74ec72117818da43313c5e6dffb79581ca07033aede2ecf236ffdf2197938d62727c5bd3913d1362e02be7109b0d498304949e1d44 SHA512 adb481590442d81040151746c7747791d76248b1b35af1702dc5389efbd2e0c6bdda070b8e84384d22f4922b5a382ac2c6519e425f417ec85c8efbe22dc38c82
+DIST gspell-1.9.1.tar.xz 424252 BLAKE2B 436e6af50f7d1058dd7692c22b5a5e18c25cc76ea6816193e48728f7e1d55ef29af26127403a40d594a2125e4d3e1ee889abe067d2c065de74ae95ca431e5fbe SHA512 72f1fb384e02bb73397b457c3e8a7b98393c9fab5c0dad07f84d1db3f6b75c093663cc83c13fefe868424c503abc2fb89c8b045d0495dd43ddcedad025f23bca

app-text/gspell/gspell-1.9.1.ebuild

@@ -0,0 +1,60 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala virtualx
+
+DESCRIPTION="Spell check library for GTK+ applications"
+HOMEPAGE="https://wiki.gnome.org/Projects/gspell"
+
+LICENSE="LGPL-2.1+"
+SLOT="0/2" # subslot = libgspell-1 soname version
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="+introspection +vala"
+REQUIRED_USE="vala? ( introspection )"
+
+DEPEND="
+	>=app-text/enchant-2.1.3:2
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20:3[introspection?]
+	dev-libs/icu:=
+	introspection? ( >=dev-libs/gobject-introspection-1.42.0:= )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.25
+	>=sys-devel/gettext-0.19.6
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+	test? (
+		app-text/enchant:2[hunspell]
+		|| (
+			app-dicts/myspell-en[l10n_en(+)]
+			app-dicts/myspell-en[l10n_en-US(+)]
+		)
+	)
+"
+# Tests require a en_US dictionary and fail with deprecated enchant aspell backend:
+# So enchant[hunspell] + myspell-en ensure they pass (hunspell is ordered before aspell),
+# however a different backend like hspell or nuspell + their en_US dict might be fine too,
+# but we don't support them at this time (2020-04-12) in enchant:2
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable introspection) \
+		$(use_enable vala)
+}
+
+src_test() {
+	virtx emake check
+}