net-misc/electrum: Bump to 4.0.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

net-misc/electrum/Manifest

@@ -1 +1,2 @@
 DIST Electrum-3.3.8.tar.gz 8911228 BLAKE2B af24f44f5805a5722d0b9500776ae1ea4f70e0869045535ea3bf27d24a61013ba718230e6292061581f55a4fae655cbacae9024a321efe655eb9816bae11ae75 SHA512 5f756da4d2df59c69997925c69f651011def07bfbdbc582f492ecc19386eee7d79b9951732a792e6041da902d776052d6590cbd2d7004bc93c8406bcf9093fe6
+DIST electrum-4.0.2.gh.tar.gz 4395620 BLAKE2B 27d5e74ea85d792f73a01d41528dc9a84af374d672e7c7101a82e18634a32d7ebdb039571bde36625b460c6c7634ec75848711dc4cabfbd1be46f16d18e35df2 SHA512 8b03d60cb549315c9f8a2cb4f02e3a483b8e8f9ee0461bb9d54acca0d9cf96d38a158bb6bccdb1bb584fd5a3f4fd8ffbcb0d45244f41dc5636689adb514f1681

net-misc/electrum/electrum-4.0.2.ebuild

@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="ncurses?"
+
+inherit desktop distutils-r1 xdg-utils
+
+DESCRIPTION="User friendly Bitcoin client"
+HOMEPAGE="https://electrum.org/"
+SRC_URI="
+	https://github.com/spesmilo/electrum/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cli ncurses qrcode +qt5"
+REQUIRED_USE="|| ( cli ncurses qt5 )"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/libsecp256k1
+	>=dev-python/aiohttp-socks-0.3[${PYTHON_USEDEP}]
+	=dev-python/aiorpcX-0.18*[${PYTHON_USEDEP}]
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	dev-python/bitstring[${PYTHON_USEDEP}]
+	<dev-python/dnspython-2[${PYTHON_USEDEP}]
+	>=dev-python/ecdsa-0.14[${PYTHON_USEDEP}]
+	dev-python/pbkdf2[${PYTHON_USEDEP}]
+	dev-python/pyaes[${PYTHON_USEDEP}]
+	dev-python/PySocks[${PYTHON_USEDEP}]
+	dev-python/qrcode[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/protobuf-python-3.12[${PYTHON_USEDEP}]
+	qrcode? ( media-gfx/zbar[v4l] )
+	qt5? (
+		dev-python/PyQt5[gui,widgets,${PYTHON_USEDEP}]
+	)
+	ncurses? ( $(python_gen_impl_dep 'ncurses') )
+	|| (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	test? (
+		dev-python/cryptography[${PYTHON_USEDEP}]
+		dev-python/pycryptodome[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	eapply "${FILESDIR}/3.1.2-no-user-root.patch"
+	eapply "${FILESDIR}/3.3.2-desktop.patch"
+
+	# Prevent icon from being installed in the wrong location
+	sed -i '/icons_dirname/d' setup.py || die
+
+	# use backwards-compatible cryptodome API
+	sed -i -e 's:Cryptodome:Crypto:' electrum/crypto.py || die
+
+	local bestgui
+	if use qt5; then
+		bestgui=qt
+	elif use ncurses; then
+		bestgui=text
+	else
+		bestgui=stdio
+	fi
+	sed -i 's/^\([[:space:]]*\)\(config_options\['\''cwd'\''\] = .*\)$/\1\2\n\1config_options.setdefault("gui", "'"${bestgui}"'")\n/' ${PN}/${PN} || die
+
+	eapply_user
+
+	xdg_environment_reset
+	distutils-r1_src_prepare
+}
+
+src_install() {
+	doicon -s 128 electrum/gui/icons/${PN}.png
+	dodoc RELEASE-NOTES
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}