gnome-extra/cinnamon-screensaver: add 6.4.0

Signed-off-by: Matthew S. Turnbull <sparky@bluefang-logic.com>
Signed-off-by: Sam James <sam@gentoo.org>

gnome-extra/cinnamon-screensaver/Manifest

@@ -1,2 +1,3 @@
 DIST cinnamon-screensaver-6.2.0.tar.gz 161045 BLAKE2B c0afe57912ed9cfc579defa4ea450c5ab79c0761f4babc9ad9c745d1c71c24ba9bcd77cd952d8e7c1ebd317025d3cf3bacc24c87e2757a94582337dc4645c814 SHA512 a7a6163be7de5fd7b58ed1aeb76610476f872f5372489a8ce724c92fa2a26ce418546ca9ae39a97dac9cf922ef13e5faf34bcbc087382db1e6fc50c02d6c8b21
 DIST cinnamon-screensaver-6.2.1.tar.gz 161088 BLAKE2B 86159f06e44bd58ca443457109c1345ba3021d1b8aa339d315da45fad994e8fccf59fffdc8bef3edefebf42a6ea4ab632354ef5a8f7c10f6d4d70ab517fce3bb SHA512 4033d1170b4ef359dc8a6d529b40e40fa5bb630f4900eaf5d45c73d7caadde00345811bc5b8f347bfc184f16abbdb232ebf71bb911c713bb00ced557115fd300
+DIST cinnamon-screensaver-6.4.0.tar.gz 160693 BLAKE2B 47e66d2d68ae10edb6b25bdd94624d7df02cb328f60eb390ced9ca31990993bea0c50af4b878ffcbc0b138d65949a0461403b8718bee29021f62f052c55049fd SHA512 286497a70b3b77f5b0f392554b7283487fee84fc3b449510232302351500f9312d6f308d3bd19d85b5f047d250aa7368413193a864e4a4ebed285ab13ad0ca4c

gnome-extra/cinnamon-screensaver/cinnamon-screensaver-6.4.0.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit meson python-single-r1 xdg
+
+DESCRIPTION="Screensaver for Cinnamon"
+HOMEPAGE="https://projects.linuxmint.com/cinnamon/ https://github.com/linuxmint/cinnamon-screensaver"
+SRC_URI="https://github.com/linuxmint/cinnamon-screensaver/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+ LGPL-2+ MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="systemd xinerama"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	${PYTHON_DEPS}
+	>=dev-libs/glib-2.37.3:2[dbus]
+	>=gnome-extra/cinnamon-desktop-6.4
+	sys-libs/pam
+	>=x11-libs/gtk+-3.22:3[introspection]
+	x11-libs/cairo
+	x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXrandr
+	x11-libs/pango
+	x11-misc/xdotool
+	x11-themes/adwaita-icon-theme
+
+	xinerama? ( x11-libs/libXinerama )
+"
+RDEPEND="
+	${COMMON_DEPEND}
+	>=app-accessibility/caribou-0.3
+	sys-apps/accountsservice
+	sys-process/procps
+	x11-apps/xprop
+	$(python_gen_cond_dep '
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/setproctitle[${PYTHON_USEDEP}]
+		>=dev-python/python3-xapp-2.4.2[${PYTHON_USEDEP}]
+	')
+
+	systemd? ( >=sys-apps/systemd-31 )
+	!systemd? ( sys-auth/elogind )
+"
+DEPEND="
+	${COMMON_DEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	sys-apps/dbus
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	python_fix_shebang install-scripts src
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use xinerama)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	python_optimize "${ED}"/usr/share/cinnamon-screensaver/
+}