dev-python/keyrings_alt: Version bump to 2.3

Package-Manager: Portage-2.3.8, Repoman-2.3.3

dev-python/keyrings_alt/Manifest

@@ -1 +1,2 @@
 DIST keyrings.alt-2.2.tar.gz 26121 SHA256 f438bd6e9f1b413b8926b0568fc8aaf2f773fa5b75fed4fb49091c5b32ad85a6 SHA512 28d29c1f3f0a9612baa61d4506f0ac0782105a0c04ca2d9be63bd3106c82c2478487a42f2d5396d2f5e5d7205ae4f2d43221dba6ce6587e6e807d597984c833b WHIRLPOOL 0b21017adda12d7f5390b4be8e58936890fe44825b82c31e709e0926739d847e2160c1389b47632dfd48df2c501f7c219463372cc5b78875281f50c7d442a18d
+DIST keyrings.alt-2.3.tar.gz 26170 SHA256 5cb9b6cdb5ce5e8216533e342d3e1b418ddd210466834061966d7dc1a4736f2d SHA512 593194f0b3e64ebab9950b1ee674e43afecf6410110e7c683cdccaa121eaaff864ef07763363c0b0ac25b94e913d6ba2e1bb1ebb428ba14e81e3c29335b81807 WHIRLPOOL 1d9dad28ed5aaa5e71647a578f75659146397a8fb97840d1307976f6a585b414402b0f98dac8a9d6e5d969eedc6ea752cee75192a8ed670300245c2feb0cc939

dev-python/keyrings_alt/keyrings_alt-2.3.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_{4,5,6}} pypy )
+
+inherit distutils-r1
+
+MY_PN="${PN/_/.}"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Alternate keyring implementations"
+HOMEPAGE="https://github.com/jaraco/keyrings.alt https://pypi.python.org/pypi/keyrings.alt"
+SRC_URI="mirror://pypi/${P:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="dev-python/six[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/fs-0.5[${PYTHON_USEDEP}]
+		<dev-python/fs-2[${PYTHON_USEDEP}]
+		dev-python/gdata[$(python_gen_usedep 'python2*')]
+		dev-python/keyczar[$(python_gen_usedep 'python2*')]
+		dev-python/pycrypto[$(python_gen_usedep 'python*')]
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)"
+
+S=${WORKDIR}/${MY_P}
+
+# Multiple failures
+RESTRICT=test
+
+python_prepare_all() {
+	sed \
+		-e "s:find_packages():find_packages(exclude=['tests']):g" \
+		-i setup.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	py.test -v -v || die
+}