gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 17:09:10 -07:00
Code Issues Projects Releases Wiki Activity

dev-libs/dee: Remove last-rited pkg, #603562

Browse Source
This commit is contained in:
Michał Górny
2017-07-05 14:19:47 +02:00
parent a5d2414208
commit 82659fd559
6 changed files with 0 additions and 208 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-libs/dee/Manifest
View File

@@ -1 +0,0 @@
DIST dee-1.2.7.tar.gz 712167 SHA256 1bf0336ce684aa0f48d6eae2469628c1a9b43695a77443bc31a5790aa673bf8a SHA512 32e25a2164cf052a76cf021006e1cdeca9b25081d19b5e7f1700308ddc21f65b4b5230fef0197fdda1739281b96af39fbf9d1df50d79c812cea8a6f60fbb7248 WHIRLPOOL 95d471be45a338200f5f88be45e8d7f333e34912c55f9b07863e903d86d1936ccfd013b68a6b22931c80f60a59e8447e11472c61e4de975a8731317924c8970d

84
dev-libs/dee/dee-1.2.7-r1.ebuild
View File

@@ -1,84 +0,0 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
PYTHON_COMPAT=( python{2_7,3_4,3_5} )
inherit gnome2 python-r1 vala
DESCRIPTION="Provide objects allowing to create MVC type programs across DBus"
HOMEPAGE="https://launchpad.net/dee/"
SRC_URI="https://launchpad.net/dee/1.0/${PV}/+download/${P}.tar.gz"
SLOT="0/4"
LICENSE="GPL-3"
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
IUSE="debug examples +icu introspection static-libs test"
REQUIRED_USE="introspection? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
dev-libs/glib:2
icu? ( dev-libs/icu:= )
introspection? (
${PYTHON_DEPS}
>=dev-libs/gobject-introspection-0.10.2:=
)
"
DEPEND="${RDEPEND}
$(vala_depend)
>=dev-util/gtk-doc-am-1.8
virtual/pkgconfig
test? (
>=dev-libs/gtx-0.2.2
dev-util/dbus-test-runner
)
"
src_prepare() {
# Fix build with gcc-6, bug #594112
eapply "${FILESDIR}"/${PN}-1.2.7-gcc-6-build.patch
sed \
-e 's:VALA_API_GEN:VAPIGEN:g' \
-i vapi/Makefile.{am,in} || die
sed \
-e '/SUBDIRS/ s:bindings::g' \
-i Makefile.{am,in} || die
vala_src_prepare
gnome2_src_prepare
sed \
-e '/GCC_FLAGS/ s:-g::' \
-e 's:VALA_API_GEN:VAPIGEN:g' \
-i configure || die
}
src_configure() {
gnome2_src_configure \
$(use_enable debug trace-log) \
$(use_enable icu) \
$(use_enable introspection) \
$(use_enable static-libs static) \
$(use_enable test tests)
}
src_install() {
gnome2_src_install
if use examples ; then
insinto /usr/share/doc/${PN}/
doins -r examples
fi
if use introspection ; then
install_gi_override() {
python_moduleinto "$(python_get_sitedir)/gi/overrides"
python_domodule "${S}"/bindings/python/Dee.py
}
python_foreach_impl install_gi_override
fi
}

92
dev-libs/dee/dee-1.2.7.ebuild
View File

@@ -1,92 +0,0 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=5
PYTHON_COMPAT=( python2_7 python3_4 )
AUTOTOOLS_AUTORECONF=y
inherit autotools-utils vala python-r1
DESCRIPTION="Provide objects allowing to create MVC type programs across DBus"
HOMEPAGE="https://launchpad.net/dee/"
SRC_URI="https://launchpad.net/dee/1.0/${PV}/+download/${P}.tar.gz"
SLOT="0"
LICENSE="GPL-3"
KEYWORDS="~alpha amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc x86"
IUSE="doc debug examples +icu introspection static-libs test"
REQUIRED_USE="introspection? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
dev-libs/glib:2
dev-libs/icu:=
introspection? (
${PYTHON_DEPS}
dev-libs/gobject-introspection:=
)"
DEPEND="${RDEPEND}
$(vala_depend)
doc? ( dev-util/gtk-doc )
test? (
dev-libs/gtx
dev-util/dbus-test-runner
)"
src_prepare() {
sed \
-e '/GCC_FLAGS/s:-g::' \
-e 's:vapigen:${VAPIGEN}:g' \
-i configure.ac || die
sed \
-e 's:bindings::g' \
-i Makefile.am || die
vala_src_prepare
autotools-utils_src_prepare
}
src_configure() {
local myeconfargs=(
--disable-silent-rules
$(use_enable debug trace-log)
$(use_enable doc gtk-doc)
$(use_enable icu)
$(use_enable test tests)
# $(use_enable test extended-tests)
)
autotools-utils_src_configure
use introspection && python_copy_sources
}
src_compile() {
autotools-utils_src_compile
compilation() {
cd bindings || die
emake \
pyexecdir="$(python_get_sitedir)"
}
use introspection && python_foreach_impl run_in_build_dir compilation
}
src_install() {
autotools-utils_src_install
if use examples; then
insinto /usr/share/doc/${PN}/
doins -r examples
fi
installation() {
cd bindings || die
emake \
PYGI_OVERRIDES_DIR="$(python_get_sitedir)"/gi/overrides \
DESTDIR="${D}" \
install
}
use introspection && python_foreach_impl run_in_build_dir installation
}

14
dev-libs/dee/files/dee-1.2.7-gcc-6-build.patch
View File

@@ -1,14 +0,0 @@
--- a/src/dee-serializable-model.c 2013-09-16 20:21:20.000000000 +0200
+++ b/src/dee-serializable-model.c 2016-05-08 16:49:03.525140126 +0200
@@ -1326,9 +1326,10 @@
pos = 0;
_iter = dee_model_get_first_iter (self);
- while (!dee_model_is_last (self, iter) && iter != _iter)
+ while (!dee_model_is_last (self, iter) && iter != _iter) {
_iter = dee_model_next (self, _iter);
pos++;
+ }
if (iter == _iter)
return pos;

11
dev-libs/dee/metadata.xml
View File

@@ -1,11 +0,0 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>gnome@gentoo.org</email>
<name>Gentoo GNOME Desktop</name>
</maintainer>
<upstream>
<remote-id type="launchpad">dee</remote-id>
</upstream>
</pkgmetadata>

6
profiles/package.mask
View File

@@ -353,12 +353,6 @@ media-plugins/vdr-xineliboutput
# Removal in 30 days. Bug #562416.
dev-java/java-gnome
# Michał Górny <mgorny@gentoo.org> (05 Jun 2017)
# (on behalf of Treecleaner project)
# Unmaintained upstream. Bad quality code.
# Removal in 30 days. Bug #603562.
dev-libs/dee
# Michał Górny <mgorny@gentoo.org> (05 Jun 2017)
# (on behalf of Treecleaner project)
# Unmaintained in Gentoo. Multiple bugs, including a security