gui-libs/libadwaita: add 1.9.3

Thanks-to: Tanuki-no Torigava
Closes: https://github.com/gentoo/gentoo/pull/45955
Closes: https://bugs.gentoo.org/976450
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

gui-libs/libadwaita/Manifest

@@ -1 +1,2 @@
 DIST libadwaita-1.8.7.tar.xz 2701780 BLAKE2B c5594ac44e6f98caa5e302690938679723e255e577ea1657483eaf0d1ad376891976c743ec3b6e5ee7ed2cf3356824779e38e4f8364195d119fe885f4780a505 SHA512 3d6e78d905a31d9d4e9b89fc2d2dec91d73e87585a694520c357482d682861e67a03a95aaaf29926c4b5ed7fc145a9938d46e10110cb834ff1d8394f5f11225e
+DIST libadwaita-1.9.3.tar.xz 2894332 BLAKE2B 58332c93e78437784f39448a599dc8e313edfd3e0f0e277cf2373b5339241b3a102b6b401e8eeca0bb793db296c7f0d3bdcb9cc007c52439c9a986e83eb97413 SHA512 65f50ea784b0d7382eed4a56c2c88d74315641d2d5a37031747e4ad11845fd69418a636a37a7d9769b3529f63dec5506ada25ea1ebc591056791020528b45721

gui-libs/libadwaita/libadwaita-1.9.3.ebuild

@@ -0,0 +1,73 @@
+# Copyright 2022-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+inherit gnome.org meson python-any-r1 vala virtualx xdg
+
+DESCRIPTION="Building blocks for modern GNOME applications"
+HOMEPAGE="https://gnome.pages.gitlab.gnome.org/libadwaita/ https://gitlab.gnome.org/GNOME/libadwaita"
+
+LICENSE="LGPL-2.1+"
+SLOT="1"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+
+IUSE="examples gtk-doc +introspection test +vala"
+REQUIRED_USE="
+	gtk-doc? ( introspection )
+	vala? ( introspection )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.84.0:2
+	>=gui-libs/gtk-4.21.1:4[introspection?]
+	dev-libs/appstream:=
+	dev-libs/fribidi
+	introspection? ( >=dev-libs/gobject-introspection-1.83.2:= )
+"
+DEPEND="${RDEPEND}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	gtk-doc? ( >=dev-util/gi-docgen-2021.1 )
+	vala? ( $(vala_depend) )
+	dev-util/glib-utils
+	sys-devel/gettext
+	virtual/pkgconfig
+	dev-lang/sassc
+"
+
+src_prepare() {
+	default
+	use vala && vala_setup
+	xdg_environment_reset
+}
+
+src_configure() {
+	local emesonargs=(
+		# Never use gi-docgen subproject
+		--wrap-mode nofallback
+
+		-Dprofiling=false
+		$(meson_feature introspection)
+		$(meson_use vala vapi)
+		$(meson_use gtk-doc documentation)
+		$(meson_use test tests)
+		$(meson_use examples)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	addwrite /dev/dri
+	virtx meson_src_test --timeout-multiplier 2
+}
+
+src_install() {
+	meson_src_install
+	if use gtk-doc; then
+		mkdir -p "${ED}"/usr/share/gtk-doc/html/ || die
+		mv "${ED}"/usr/share/doc/${PN}-${SLOT} "${ED}"/usr/share/gtk-doc/html/ || die
+	fi
+}