x11-misc/dclock: Version 2.2.2_p12

Package-Manager: Portage-3.0.5, Repoman-3.0.1
Signed-off-by: Jeroen Roovers <jer@gentoo.org>
This commit is contained in:
Jeroen Roovers
2020-09-04 10:12:43 +02:00
parent 6bb35c69bb
commit 7fd72db804
2 changed files with 77 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST dclock_2.2.2-12.debian.tar.xz 16112 BLAKE2B 3da6a75834791cbba71d84c8d46d65b18db6a9aa97a085d984b598c8db41fe507965390568377a9167823d0b3856165e58115aa74b05da35fd6432b44ea877e9 SHA512 c6c468a378e421fb9ef2c6e84db991644888f8d2d9afe220142ea26914423387d3aed335b43fa69b38501c3d713d5540bb2efc2e52dd0db1fa1cd3d9c00c1531
DIST dclock_2.2.2-9.debian.tar.xz 15260 BLAKE2B dab41f4fe79d2ce6ef4effb466c3923c77a94bfaf4b6ca1dde5bd9b92e0d9ff9a5d89dd9b569f831e107bb62de691e24661609b61af84d1a64958de34304f9be SHA512 025d1d228930adb6e2b13226188b6c3d37aef59786f23826f301c7b22dabba5cfc24f76347fe2f199c239daea968cd043293bd60524110235855cb77c9e4d1f0
DIST dclock_2.2.2.orig.tar.gz 63583 BLAKE2B b1208439e3a689ff1e00cbdbfa7e3a559b7ec7705ab0834cf350d1ba1e3dcd01d4746e90999f6215cfa9e101a4bd8cf42ff324a307c792028479077152b5414b SHA512 c43ba031fd0d9ba2bc7e8fe9becc73591bfc47cd4ca931df03fa55207cfb148e24e5d702a7de5af8b67e188c561eae2fb7da14162f6a982d0abbb3251c32372c
+76
View File
@@ -0,0 +1,76 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs
DESCRIPTION="Digital clock for the X window system"
HOMEPAGE="https://packages.qa.debian.org/d/dclock.html"
SRC_URI="
mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p*/}.orig.tar.gz
mirror://debian/pool/main/d/${PN}/${PN}_${PV/_p/-}.debian.tar.xz
"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE="xft"
RDEPEND="
x11-libs/libX11
x11-libs/libXext
x11-libs/libXt
xft? (
media-libs/freetype
x11-libs/libXft
)
"
DEPEND="
${RDEPEND}
"
BDEPEND="
app-text/rman
x11-misc/imake
xft? ( virtual/pkgconfig )
"
S=${WORKDIR}/${P/_p*/}
PATCHES=(
"${WORKDIR}"/debian/patches
)
src_prepare() {
default
sed -i -e '/CDEBUGFLAGS/d' Imakefile || die
}
src_configure() {
if use xft; then
append-cppflags \
-DXFT_SUPPORT \
$( $(tc-getPKG_CONFIG) --cflags freetype2 )
else
append-cppflags -UXFT_SUPPORT
sed -i -e '/EXTRA_LIBRARIES/s|^|#|g' Imakefile || die
fi
xmkmf || die
}
src_compile() {
emake \
CC="$(tc-getCC)" \
CFLAGS="${CFLAGS}" \
CPPFLAGS="${CPPFLAGS}" \
EXTRA_LDOPTIONS="${LDFLAGS}"
}
src_install() {
default
emake DESTDIR="${D}" install.man
insinto /usr/share/sounds
doins sounds/*
insinto /usr/share/X11/app-defaults
newins Dclock.ad DClock
}