sys-apps/fwts: Upgrade FWTS to 24.03

Signed-off-by: Jakub Czapiga <mordijc@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/36098
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

sys-apps/fwts/Manifest

@@ -1,2 +1,3 @@
 DIST fwts-23.11.00.tar.gz 3962015 BLAKE2B 33afde1548629fda784b301b42c7ca3ae4c17deb86909b0534f839ba369dae74fc0f7a3c2f4b50a2ad101da9debcb522326b649ba811b7f13c8cf7b79d552f26 SHA512 df72a799a7e317f53bd43c35953a8955aa194a93596eacab43300717d87dac4aef3bdfcdb1b2028c0177a3f40577dd0e4a55e5c3269e37190a47684df928b092
+DIST fwts-24.03.00.tar.gz 3967205 BLAKE2B db2d326404d5b4e0c04eb025ba42f43696825535e37058c11b569afa3c1e6317783b15aae2819d504edbbd2227408fd98b8a5d2012a683ca5983c1c1ed892135 SHA512 5d414f4e819148e789b30c0cdccf016fceb51d93d61edcee632bc4727773186380fbdf6f6522ae50e385dac8d59ebcd7f424b5ff030ffb9b8c9d775710d7e135
 DIST fwts_22.03.00.orig.tar.gz 3900335 BLAKE2B 2e36392f69140b1a2d3b77cc8d57740f66ea016063644916e69bb738e20191a780a9d2ed275cfd8b871ad8c3455f96c8ae26ab7c1574c0cc8efdbbb20f4cc785 SHA512 88f183293da4f6ebc1cefc382c9b5e1b378ac7d03e0c577937db89be9e8417e0ffdf0952cdffda57ac21787c3fe02c5254ec7ce61e100e78555ffa92d6a30dc2

sys-apps/fwts/fwts-24.03.00.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Firmware Test Suite"
+HOMEPAGE="https://wiki.ubuntu.com/Kernel/Reference/fwts https://github.com/fwts/fwts"
+SRC_URI="https://github.com/fwts/fwts/archive/refs/tags/V${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# https://bugs.launchpad.net/fwts/+bug/2047906 (bug #795051)
+KEYWORDS="~amd64"
+
+DEPEND="dev-libs/glib:2
+	>=dev-libs/json-c-0.10-r1
+	dev-libs/libbsd
+	dev-libs/libpcre
+	sys-apps/dmidecode
+	sys-apps/dtc
+	sys-apps/pciutils
+	sys-power/iasl
+	sys-power/pmtools
+"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-22.03.00-werror.patch"
+)
+
+src_prepare() {
+	default
+
+	sed -e 's:/usr/bin/lspci:'$(type -p lspci)':' \
+		-e 's:/usr/sbin/dmidecode:'$(type -p dmidecode)':' \
+		-e 's:/usr/bin/iasl:'$(type -p iasl)':' \
+		-i src/lib/include/fwts_binpaths.h || die
+
+	eautoreconf
+}
+
+src_compile() {
+	# https://github.com/fwts/fwts/issues/7 (bug #870109)
+	emake -j1 --shuffle=none
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+}