app-emacs/org-mode: bump to 9.7.25

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/org-mode/Manifest

@@ -3,3 +3,4 @@ DIST org-mode-release_9.7.21.tar.gz 2364695 BLAKE2B 1cd3fe37ecfe4450dce69dd7499b
 DIST org-mode-release_9.7.22.tar.gz 2364662 BLAKE2B 10a60b241fc87b141f3c6ea07bd99aae464fcf5bcaaf667c0a2340da85b711118d28059831a27d3eafacfedd1c7119162fdfb4cf19f42c9e46ac650d0afa56ce SHA512 7fb8f141315fa22ab5b87bcf16d104377b3309b1e25a88e93c5f088238112dfe726bd3b28d35530c0f1c7684c42967028e469b1767638ddff89bb891b6922d2f
 DIST org-mode-release_9.7.23.tar.gz 2364944 BLAKE2B dc494ea638e4fdc12868855fd39180f09fe2c20e75b225b4247cbccfa47689322c0336a4b08cd518d35a60162d6cf235624ea008636f4fc89abcee0e7aa5248b SHA512 b0f821adc14e14d6ea38086b083a1983808f441989374cf57a561835a5312d18011a41d68ae1d0fe2f611ab941299bf63108baba2eb1e36624fd8e15fef686a1
 DIST org-mode-release_9.7.24.tar.gz 2364959 BLAKE2B d62a5a3269101218eec757ecc0140b2652319d22804b28bc856335a48742da0284e9d5923000431c70c1e8a4fd84a87a460a602f673bbbc810dffc199ab41b6d SHA512 c24d6864ef3cfd883c5de93eaf409fdde326392261d254af8da9bb4d15db6cbfae415a90e5397b6f35cb13ac43ca045d27589a60176e0be412c82119c535dcb8
+DIST org-mode-release_9.7.25.tar.gz 2365003 BLAKE2B 4e83df1b08eb658e940699f18e49348fcc7c1f470b08172e036ed9ed083887be35c29f98438c9ad06b1cc7ac7d39d6f75ab1abe855abcf96f2a86eb193bf50c0 SHA512 c36135e7a4c5a18dd0577d49335899a6728fab4ce179d3bfbbe7c51b6ee717e607fa0b4bc24ae958b7cb5654121d1eb741cc6011af8cb28d9b2a8fec18eadcb9

app-emacs/org-mode/org-mode-9.7.25.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="An Emacs mode for notes and project planning"
+HOMEPAGE="https://orgmode.org/"
+
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}.git"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/org"
+	S="${WORKDIR}/org"
+else
+	MY_P="${PN}-release_${PV}"
+	SRC_URI="https://git.savannah.gnu.org/cgit/emacs/${PN}.git/snapshot/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
+SLOT="0"
+IUSE="doc odt-schema"
+RESTRICT="test"
+
+BDEPEND="
+	doc? ( virtual/texi2dvi )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	# Remove failing tests.
+	rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell}.el || die
+}
+
+src_compile() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}"
+
+	use doc && emake -j1 pdf card
+}
+
+src_install() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		DESTDIR="${D}" \
+		ETCDIRS="styles csl $(use odt-schema && echo schema)" \
+		lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}" \
+		infodir="${EPREFIX}/usr/share/info" \
+		install
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	dodoc README.org CONTRIBUTE.org etc/ORG-NEWS
+	use doc && dodoc doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
+
+	local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
+		so you may have to install one or more additional packages.
+		A non-exhaustive list of these dependencies may be found at
+		<http://orgmode.org/worg/org-dependencies.html>."
+	readme.gentoo_create_doc
+}