www-client/falkon: 25.08.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

www-client/falkon/Manifest

@@ -1,2 +1,3 @@
 DIST falkon-25.04.3.tar.xz 2706120 BLAKE2B 72f0f474ba87dbb7b1bc6f4e100f94394c24412543d72f8963f0ac9c99f977a4ee13a69ae3799d51d99dffbd3919d7ad54c45a5fee5fcfa82c99427076822136 SHA512 3abc885ef11624b0eb44c8760fe6fbdf5b1a29951a9c7f04d989134a5536c119ff8445f22487feb0f3e1488ef27a85f6225726318a67d85216828f6618d60a2c
 DIST falkon-25.08.0.tar.xz 2698532 BLAKE2B 13050c2cee6762d0a95af6be43e673e487d43ca8c5faca4ad55a76f46ab52ee78701ecac81b2ed8bc259509fc91d9303d5ad5850e8c2e2cdb9994b6803f5ba1c SHA512 1ee956303bc54453e127ad9c54f7bf2f7d643c1e5778f64a8f5244f8257076da4a41f4a79a8279deafa285bbd4d39d807a1c268b699c493fe92480273a375356
+DIST falkon-25.08.1.tar.xz 2698488 BLAKE2B 8cef7a48cd71101136b99f6d248bcf5e7b68065b22dafd981ecf784f5c6aa3907fba8175f70ab4079f22b29cc82c111c0a8da9cf36467f19cc37e3f4e5108065 SHA512 28fed49f0ca37f15bb4760b4e4f66dc0097d74ea54751c119e24176d452b1aa687f496cc7b1577cfae481b2f1a0b8dc40a09eca9db49eea84e83ffe7be574f95

www-client/falkon/falkon-25.08.1.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=6.16.0
+QTMIN=6.9.1
+PYTHON_COMPAT=( python3_{10..13} )
+inherit ecm gear.kde.org python-single-r1 xdg
+
+DESCRIPTION="Cross-platform web browser using QtWebEngine"
+HOMEPAGE="https://www.falkon.org/ https://apps.kde.org/falkon/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="dbus kde python +X"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="test" # bug 653046
+
+COMMON_DEPEND="
+	dev-libs/openssl:0=
+	>=dev-qt/qt5compat-${QTMIN}:6
+	>=dev-qt/qtbase-${QTMIN}:6[dbus?,gui,network,sql,sqlite,ssl,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6[widgets]
+	>=dev-qt/qtwebchannel-${QTMIN}:6
+	>=dev-qt/qtwebengine-${QTMIN}:6=[widgets]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	virtual/libintl
+	kde? (
+		>=kde-frameworks/kcoreaddons-${KFMIN}:6
+		>=kde-frameworks/kcrash-${KFMIN}:6
+		>=kde-frameworks/kio-${KFMIN}:6
+		>=kde-frameworks/kjobwidgets-${KFMIN}:6
+		>=kde-frameworks/kwallet-${KFMIN}:6
+		>=kde-frameworks/purpose-${KFMIN}:6
+	)
+	python? (
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep "
+			>=dev-python/pyside-${QTMIN}:6[gui,positioning,uitools(-),webengine,widgets,\${PYTHON_USEDEP}]
+		")
+	)
+	X? (
+		x11-libs/libxcb:=
+		x11-libs/xcb-util
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent]
+"
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	DEPEND+=" >=kde-frameworks/ki18n-${KFMIN}:6"
+fi
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtsvg-${QTMIN}:6
+"
+BDEPEND=">=dev-qt/qttools-${QTMIN}:6[linguist]"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_KEYRING=OFF
+		-DDISABLE_DBUS=$(usex !dbus)
+		$(cmake_use_find_package kde KF6Wallet)
+		$(cmake_use_find_package kde KF6KIO)
+		-DBUILD_PYTHON_SUPPORT=$(usex python)
+		-DNO_X11=$(usex !X)
+	)
+	use python && mycmakeargs+=(
+		-DPYTHON_CONFIG_SUFFIX="-${EPYTHON}" # shiboken_helpers.cmake quirk
+		-DPython3_INCLUDE_DIR=$(python_get_includedir)
+		-DPython3_LIBRARY=$(python_get_library_path)
+	)
+	ecm_src_configure
+}