kde-apps/dolphin-plugins-git: 26.08.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/dolphin-plugins-git/Manifest

@@ -1 +1,2 @@
 DIST dolphin-plugins-26.04.3.tar.xz 338640 BLAKE2B 05facd15b7756f0ab3e56f07093dae40e2c81396c7002cf9b1284dde23d4a8d0b76ac3cea856bd6d19770347488d235acf5c9942c0c3792a69e758fdbb477fe5 SHA512 6d83b395a5ce23ecbbf22a35448b00822ea43e5cf9c8df8e68a63a35b9dd8337af8b3eb47fe5816abff0bbe1a5f66852fc6625acff2e717351335228cba35412
+DIST dolphin-plugins-26.08.0.tar.xz 347020 BLAKE2B 7275cdf684773f3d58b39ec867d0a42d97ae8004db65d34fc6fd3f9676d37ac314473af5c0718cdfe98673df5faa1c71e67ffc7c11ce1c4d44df5241f611b3e3 SHA512 b282f455872037deca6a15686c2877b1dfefd4b4a1483ee7c201302bf91e7b4f676dd75018f2fe09e82b57016bdb9258e091ec12b7f8972eafc3e62c5457eae3

kde-apps/dolphin-plugins-git/dolphin-plugins-git-26.08.0.ebuild

@@ -0,0 +1,59 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+KDE_ORG_NAME="dolphin-plugins"
+MY_PLUGIN_NAME="git"
+PVCUT=$(ver_cut 1-3)
+KFMIN=6.27.0
+QTMIN=6.11.2
+inherit ecm gear.kde.org
+
+DESCRIPTION="Dolphin plugin for Git integration"
+HOMEPAGE="https://apps.kde.org/dolphin_plugins/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE=""
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[concurrent,gui,widgets]
+	>=kde-apps/dolphin-${PVCUT}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	dev-vcs/git
+	>=kde-apps/dolphin-plugins-common-${PV}
+"
+
+src_prepare() {
+	ecm_src_prepare
+	ecm_punt_po_install
+	# solid, qtdbus only required by mountiso
+	ecm_punt_qt_module DBus
+	ecm_punt_kf_module Solid
+	# kxmlgui, qtnetwork only required by dropbox
+	ecm_punt_qt_module Network
+	ecm_punt_kf_module XmlGui
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_${MY_PLUGIN_NAME}=ON
+		-DBUILD_bazaar=OFF
+		-DBUILD_dropbox=OFF
+		-DBUILD_hg=OFF
+		-DBUILD_makefileactions=OFF
+		-DBUILD_mountiso=OFF
+		-DBUILD_mountedisooverlay=OFF
+		-DBUILD_svn=OFF
+	)
+	ecm_src_configure
+}