net-wireless/gnome-bluetooth: Version bump to 42.5

Signed-off-by: Matt Turner <mattst88@gentoo.org>

net-wireless/gnome-bluetooth/Manifest

@@ -1,2 +1,3 @@
 DIST gnome-bluetooth-3.34.5.tar.xz 353936 BLAKE2B 40300752830f71d436591e22a64a282745d8419ee46de534f76c4871a86a4c8f7b2203e3ddc4ca08d26348b97bf4a68315802ffa09c69265c55001e4806c7f1e SHA512 48431b3d19083705a6623442c5cd2d6c14962cdf30fc599ba47dceb6612b80142af77e1b6df142b530cb1015638081a06de38a3034177e0d05a354c40f19d9e5
 DIST gnome-bluetooth-42.4.tar.xz 304048 BLAKE2B 7451c893496f04e38d36ba93aa7c9650144c020bf1ce156e11fbf62a3a2d5ee637ebdea2b397ee2affb96da8568a6f7456c5fb181a9c752b5deb7e14371f9e84 SHA512 5dab59e6ba3e291cb7630b6bc2da3a776ad044565ace3b9fcc30c357f2740f4ba73fca23a099b1717f8d181a3af67b33c0934a35cd680a149c2168e2380410aa
+DIST gnome-bluetooth-42.5.tar.xz 304040 BLAKE2B a860ab3916e2064025a2310a874719e32f80e4f7953146222b62b0e3637cb221c72670191561e27891c1b87fbcf5571a69a56e9fef4c655e6495e4b72d704ace SHA512 0606b1a6053bc03568a492b4f000154e9a12ef9e9f7222837ae26635c446a0dc14f92ed2ca7bb2a262c4d87f369c05f6e0e75593abc45f513785197319848967

net-wireless/gnome-bluetooth/gnome-bluetooth-42.5.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..11} )
+inherit gnome.org meson python-any-r1 xdg
+
+DESCRIPTION="Bluetooth graphical utilities integrated with GNOME"
+HOMEPAGE="https://wiki.gnome.org/Projects/GnomeBluetooth"
+
+LICENSE="GPL-2+ LGPL-2.1+ FDL-1.1+"
+SLOT="3/13" # subslot = libgnome-bluetooth-3 soname version
+IUSE="gtk-doc +introspection sendto test"
+RESTRICT="!test? ( test )"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+
+DEPEND="
+	>=dev-libs/glib-2.44:2
+	>=gui-libs/gtk-4.4:4[introspection?]
+	media-libs/gsound
+	>=gui-libs/libadwaita-1.1:1
+	>=x11-libs/libnotify-0.7.0
+	virtual/libudev:=
+	>=sys-power/upower-0.99.14:=
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+RDEPEND="${DEPEND}
+	acct-group/plugdev
+	virtual/udev
+	>=net-wireless/bluez-5
+	sendto? ( !net-wireless/gnome-bluetooth:2 )
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	gtk-doc? ( >=dev-util/gtk-doc-1.9 )
+	virtual/pkgconfig
+	test? (
+		$(python_gen_any_dep '
+			>=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]
+			dev-python/dbus-python[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	if use test; then
+		python_has_version ">=dev-python/python-dbusmock-0.26.0[${PYTHON_USEDEP}]" &&
+		python_has_version "dev-python/dbus-python[${PYTHON_USEDEP}]"
+	fi
+}
+
+pkg_setup() {
+	# Check for python is unconditional
+	python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use sendto)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+}