dev-python/pydantic: add 2.10.5

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/pydantic/Manifest

@@ -1,2 +1,3 @@
 DIST pydantic-2.10.4.tar.gz 762094 BLAKE2B 0d9f3534df4ae05b2724788944776d0ac95329cfe48d59627e71b4769c7813410d0c64f0d7ca96e28aec8e403b2507873673b87acb230bb12ad5d4f304eb76ca SHA512 1c7bfcc214195d8db0cadbdb177da3e2e3ea596d695360036b0a268410711a780f9a88df622016d9bb6d39596f20e01bebc4cf38bdbe5dc987cb80fbb14aeb56
+DIST pydantic-2.10.5.tar.gz 761287 BLAKE2B f34b8a358a5a0e3839097a47b492eff7e6cea96eb6a77e1623ad1da90b4d13118f4b2c68b076ead91df450d85dfbcab1daebe77c6bdfa1ff9e4a49febf0dc0d1 SHA512 0e8ab6786c94b13fe155501cc1cba357bcf69b40413383415fd7e0b6fcaf5a818aa1efcc67a837c1c3c2315eb8b7b26c3af4b03c3f8a57ff3694955f792d2964
 DIST pydantic-2.9.2.tar.gz 769917 BLAKE2B 4e34fda6a9e8e8331278d0b7d0c2dfd61bde637c126fa6dabf78a09c6ef993f84dc8df6af421c8fb6d69c8e1c387a40e4bcd38cbe02f5ac521c6c70821735763 SHA512 2aace9e79a98bd94e5dc626736a245051912a11fdce36013d2ad2f96b266052386a3e12b259dca30ddc38b63c6b00b5bcc9cd5e80f7805de4d8701064f0982aa

dev-python/pydantic/pydantic-2.10.5.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3 python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Data parsing and validation using Python type hints"
+HOMEPAGE="
+	https://github.com/pydantic/pydantic/
+	https://pypi.org/project/pydantic/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/annotated-types-0.6.0[${PYTHON_USEDEP}]
+	~dev-python/pydantic-core-2.27.2[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-4.12.2[${PYTHON_USEDEP}]
+	dev-python/tzdata[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/cloudpickle[${PYTHON_USEDEP}]
+		dev-python/dirty-equals[${PYTHON_USEDEP}]
+		>=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/faker-18.13.0[${PYTHON_USEDEP}]
+		>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rich[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	sed -i -e '/benchmark/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=()
+	local EPYTEST_IGNORE=(
+		# require pytest-examples
+		tests/test_docs.py
+		# benchmarks
+		tests/benchmarks
+	)
+
+	if ! has_version "dev-python/cloudpickle[${PYTHON_USEDEP}]"; then
+		EPYTEST_IGNORE+=(
+			tests/test_pickle.py
+		)
+	fi
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_mock
+}