mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-09 06:37:10 -08:00
www-client/qutebrowser: upgrade to 2.3.0
Closes: https://bugs.gentoo.org/722702 Package-Manager: Portage-3.0.20, Repoman-3.0.3 Signed-off-by: Stefan Strogin <steils@gentoo.org>
This commit is contained in:
@@ -1,3 +1,4 @@
|
||||
DIST qutebrowser-2.1.1.tar.gz 6249239 BLAKE2B 941742728f305539b07f2c97198cb3154a2c9d60da3a25175c34875d647fae8f802deaf906ce688a3f81327560f8d9a740314cfdd8dc3aac767bd3aaec30f14d SHA512 85c81454406e25a347866984059923500a23dfe9d2427324d6998a9738962155442b69e3b6318c2683fb7790ba908e8486ea0d42073c38d7a5a1f249577c2b5d
|
||||
DIST qutebrowser-2.2.2.tar.gz 6314896 BLAKE2B e4396332b16ea71bc7dfa2d54a275b6058576f029406fd1164803447119474ac39c105e80ad45b4bdd3a217e2cf26e7b8efe76306e8f1ddcef23ebfd8bdf16f4 SHA512 ccb785374c083dbd8c6dd99d5427bbba2391c7e18a3d4453750a2a65cb4e82fdaa3065a29eef20f7a2766d9c672177ac3a0c8e6bf13b8e6dd090187986fb04c6
|
||||
DIST qutebrowser-2.2.3.tar.gz 6234298 BLAKE2B 7401241b5032bc2c98214930772a1228b9ef1cd9bdabba64295b10c7f0f8c0f336f321baeb4a25ffc7576328e9b838d6629b83c93a5c76defd4000743c4a859c SHA512 608a588ba670b60d6278bfcae324ca5c5454c4f932f7493189ae8666293a0077a2f2a0066211d080b649d180c687c14adbe075c6c92a411b88fee18446930c4e
|
||||
DIST qutebrowser-2.3.0.tar.gz 6244786 BLAKE2B 6722074efd854e70aeb40c5992277d0dad59045795c464ecea2b53fcd648b900054e9ad7d19cf2879d814624304a3827c166f495e721344ecc334aa0f49a0d39 SHA512 1f0afc642fe68d4524fa0263f8f196429710f1ae0a27edb43748a688f1eadd3dc42af82da96715b78cbe19e6d0e6c1e9604a55d6c5deb7ebc5eba97b9bfa118f
|
||||
|
||||
@@ -0,0 +1,90 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{7,8,9} )
|
||||
|
||||
inherit desktop distutils-r1 optfeature xdg-utils
|
||||
|
||||
DESCRIPTION="A keyboard-driven, vim-like browser based on PyQt5 and QtWebEngine"
|
||||
HOMEPAGE="https://www.qutebrowser.org/ https://github.com/qutebrowser/qutebrowser"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-3"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+adblock test"
|
||||
|
||||
BDEPEND="app-text/asciidoc"
|
||||
RDEPEND=">=dev-python/colorama-0.4.4[${PYTHON_USEDEP}]
|
||||
$(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' python3_{7,8})
|
||||
>=dev-python/jinja-3.0.1[${PYTHON_USEDEP}]
|
||||
>=dev-python/markupsafe-2.0.1[${PYTHON_USEDEP}]
|
||||
dev-python/pygments[${PYTHON_USEDEP}]
|
||||
dev-python/PyQt5[${PYTHON_USEDEP},dbus,declarative,multimedia,gui,network,opengl,printsupport,sql,widgets]
|
||||
dev-python/PyQtWebEngine[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyyaml-5.4.1[${PYTHON_USEDEP},libyaml]
|
||||
dev-python/typing-extensions[${PYTHON_USEDEP}]
|
||||
dev-python/zipp[${PYTHON_USEDEP}]
|
||||
adblock? ( dev-python/adblock[${PYTHON_USEDEP}] )"
|
||||
|
||||
distutils_enable_tests setup.py
|
||||
|
||||
# Tests depend (misc/requirements/requirements-tests.txt) on plugins
|
||||
# we don't have packages for.
|
||||
RESTRICT="test"
|
||||
|
||||
python_compile_all() {
|
||||
a2x -f manpage doc/${PN}.1.asciidoc || die "Failed generating man page"
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
insinto /usr/share/metainfo
|
||||
doins misc/org.qutebrowser.qutebrowser.appdata.xml
|
||||
doman doc/${PN}.1
|
||||
domenu misc/org.${PN}.${PN}.desktop
|
||||
for s in 16 24 32 48 64 128 256 512; do
|
||||
doicon -s ${s} icons/qutebrowser-${s}x${s}.png
|
||||
done
|
||||
doicon -s scalable icons/${PN}.svg
|
||||
|
||||
insinto /usr/share/qutebrowser/userscripts
|
||||
doins misc/userscripts/README.md
|
||||
exeinto /usr/share/qutebrowser/userscripts
|
||||
for f in misc/userscripts/*; do
|
||||
if [[ "${f}" == "__pycache__" ]]; then
|
||||
continue
|
||||
fi
|
||||
doexe "${f}"
|
||||
done
|
||||
|
||||
exeinto /usr/share/qutebrowser/scripts
|
||||
for f in scripts/*; do
|
||||
if [[ "${f}" == "scripts/__init__.py" || \
|
||||
"${f}" == "scripts/__pycache__" || \
|
||||
"${f}" == "scripts/dev" || \
|
||||
"${f}" == "scripts/testbrowser" || \
|
||||
"${f}" == "scripts/asciidoc2html.py" || \
|
||||
"${f}" == "scripts/setupcommon.py" || \
|
||||
"${f}" == "scripts/link_pyqt.py" ]]; then
|
||||
continue
|
||||
fi
|
||||
doexe "${f}"
|
||||
done
|
||||
|
||||
distutils-r1_python_install_all
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
optfeature "PDF display support" www-plugins/pdfjs
|
||||
xdg_desktop_database_update
|
||||
xdg_icon_cache_update
|
||||
xdg_mimeinfo_database_update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
xdg_desktop_database_update
|
||||
xdg_icon_cache_update
|
||||
xdg_mimeinfo_database_update
|
||||
}
|
||||
Reference in New Issue
Block a user