mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-17 14:49:30 -07:00
sys-kernel/gentoo-kernel-modprep: Bump to 6.6.151
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -4,6 +4,7 @@ DIST gentoo-kernel-modprep-6.12.103.tar.xz 8903716 BLAKE2B a3e9cbdb5c75201854678
|
||||
DIST gentoo-kernel-modprep-6.18.43.tar.xz 9564236 BLAKE2B 70e8328e8e0ca375e26956f5381f0cf206cfaa1ec014663677b3d9ccdbc985250896c418527b03267a039db8edd160d235b2cd5798e1e5f50fa0db6b6ac84b54 SHA512 7287c3162e0129cebb1e87f31807fae51969cfc5480600d889f8814ee9f7374e4286e367bcbf7441717d5a81a86cba6885f0e5d624df43fcd815b7b6c227362a
|
||||
DIST gentoo-kernel-modprep-6.18.44.tar.xz 9569256 BLAKE2B 3c81a95d068aee7ca06c099d21143369c9434f58a503219a907cf868fc24b7c223d7d76ded5430c3d72ed327c6d061df68abbec38054f457bc2fb6116fb6d698 SHA512 874109f6e7f69edb7bb5584b94c404164f19e28d6a5b6468861e7d3e7673b2e5abe0b70b25f291fa8405246dfc6b19114a44bc29f8295afa4b016968888cd021
|
||||
DIST gentoo-kernel-modprep-6.6.150.tar.xz 8263396 BLAKE2B acb794082efaf4aff5ba048f2eb12fa55f44b9de8a9c3c5aa1576e7486f97a4aa345bf552122c8a334b9279831cfbc693f97235b0aa8d690264a2dabb2ef8a1c SHA512 9d44443625c8374c48b2e74f396a9ce733d87af0965f4697708f4ea90c9a142af26340000128d0f2eb5649f905a57a5ec064099a605ecb916d5c7b36ac7b08c7
|
||||
DIST gentoo-kernel-modprep-6.6.151.tar.xz 8244536 BLAKE2B 2c8c130deb67acf74635739a5208c1c726277843e8d7c292305041a5d768881bd29674ea43c010ec17350a09e322b6b8716fcab86bf99fca2d246ff4eb95c512 SHA512 df3ed1317b00f082d50ce05710c2f634d4766791d0792729a9c252e798f16ed199c2eca2b8933b97d6b941ec99a16fdd1255e2beea8ec1f1380b22ef397b26af
|
||||
DIST gentoo-kernel-modprep-7.1.7.tar.xz 10048460 BLAKE2B e1b8eb82746d36f7450cc56dccd6366b14a4022c888caaf81a4b8521ac8cb31bd14fb4df68a2f4e3ab2fe739764d8ecbf48c56207773dc05b192e153282c08b8 SHA512 46ef0d154fd3852e098ae3479a4c3e02ecdd16d75a52567664766fe3ea0c682d58d01ccbe97a1d44b68aabe52c51d45a101fae9fd0002200f2f63ecefce31b61
|
||||
DIST gentoo-kernel-modprep-7.1.8.tar.xz 10042024 BLAKE2B f91ccea29e26710ea417b9cc1eb5249cda92f249d6d8de2e65e0d50d64c5f426a17f5a3470d28bda8dae3a685c405fc856ebeb1afddde3f620b5d4dcd9e57e79 SHA512 d6ccf61ce6725d542866e773084255691005775b1030b778d78731bfd75a376674c5522b994ab7fa3014890d0bf21ab5eb46a099b4632461e117ce1b5429070e
|
||||
DIST linux-6.1.tar.xz 134728520 BLAKE2B ae60257860b2bd1bd708d183f0443afc60ebbd2b3d535c45e44c2e541bd0928530a3b62de6385dd4e4726ebbedcc0a871d4f3ffb4105b9f1f6d8ed7467f5688e SHA512 6ed2a73c2699d0810e54753715635736fc370288ad5ce95c594f2379959b0e418665cd71bc512a0273fe226fe90074d8b10d14c209080a6466498417a4fdda68
|
||||
@@ -27,5 +28,6 @@ DIST patch-6.12.103.xz 5533296 BLAKE2B 050d3cc4bec3105b33085731e64ba982ab6200dbe
|
||||
DIST patch-6.18.43.xz 2996272 BLAKE2B 0f6f62177e1d45877c4d5169dad95668c742534c2c516a4aac66b7cfa0e2888d845453840fa1aad81d58d48fdc8b22736d77a9453e0faa4c4e513af39a2ed25d SHA512 d9850924efd1df2854d40b68433e986fef6462942ca2273cbaae46d85854c9888078ab633bc83005f90b896f994f7cb261ca54cf49269c1e696385de048e109b
|
||||
DIST patch-6.18.44.xz 3097408 BLAKE2B 43b7b84b6be495c65b737fb136feeff40cecc6a6c4a67229d16312bcd35d522324a6459d644a3d03209598dc05881c1a953c52b200c0cdf46a17157c47f2119f SHA512 e3e46ca232c491d1579a1c94c219908886198decaa3eb069011aa9012a0ed9ae65103787755149745ef76aa3920cb97b09329b8c87e1e2f7f2b4189993f617de
|
||||
DIST patch-6.6.150.xz 6683732 BLAKE2B a8058aff8d1108ef95dcbd5810aca2783b01c63b21d419bc02f611cf46f243e8a9fa5ec7b49c57d7a75199b662578a8a85945ca64b3ab2be081e248aa89fa4d1 SHA512 4ecfe8a28de9cb6834ee63e32c80a9abff8e4f2e5693b59750e3f9ed5069788ad5ab464e98c54ce6a66b4cab0197fb9753e09b7da3d1f826f5444faf6d99b107
|
||||
DIST patch-6.6.151.xz 6794752 BLAKE2B e15aded5ee89b19b95d2229bd88c9c959f2995cc695dd9561363dbfd2fdc53bfd7a0fb23bf61b8ab5b087cf39266e5ef27519d891c70ec0b04909e98425dc584 SHA512 fe1a1b33985e65fc918de20632742bd0eb7efbe5a4f3baff16e089a1d37bf2dc70e537e67d1dc7b5f575dbcd57c6def9b0d24ae6ac64620acbdf3bf02d5ec29d
|
||||
DIST patch-7.1.7.xz 1104868 BLAKE2B 6f538ea0e56c203170d7f0e64630716ae83e668c6419ec04350c0ca8f0a4f97c63bce2e81fcb2867cd7599160338864f0006ac44c074a5021a7d392f3aae6fe3 SHA512 ec8107785cc22510ff8fca179ef837fb7dd2db2a7c11b31f3e859dbd77170419d5f5f72837bcba8e3a3c617c19707a04c841aa373c60aceeab86329860c7a5cd
|
||||
DIST patch-7.1.8.xz 1241320 BLAKE2B 8a364fe7cba72c1ae5d9c0784304aed681359d52840b7482cce46874cf478bb2d19d31b21e42ac977c048042b78601482e287513820bcb07fa328fc5b23d233d SHA512 15477b52f1c36e42d38486037b721bca075d8312d09b108c2628e14137fed6aeb9ed641035adae0f40d3fed9a231f8a315c7d163bb599d319714464963d8626d
|
||||
|
||||
@@ -0,0 +1,177 @@
|
||||
# Copyright 2020-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit dist-kernel-utils toolchain-funcs verify-sig
|
||||
|
||||
BASE_P=linux-${PV%.*}
|
||||
PATCH_PV=${PV%_p*}
|
||||
PATCHSET=linux-gentoo-patches-6.6.145
|
||||
SHA256SUM_DATE=20260809
|
||||
|
||||
DESCRIPTION="Minimal subset of gentoo-kernel-bin for building modules, for containers"
|
||||
HOMEPAGE="
|
||||
https://wiki.gentoo.org/wiki/Project:Distribution_Kernel
|
||||
https://www.kernel.org/
|
||||
"
|
||||
SRC_URI+="
|
||||
https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${BASE_P}.tar.xz
|
||||
https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/patch-${PATCH_PV}.xz
|
||||
https://distfiles.gentoo.org/pub/proj/dist-kernel/patchsets/$(ver_cut 1-2)/${PATCHSET}.tar.xz
|
||||
https://distfiles.gentoo.org/pub/proj/dist-kernel/binpkg/modprep/$(ver_cut 1-2)/${P}.tar.xz
|
||||
verify-sig? (
|
||||
https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/sha256sums.asc
|
||||
-> linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc
|
||||
)
|
||||
"
|
||||
S=${WORKDIR}
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT=${PV}
|
||||
KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
|
||||
|
||||
RDEPEND="
|
||||
virtual/libelf
|
||||
!sys-kernel/gentoo-kernel-bin:${SLOT}
|
||||
"
|
||||
PDEPEND="
|
||||
>=virtual/dist-kernel-${PV}
|
||||
"
|
||||
BDEPEND="
|
||||
app-alternatives/bc
|
||||
app-alternatives/lex
|
||||
app-alternatives/yacc
|
||||
dev-util/pahole
|
||||
virtual/libelf
|
||||
verify-sig? ( >=sec-keys/openpgp-keys-kernel-20250702 )
|
||||
"
|
||||
|
||||
KV_LOCALVERSION='-gentoo-dist-bin'
|
||||
KV_FULL=${PV/_p/-p}${KV_LOCALVERSION}
|
||||
|
||||
VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kernel.org.asc
|
||||
|
||||
src_unpack() {
|
||||
if use verify-sig; then
|
||||
cd "${DISTDIR}" || die
|
||||
verify-sig_verify_signed_checksums \
|
||||
"linux-$(ver_cut 1).x-sha256sums-${SHA256SUM_DATE}.asc" \
|
||||
sha256 "${BASE_P}.tar.xz patch-${PATCH_PV}.xz"
|
||||
cd "${WORKDIR}" || die
|
||||
fi
|
||||
|
||||
unpack "${BASE_P}.tar.xz" "patch-${PATCH_PV}.xz" "${PATCHSET}.tar.xz"
|
||||
local pkg_arch=${ARCH}
|
||||
[[ ${ARCH} == ppc64 ]] && pkg_arch=ppc64le
|
||||
tar -x -f "${DISTDIR}/${P}.tar.xz" "${P}/${pkg_arch}" || die
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
local patch
|
||||
cd "${BASE_P}" || die
|
||||
eapply "${WORKDIR}/patch-${PATCH_PV}"
|
||||
eapply "${WORKDIR}/${PATCHSET}"
|
||||
|
||||
default
|
||||
|
||||
# add Gentoo patchset version
|
||||
local extraversion=${PV#${PATCH_PV}}
|
||||
sed -i -e "s:^\(EXTRAVERSION =\).*:\1 ${extraversion/_/-}:" Makefile || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# force ld.bfd if we can find it easily
|
||||
local HOSTLD="$(tc-getBUILD_LD)"
|
||||
if type -P "${HOSTLD}.bfd" &>/dev/null; then
|
||||
HOSTLD+=.bfd
|
||||
fi
|
||||
local LD="$(tc-getLD)"
|
||||
if type -P "${LD}.bfd" &>/dev/null; then
|
||||
LD+=.bfd
|
||||
fi
|
||||
tc-export_build_env
|
||||
local makeargs=(
|
||||
V=1
|
||||
WERROR=0
|
||||
|
||||
HOSTCC="$(tc-getBUILD_CC)"
|
||||
HOSTCXX="$(tc-getBUILD_CXX)"
|
||||
HOSTLD="${HOSTLD}"
|
||||
HOSTAR="$(tc-getBUILD_AR)"
|
||||
HOSTCFLAGS="${BUILD_CFLAGS}"
|
||||
HOSTLDFLAGS="${BUILD_LDFLAGS}"
|
||||
|
||||
CROSS_COMPILE=${CHOST}-
|
||||
AS="$(tc-getAS)"
|
||||
CC="$(tc-getCC)"
|
||||
LD="${LD}"
|
||||
AR="$(tc-getAR)"
|
||||
NM="$(tc-getNM)"
|
||||
STRIP="$(tc-getSTRIP)"
|
||||
OBJCOPY="$(tc-getOBJCOPY)"
|
||||
OBJDUMP="$(tc-getOBJDUMP)"
|
||||
READELF="$(tc-getREADELF)"
|
||||
|
||||
# we need to pass it to override colliding Gentoo envvar
|
||||
ARCH="$(tc-arch-kernel)"
|
||||
|
||||
O="${WORKDIR}"/modprep
|
||||
)
|
||||
|
||||
local kernel_dir=( "${P}"/*/usr/src/"linux-${KV_FULL}" )
|
||||
|
||||
mkdir modprep || die
|
||||
cp "${kernel_dir}/.config" modprep/ || die
|
||||
emake -C "${BASE_P}" "${makeargs[@]}" modules_prepare
|
||||
}
|
||||
|
||||
src_install() {
|
||||
local rel_kernel_dir=/usr/src/linux-${KV_FULL}
|
||||
local pkg_dir=( "${P}"/* )
|
||||
local kernel_dir="${pkg_dir}/usr/src/linux-${KV_FULL}"
|
||||
local image="${kernel_dir}/$(dist-kernel_get_image_path)"
|
||||
local uki="${image%/*}/uki.efi"
|
||||
|
||||
mv "${pkg_dir}"/lib "${ED}"/ || die
|
||||
cd "${kernel_dir}" || die
|
||||
insinto "${rel_kernel_dir}"
|
||||
doins System.map Module.symvers
|
||||
doins -r certs include scripts
|
||||
|
||||
local kern_arch=$(tc-arch-kernel)
|
||||
insinto "${rel_kernel_dir}/arch/${kern_arch}"
|
||||
doins -r "arch/${kern_arch}/include"
|
||||
|
||||
# Add the identifier
|
||||
echo "${CATEGORY}/${PF}:${SLOT}" > "${ED}${rel_kernel_dir}/dist-kernel" || die
|
||||
|
||||
cd "${WORKDIR}/${BASE_P}" || die
|
||||
insinto "${rel_kernel_dir}"
|
||||
doins -r include
|
||||
|
||||
# remove everything but Makefile* and Kconfig*
|
||||
find -type f '!' '(' -name 'Makefile*' -o -name 'Kconfig*' ')' \
|
||||
-delete || die
|
||||
find -type l -delete || die
|
||||
cp -p -R * "${ED}${rel_kernel_dir}/" || die
|
||||
|
||||
# strip out-of-source build stuffs from modprep
|
||||
# and then copy built files
|
||||
cd "${WORKDIR}" || die
|
||||
find modprep -type f '(' \
|
||||
-name Makefile -o \
|
||||
-name '*.[ao]' -o \
|
||||
'(' -name '.*' -a -not -name '.config' ')' \
|
||||
')' -delete || die
|
||||
rm modprep/source || die
|
||||
cp -p -R modprep/. "${ED}${rel_kernel_dir}"/ || die
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
dist-kernel_update_lib_symlinks
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
dist-kernel_update_src_symlink "${EROOT}/usr/src/linux" "${KV_FULL}"
|
||||
}
|
||||
Reference in New Issue
Block a user