dev-python/trimesh: Bump to 4.1.5

Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-02-24 09:49:07 +01:00
parent 6c209d09ca
commit 7fe678dc3d
2 changed files with 69 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST trimesh-4.1.3.gh.tar.gz 13438037 BLAKE2B 1aaa2ad9fc974bc335710e12381f63fc7d6c6db47b6d88e9590dba92c126dee374ebe8282df02bdd4405558b391ce836c861b0672be847c627238c9c4c6c2285 SHA512 5f9b81c9e59760ec023e0a2ceeb62fdd4308f69ebc0cb495bcb0d7b58244a6754d4016c87110509f01696b291c03838b7896f9f470fe95f99d8755781b82051a
DIST trimesh-4.1.4.gh.tar.gz 13438872 BLAKE2B b03efc741bccf3b08c9f8611dbf282d99fb8a2691d54d0230326453aa5666b69470d00fce7eccf2863c6f6939c56d74d3d537100b8def9c8660a33eabf3ba462 SHA512 bbdc3ec24d5a53e329b3b3021bec14668b1bb19e231ebb5f2ee186449e9c4ad162a14c4f42b8bdaed513ff5c874bf7ec1f0fc4bf103ee6b79ca7564494316984
DIST trimesh-4.1.5.gh.tar.gz 13440026 BLAKE2B bdf27c0ebfc24ede66ecd8ae94151cbf926e187112f096246080db34a43a23f950674a461c29d8b87a71d6b5bc8e3cc824007b54be90593ceb552e1669e41e36 SHA512 a62cdbad4a053fe6bf3d70285c2484600af09f9bc6a638214b10718bdf3c0901053bad0d25c4d7dc96f396c66fb3d438981d3fc96ea179bb078abb3d8b87695b
+68
View File
@@ -0,0 +1,68 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 optfeature
DESCRIPTION="Python library for loading and using triangular meshes"
HOMEPAGE="
https://trimesh.org/
https://github.com/mikedh/trimesh/
https://pypi.org/project/trimesh/
"
SRC_URI="
https://github.com/mikedh/${PN}/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
RDEPEND="
dev-python/chardet[${PYTHON_USEDEP}]
dev-python/colorlog[${PYTHON_USEDEP}]
dev-python/httpx[${PYTHON_USEDEP}]
dev-python/jsonschema[${PYTHON_USEDEP}]
dev-python/lxml[${PYTHON_USEDEP}]
dev-python/networkx[${PYTHON_USEDEP}]
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pycollada[${PYTHON_USEDEP}]
dev-python/pyglet[${PYTHON_USEDEP}]
dev-python/requests[${PYTHON_USEDEP}]
dev-python/scipy[${PYTHON_USEDEP}]
dev-python/setuptools[${PYTHON_USEDEP}]
>=dev-python/shapely-1.8.2[${PYTHON_USEDEP}]
dev-python/svg-path[${PYTHON_USEDEP}]
dev-python/sympy[${PYTHON_USEDEP}]
dev-python/xxhash[${PYTHON_USEDEP}]
sci-libs/rtree[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/mapbox_earcut[${PYTHON_USEDEP}]
)
"
EPYTEST_TIMEOUT=1800
EPYTEST_XDIST=1
distutils_enable_tests pytest
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
pkg_postinst() {
optfeature_header "${PN} functionality can be extended by installing the following packages:"
optfeature "making GUI applications with 3D stuff" dev-python/glooey
optfeature "2D triangulations of polygons" dev-python/mapbox_earcut
optfeature "loading a number of additional mesh formats" dev-python/meshio
optfeature "figuring out how much memory we have" dev-python/psutil
optfeature "marching cubes and other nice stuff" dev-python/scikit-image
}