xfce-base/thunar: Bump to 4.16.10

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/thunar/Manifest

@@ -1,3 +1,4 @@
+DIST thunar-4.16.10.tar.bz2 2324476 BLAKE2B a8305f234b6f69654d6559594f1228ebbb5009b337fbdee6d94dc2f3c309d67cbe2aa5c357fd5207d4e907b9d06875dd3164d501c84a22c9f73e71b705577fd7 SHA512 b6fbb27acaae85e7d5c711213c5c457d7eaf973dabafbeabbc00ef01491b54b05da00304503ed03a1ee0716c2558f435754666dd5358f36b2e155e4c8132ebce
 DIST thunar-4.16.8.tar.bz2 2429407 BLAKE2B 0af1c14fff30f276c279ff459e33ff4c23533e1ce494cadba02fca6436c1d1d2a0c8ea302dfb9c7b5ff9b6d7a69a80996afa1274cc9f3c66f112b8230d8b30f3 SHA512 722caeef9a8a074bac705b0108faab418009e61d8e177838b6a63cbf29f7b9c78e3a135b8a59f154e978feb811d5d115810df2b2e9d53d93f1c34e62a2d5f7b8
 DIST thunar-4.16.9.tar.bz2 2323489 BLAKE2B dac834a9c3794f2e8bb4b6d29d3da17de1c49f3905fe4eac047c21dc89dda11582743ef084e7a6beb7cf128840cb6673442476b010352fe59a477bfff70c430c SHA512 afad777f78b898134e572a6d09d4adf69ead5d195cb077731c9261dde3cac489d37eb4b0148a2ca9b920a2c1298c5993170335a7e62b9b9c1863b2cfbfdc6fcb
 DIST thunar-4.17.3.tar.bz2 2427025 BLAKE2B 5fde8faf29f8b8f78a604c12cd0366187865d2c176109a8501500af573e77cfaf53aecc145674f2f49d730f2596c06e3304c4b2e033759430b1d3fd06439310b SHA512 7394121dd995296802b50ae6188a56228dec82f9cb1c29cf8c9bc4db6a69921e78f6a2bfcab459578faf64703eecc59a04ce6f4d623300e54faa2e0b4e261699

xfce-base/thunar/thunar-4.16.10.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit xdg-utils
+
+DESCRIPTION="File manager for the Xfce desktop environment"
+HOMEPAGE="https://www.xfce.org/projects/ https://docs.xfce.org/xfce/thunar/start"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="exif introspection libnotify pcre +trash-panel-plugin udisks"
+
+GVFS_DEPEND=">=gnome-base/gvfs-1.18.3"
+DEPEND=">=dev-libs/glib-2.50
+	>=x11-libs/gdk-pixbuf-2.14
+	>=x11-libs/gtk+-3.22:3
+	>=xfce-base/exo-4.15.3:=
+	>=xfce-base/libxfce4ui-4.15.3:=
+	>=xfce-base/libxfce4util-4.15.2:=
+	>=xfce-base/xfconf-4.12:=
+	exif? ( >=media-libs/libexif-0.6.19:= )
+	introspection? ( dev-libs/gobject-introspection:= )
+	libnotify? ( >=x11-libs/libnotify-0.7 )
+	pcre? ( >=dev-libs/libpcre-6:= )
+	trash-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
+	udisks? ( dev-libs/libgudev:= )"
+RDEPEND="${DEPEND}
+	>=dev-util/desktop-file-utils-0.20-r1
+	x11-misc/shared-mime-info
+	trash-panel-plugin? ( ${GVFS_DEPEND} )
+	udisks? (
+		virtual/udev
+		${GVFS_DEPEND}[udisks,udev]
+		)"
+BDEPEND="
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig"
+
+src_configure() {
+	local myconf=(
+		$(use_enable introspection)
+		$(use_enable udisks gudev)
+		$(use_enable libnotify notifications)
+		$(use_enable exif)
+		$(use_enable pcre)
+		$(use_enable trash-panel-plugin tpa-plugin)
+	)
+
+	econf "${myconf[@]}"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "If you were using an older Xfce version and Thunar fails to start"
+	elog "with a message similar to:"
+	elog "  Failed to register: Timeout was reached"
+	elog "you may need to reset your xfce4 session:"
+	elog "  rm ~/.cache/sessions/xfce4-session-*"
+	elog "See https://bugs.gentoo.org/698914."
+
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_icon_cache_update
+}