sci-visualization/tensorboard: bump 2.8.0

Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Jason Zaman <perfinion@gentoo.org>

sci-visualization/tensorboard/Manifest

@@ -1,2 +1,3 @@
 DIST tensorboard-2.5.0.zip 6019104 BLAKE2B f07db4fec7cc39e15c4f580f479679f0db4f06e66d81768799ed3652bb9ba63c7b61bde7f12119d09474009e55c12d91ef0f2b3aeeb05682532630314cab871a SHA512 e39ca09bd00fab9b5f6f9393e48cb6be2313f86c24b2f0ffcfd08b08b9ed4e95e7e19297bb67d8b558e1913640774f9b9d512a34153251acb9f566d6485e0f78
 DIST tensorboard-2.7.0.zip 5757617 BLAKE2B 98e67e322548f4b88448856da3a2457a6aae9ecb1540916d46a90401307f4919df37af8a3048bdb850ea78886d18423edc87fca51812f3b9489de62d3effa0fc SHA512 e9b046000250a78eab4e6e68e5cc05696254893cf7422b59d2e168d7322287501654370a797e90af7437e91b64a27743e348513bcb5571805b3f10bb2059636d
+DIST tensorboard-2.8.0.zip 5776309 BLAKE2B b06c740fbe01c707e937018184e286fb7221391715c5ca6d843a89c9dd3a364b8693e748ccbde735d074b0abdbca65d4e2dd9a6e57b4ede61f78a661bd16e702 SHA512 3d937e41ac0abfe44cfab12f0b5269de45615c512499107a239bb348df7f3ccaabf283afcea2a7bac4a34d7b9318947c709a84154d0d2e61912138c31c86673f

sci-visualization/tensorboard/tensorboard-2.8.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8,9} )
+inherit python-r1
+
+DESCRIPTION="TensorFlow's Visualization Toolkit"
+HOMEPAGE="https://www.tensorflow.org/"
+SRC_URI="https://files.pythonhosted.org/packages/py3/${PN::1}/${PN}/${P}-py3-none-any.whl -> ${P}.zip"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+RDEPEND="
+	${PYTHON_DEPS}
+	dev-python/bleach[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-1.6.3[${PYTHON_USEDEP}]
+	>=dev-python/google-auth-oauthlib-0.4.1[${PYTHON_USEDEP}]
+	dev-python/grpcio[${PYTHON_USEDEP}]
+	dev-python/html5lib[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/numpy[${PYTHON_USEDEP}]
+	dev-python/protobuf-python[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	dev-python/werkzeug[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.4.1[${PYTHON_USEDEP}]"
+BDEPEND="app-arch/unzip
+	${PYTHON_DEPS}"
+PDEPEND="sci-libs/tensorflow[python,${PYTHON_USEDEP}]"
+
+S="${WORKDIR}"
+
+src_prepare() {
+	eapply_user
+
+	sed -i -e '/_vendor.__init__/d' -e '/_vendor.bleach/d' -e '/_vendor.html5lib/d' -e '/_vendor.webencodings/d' \
+		"${S}/${P}.dist-info/RECORD" || die "failed to unvendor"
+	grep -q "_vendor" "${S}/${P}.dist-info/RECORD" && die "More vendored deps found"
+
+	find "${S}/${PN}" -name '*.py' -exec sed -i \
+		-e 's/^from tensorboard\._vendor import /import /' \
+		-e 's/^from tensorboard\._vendor\./from /' \
+		{} + || die "failed to unvendor"
+
+	rm -rf "${S}/${PN}/_vendor" || die
+
+	sed -i -e '/tensorboard-plugin-/d' "${S}/${P}.dist-info/METADATA" || die "failed to remove plugin deps"
+	sed -i -e '/tensorboard-data-server/d' "${S}/${P}.dist-info/METADATA" || die "failed to remove data-server deps"
+}
+
+src_install() {
+	do_install() {
+		python_domodule "${PN}"
+		python_domodule "${P}.dist-info"
+	}
+	python_foreach_impl do_install
+}